;/* 這是被CALL197.C調用的MAX197匯編程序，文件名為M197B.ASM         */
;/* 功能：本程序主要是讀出MAX197輸入通道CH0~CH7任一通道的模數轉換值,*/
;/*    轉換值放在寄存器R6,R7中,R6放高位。MAX197芯片的8個通道可選    */
;/*    四種輸入范圍(±10V，±5V，0～10V，0～5V)之一，這里采用0～5V    */
;/*    輸入。MAX197有內部時鐘和外部時鐘兩種工作模式,這里采用內      */
;/*    部時鐘模式。MAX197有內帶4.096V的參考電壓，也可用外部參考     */
;/*    電壓，這里采用內帶4.096V的參考電壓。                         */
;/*    MAX197的控制字：輸入電壓范圍為單極性（0－5V）、內部觸發采    */
;/*    集方式、第1通道，則應寫入16 進制數40H，而對應第8通道則寫入   */
;/*    47H。判斷轉換完成與否用延時方式-延時10μs。                    */

   NAME MAX197B
   ?PR?_a_func?MAX197B     SEGMENT CODE
   ?DT?_a_func?MAX197B     SEGMENT DATA OVERLAYABLE
   ?DT?MAX197B             SEGMENT DATA

   PUBLIC   chai
   PUBLIC   ?_a_func?BYTE
   PUBLIC    _a_func
   RSEG  ?DT?_a_func?MAX197B
	 ?_a_func?BYTE:
	 aa:DS 1
   RSEG  ?DT?MAX197B
	 chai:DS 2
   RSEG  ?PR?_a_func?MAX197B
	  _a_func:

CS        EQU P3.7
WRR       EQU P3.5
RDR       EQU P3.4
HEBN      EQU P3.3


         MOV aa,R7      ;R7中放傳遞進來的字符型參數,為控制字
         MOV A,aa
         CLR CS
         NOP
         CLR WRR
         NOP
         MOV P1,A       ;采集通道控制字由累加器A送入P1中
         SETB WRR
         NOP
         SETB CS
         NOP            ;用延時方式-等待轉換完成
         NOP
         NOP
         NOP
         NOP
         NOP
         NOP
         NOP
         NOP
         NOP
         CLR    CS
         CLR    RDR
         MOV   P1,#0FFH
         SETB   HEBN
         MOV A,P1         ;接受高4位
         ANL A,#0FH
         MOV R6,A         ;R6中放返回轉換值高4位
         MOV P1,#0FFH
         CLR HEBN
         MOV A,P1         ;接受低8位
         MOV R7,A         ;R7中放返回轉換值低8位
         SETB   RDR
         SETB   CS
         RET
         END