;/* 這是被CALL111.C調用的MAX111匯編程序，文件名為MAX111B.ASM         */
;/* 功能：本程序主要是讀出芯片MAX111輸入通道CH0和CH1的模數轉換值,    */
;/*    轉換值放在寄存器R6,R7中,R6放高位。MAX111芯片的2個通道         */
;/*    可編程為單極性/雙極性和差動/單端工作, 這里采用單端\單極性     */
;/*    輸入。MAX111有內部時鐘和外部時鐘兩種工作模式。這里采用內      */
;/*    部時鐘模式                                                    */

   NAME MAX111B
   ?PR?_a_func?MAX111B    SEGMENT CODE
   ?DT?_a_func?MAX111B    SEGMENT DATA OVERLAYABLE
   ?DT?MAX111B            SEGMENT DATA

   PUBLIC   chai
   PUBLIC   ?_a_func?BYTE
   PUBLIC    _a_func
   RSEG  ?DT?_a_func?MAX111B
	 ?_a_func?BYTE:
	 aa:DS 2
   RSEG  ?DT?MAX111B
	 chai:DS 2
   RSEG  ?PR?_a_func?MAX111B
	 _a_func:

CS                 BIT  P1.0
DOUT               BIT  P1.3
DIN                BIT  P1.2
SCK                BIT  P1.1
BUSY               BIT  P1.7
count              EQU 20H
ctrlh              EQU 21H
ctrll              EQU 22H
byteinh            EQU 23H
byteinl            EQU 24H

                 MOV aa,R7      ;在入口：R6,R7中放傳遞進來的一個整型數
                 MOV aa+1,R6
                 MOV ctrlh,R6
                 MOV ctrll,R7
                 LCALL M111
                 MOV R6,byteinh ;在出口，R6和R7中放返回整型值
                 MOV R7,byteinl
                 RET

M111:            SETB BUSY      ;送通道控制字及讀出轉換值子程序
                 SETB DOUT
                 JNB ctrlh.7,WAIBUSY
                 MOV   R3, #0CH  ;等待BUSY信號為高電平
DLP3:            MOV   R2, #0FFH
DLP2:            MOV   R1, #0FFH
DLP1:            JB BUSY,WAIBUSY
                 DJNZ  R1, DLP1
                 DJNZ  R2, DLP2
                 DJNZ  R3, DLP3
                 SJMP TIMEOUT     ;超時轉
WAIBUSY:	     CLR SCK
		         CLR CS
		         MOV COUNT,#08H   ;處理高8位
LOOP1:           NOP
                 MOV C,ctrlh.7
                 MOV DIN,C
                 SETB SCK
                 MOV C,DOUT
                 MOV byteinh.7,C
                 CLR SCK
                 MOV A,ctrlh
                 RL A
                 MOV ctrlh,A
                 MOV A,byteinh
                 RL A
                 MOV byteinh,A
                 DJNZ COUNT,LOOP1
		         MOV COUNT,#08H     ;處理低8位
LOOP2:           NOP
                 MOV C,ctrll.7
                 MOV DIN,C
                 SETB SCK
                 MOV C,DOUT
                 MOV byteinl.7,C
                 CLR SCK
                 MOV A,ctrll
                 RL A
                 MOV ctrll,A
                 MOV A,byteinl
                 RL A
                 MOV byteinl,A
                 DJNZ COUNT,LOOP2
	 	         SETB CS
		         CLR C
 		         RET
TIMEOUT: 	     SETB CS        ;超時置進位位
		         SETB C
 		         RET
Delay:           NOP            ;延時程序
                 MOV   R2, #1
                 MOV   R1, #0
                 MOV   R0, #0
DLP:             NOP
                 DJNZ  R0, DLP
                 DJNZ  R1, DLP
                 DJNZ  R2, DLP
                 RET
	    	     END