KEY4: SETB P1.0
        MOV DPTR,#TBK
        MOV A,R7
        MOVC A,@A+DPTR
        MOV  R7,A
        SJMP KEY6
  KEY5: MOV A,#0F0H
        NOP
  KEY6: NOP
        RET 
;---
TBK:
; 鍵盤(pán)布局
DB 07H, 08H, 09H, 10H ; 7 8 9 +
DB 04H, 05H, 06H, 20H ; 4 5 6 -
DB 01H, 02H, 03H, 30H ; 1 2 3 *
DB 00H, 0FFH, 80H, 40H ; 0 . = /

;**************************************
;顯示程序
;**************************************
DISPLAY:
     MOV DPTR, #DISPTAB
     MOV R0, #RAWIN
     MOV TEMP1, DCOUNT
     ; CLEAR THE SCREEN
     MOV COM, #01H
     LCALL PR1
     
     MOV A, DCOUNT
     JZ DISP_ZERO
     
     JB STAT.7, DISP_ERR
DISP_NORMAL:
MOV A, @R0
INC R0
INC A
JZ DISP_DP
DEC A
DISP_LOOKUP:
MOVC A, @A+DPTR
MOV DAT, A
LCALL PR2
LCALL DELAY
DJNZ TEMP1, DISP_NORMAL
SJMP DISP_DONE
; -----------
DISP_ZERO:
MOV A, #00H ; '0'
MOV TEMP1, #01H
SJMP DISP_LOOKUP

; --------------
DISP_DP: ; DISPLAY, DECIMAL POINT
MOV A, #0AH
SJMP DISP_LOOKUP
; -----------
DISP_ERR:
     MOV A, #0CH ; 'E'
     MOVC A, @A+DPTR
     MOV DAT, A
     LCALL PR2
     LCALL DELAY
     SJMP DISP_DONE
; ----------------
DISP_DONE:
RET
;=================
DISPTAB:
DB 30H,31H,32H,33H,34H,35H,36H,37H, 38H, 39H
DB 2EH, 2DH, 45H ; '.', '-', 'E'    
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; =======================================================

;;***************************************
;; LCD 初始化程序
;;***************************************
LCDINIT:MOV   A,#30H
        MOV   DPTR,#CW_ADD
        MOV   R2,#03H
LCDINT1:MOVX  @DPTR,A
        LCALL DELAY
        DJNZ  R2,LCDINT1
        MOV   COM,#38H
        LCALL PR1
        MOV   COM,#01H
        LCALL PR1
        MOV   COM,#06H     ;設(shè)置輸入方式
        LCALL PR1
        MOV   COM,#0FH      
        LCALL PR1
        
        RET


;********************************
;讀BF和AC值
;********************************


PR0: PUSH  DPH
     PUSH  DPL
     PUSH  ACC
     MOV   DPTR,#CR_ADD
     MOVX  A,@DPTR
     MOV   COM,A
     POP   ACC
     POP   DPL
     POP   DPH
     RET
;********************************
;寫(xiě)指令代碼字程序
;********************************
     
PR1: PUSH  DPH
     PUSH  DPL
     PUSH  ACC
     MOV   DPTR,#CR_ADD       
PR11:MOVX  A,@DPTR
     JB    ACC.7,PR11
     MOV   A,COM
     MOV   DPTR,#CW_ADD
     MOVX  @DPTR,A
     POP   ACC
     POP   DPL
     POP   DPH
     RET
;********************************
;寫(xiě)顯示數(shù)據(jù)子程序
;******************************** 
PR2: PUSH   DPH
     PUSH   DPL
     PUSH   ACC
     MOV    DPTR,#CR_ADD
PR21:MOVX   A,@DPTR
     JB     ACC.7,PR21
     MOV    A,DAT
     MOV    DPTR,#DW_ADD
     MOVX   @DPTR,A
     POP    ACC
     POP    DPL
     POP    DPH
     RET       
;********************************
;讀顯示數(shù)據(jù)子程序
;******************************** 
PR3: PUSH   DPH
     PUSH   DPL
     PUSH   ACC
     MOV    DPTR,#CR_ADD
PR31:MOVX   A,@DPTR
     JB     ACC.7,PR31
     MOV    DPTR,#DR_ADD
     MOVX   A,@DPTR
     MOV    DAT,A
     POP    ACC
     POP    DPL
     POP    DPH
     RET
     
;*****************************************
;  DELAY
;*****************************************
DELAY:  MOV   R6,#02H
        MOV   R7,#02H
DELAY1: NOP
        DJNZ  R7,DELAY1
        DJNZ  R6,DELAY1
        RET 


; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; FLOATLIB          浮點(diǎn)程序庫(kù)
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; ===========================================================

;（１） 標(biāo)號(hào)： ＦＳＤＴ 功能：浮點(diǎn)數(shù)格式化 

;入口條件：待格式化浮點(diǎn)操作數(shù)在[R0]中。 
;出口信息：已格式化浮點(diǎn)操作數(shù)仍在[R0]中。 
;影響資源：PSW、A、R2、R3、R4、位1FH 堆棧需求： ６字節(jié) 
FSDT: LCALL MVR0 ; 將待格式化操作數(shù)傳送到第一工作區(qū)中 
LCALL RLN ; 通過(guò)左規(guī)完成格式化 
LJMP MOV0 ; 將已格式化浮點(diǎn)操作數(shù)傳回到[R0]中 

;（２） 標(biāo)號(hào)： ＦＡＤＤ 功能：浮點(diǎn)數(shù)加法 

;入口條件：被加數(shù)在[R0]中，加數(shù)在[R1]中。 
;出口信息：OV=0時(shí)，和仍在[R0]中，OV=1時(shí)，溢出。 
;影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求： ６字節(jié) 
FADD: CLR F0 ; 設(shè)立加法標(biāo)志 
SJMP AS ; 計(jì)算代數(shù)和 

;（３） 標(biāo)號(hào)： ＦＳＵＢ 功能：浮點(diǎn)數(shù)減法 

;入口條件：被減數(shù)在[R0]中，減數(shù)在[R1]中。 
;出口信息：OV=0時(shí)，差仍在[R0]中，OV=1時(shí)，溢出。 
;影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：６字節(jié) 
FSUB: SETB F0 ; 設(shè)立減法標(biāo)志 
AS: LCALL MVR1 ; 計(jì)算代數(shù)和。先將[R1]傳送到第二工作區(qū) 
MOV C,F0 ; 用加減標(biāo)志來(lái)校正第二操作數(shù)的有效符號(hào) 
RRC A 
XRL A,@R1 
MOV C,ACC.7 
ASN: MOV 1EH,C ; 將第二操作數(shù)的有效符號(hào)存入位1EH中 
XRL A,@R0 ; 與第一操作數(shù)的符號(hào)比較 
RLC A 
MOV F0,C ; 保存比較結(jié)果 
LCALL MVR0 ; 將[R0]傳送到第一工作區(qū)中 
LCALL AS1 ; 在工作寄存器中完成代數(shù)運(yùn)算 
MOV0: INC R0 ; 將結(jié)果傳回到[R0]中的子程序入口 
INC R0 
MOV A,R4 ; 傳回尾數(shù)的低字節(jié) 
MOV @R0,A 
DEC R0 
MOV A,R3 ; 傳回尾數(shù)的高字節(jié) 
MOV @R0,A 
DEC R0 
MOV A,R2 ; 取結(jié)果的階碼 
MOV C,1FH ; 取結(jié)果的數(shù)符 
MOV ACC.7,C ; 拼入階碼中 
MOV @R0,A 
CLR ACC.7 ; 不考慮數(shù)符 
CLR OV ; 清除溢出標(biāo)志 
CJNE A,#3FH,MV01; 階碼是否上溢？ 
SETB OV ; 設(shè)立溢出標(biāo)志 
MV01: MOV A,@R0 ; 取出帶數(shù)符的階碼 
RET 
MVR0: MOV A,@R0 ; 將[R0]傳送到第一工作區(qū)中的子程序 
MOV C,ACC.7 ; 將數(shù)符保存在位1FH中 
MOV 1FH,C 
MOV C,ACC.6 ; 將階碼擴(kuò)充為８ｂｉｔ補(bǔ)碼 
MOV ACC.7,C 
MOV R2,A ; 存放在R2中 
INC R0 
MOV A,@R0 ; 將尾數(shù)高字節(jié)存放在R3中 
MOV R3,A 
INC R0 
MOV A,@R0 ; 將尾數(shù)低字節(jié)存放在R4中 
MOV R4,A 
DEC R0 ; 恢復(fù)數(shù)據(jù)指針 
DEC R0 
RET 
MVR1: MOV A,@R1 ; 將[R1]傳送到第二工作區(qū)中的子程序 
MOV C,ACC.7 ; 將數(shù)符保存在位1EH中 
MOV 1EH,C 
MOV C,ACC.6 ; 將階碼擴(kuò)充為８ｂｉｔ補(bǔ)碼 
MOV ACC.7,C 
MOV R5,A ; 存放在R5中 
INC R1 
MOV A,@R1 ; 將尾數(shù)高字節(jié)存放在R6中 
MOV R6,A 
INC R1 
MOV A,@R1 ; 將尾數(shù)低字節(jié)存放在R7中 
MOV R7,A 
DEC R1 ; 恢復(fù)數(shù)據(jù)指針 
DEC R1 
RET 
AS1: MOV A,R6 ; 讀取第二操作數(shù)尾數(shù)高字節(jié) 
ORL A,R7 
JZ AS2 ; 第二操作數(shù)為零，不必運(yùn)算 
MOV A,R3 ; 讀取第一操作數(shù)尾數(shù)高字節(jié) 
ORL A,R4 
JNZ EQ1 
MOV A,R6 ; 第一操作數(shù)為零，結(jié)果以第二操作數(shù)為準(zhǔn) 
MOV R3,A 
MOV A,R7 
MOV R4,A 
MOV A,R5 
MOV R2,A 
MOV C,1EH 
MOV 1FH,C 
AS2: RET 
EQ1: MOV A,R2 ; 對(duì)階，比較兩個(gè)操作數(shù)的階碼 
XRL A,R5 
JZ AS4 ; 階碼相同，對(duì)階結(jié)束 
JB ACC.7,EQ3; 階符互異 
MOV A,R2 ; 階符相同，比較大小 
CLR C 
SUBB A,R5 
JC EQ4 
EQ2: CLR C ; 第二操作數(shù)右規(guī)一次 
MOV A,R6 ; 尾數(shù)縮小一半 
RRC A 
MOV R6,A 
MOV A,R7 
RRC A 
MOV R7,A 
INC R5 ; 階碼加一 
ORL A,R6 ; 尾數(shù)為零否？ 
JNZ EQ1 ; 尾數(shù)不為零，繼續(xù)對(duì)階 
MOV A,R2 ; 尾數(shù)為零，提前結(jié)束對(duì)階 
MOV R5,A 
SJMP AS4 
EQ3: MOV A,R2 ; 判斷第一操作數(shù)階符 
JNB ACC.7,EQ2; 如為正，右規(guī)第二操作數(shù) 
EQ4: CLR C 
LCALL RR1 ; 第一操作數(shù)右規(guī)一次 
ORL A,R3 ; 尾數(shù)為零否？ 
JNZ EQ1 ; 不為零，繼續(xù)對(duì)階 
MOV A,R5 ; 尾數(shù)為零，提前結(jié)束對(duì)階 
MOV R2,A 
AS4: JB F0,AS5 ; 尾數(shù)加減判斷 
MOV A,R4 ; 尾數(shù)相加 
ADD A,R7 
MOV R4,A 
MOV A,R3 
ADDC A,R6 
MOV R3,A 
JNC AS2 
LJMP RR1 ; 有進(jìn)位，右規(guī)一次 
AS5: CLR C ; 比較絕對(duì)值大小 
MOV A,R4 
SUBB A,R7 
MOV B,A 
MOV A,R3 
SUBB A,R6 
JC AS6 
MOV R4,B ; 第一尾數(shù)減第二尾數(shù) 
MOV R3,A 
LJMP RLN ; 結(jié)果規(guī)格化 
AS6: CPL 1FH ; 結(jié)果的符號(hào)與第一操作數(shù)相反 
CLR C ; 結(jié)果的絕對(duì)值為第二尾數(shù)減第一尾數(shù) 
MOV A,R7 
SUBB A,R4 
MOV R4,A 
MOV A,R6 
SUBB A,R3 
MOV R3,A 
RLN: MOV A,R3 ; 浮點(diǎn)數(shù)規(guī)格化 
ORL A,R4 ; 尾數(shù)為零否？ 
JNZ RLN1 
MOV R2,#0C1H; 階碼取最小值 
RET 
RLN1: MOV A,R3 
JB ACC.7,RLN2; 尾數(shù)最高位為一否？ 
CLR C ; 不為一，左規(guī)一次 
LCALL RL1 
SJMP RLN ; 繼續(xù)判斷 
RLN2: CLR OV ; 規(guī)格化結(jié)束 
RET 
RL1: MOV A,R4 ; 第一操作數(shù)左規(guī)一次 
RLC A ; 尾數(shù)擴(kuò)大一倍 
MOV R4,A 
MOV A,R3 
RLC A 
MOV R3,A 
DEC R2 ; 階碼減一 
CJNE R2,#0C0H,RL1E; 階碼下溢否？ 
CLR A 
MOV R3,A ; 階碼下溢，操作數(shù)以零計(jì) 
MOV R4,A 
MOV R2,#0C1H 
RL1E: CLR OV 
RET 
RR1: MOV A,R3 ; 第一操作數(shù)右規(guī)一次 
RRC A ; 尾數(shù)縮小一半 
MOV R3,A 
MOV A,R4 
RRC A 
MOV R4,A 
INC R2 ; 階碼加一 
CLR OV ; 清溢出標(biāo)志 
CJNE R2,#40H,RR1E; 階碼上溢否？ 
MOV R2,#3FH ; 階碼溢出 
SETB OV 
RR1E: RET

;(４） 標(biāo)號(hào)： ＦＭＵＬ 功能：浮點(diǎn)數(shù)乘法 

;入口條件：被乘數(shù)在[R0]中，乘數(shù)在[R1]中。 
;出口信息：OV=0時(shí)，積仍在[R0]中，OV=1時(shí)，溢出。 
;影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：６字節(jié) 
FMUL: LCALL MVR0 ; 將[R0]傳送到第一工作區(qū)中 
MOV A,@R0 
XRL A,@R1 ; 比較兩個(gè)操作數(shù)的符號(hào) 
RLC A 
MOV 1FH,C ; 保存積的符號(hào) 
LCALL MUL0 ; 計(jì)算積的絕對(duì)值 
LJMP MOV0 ; 將結(jié)果傳回到[R0]中 
MUL0: LCALL MVR1 ; 將[R1]傳送到第二工作區(qū)中 
MUL1: MOV A,R3 ; 第一尾數(shù)為零否？ 
ORL A,R4 
JZ MUL6 
MOV A,R6 ; 第二尾數(shù)為零否？ 
ORL A,R7 
JZ MUL5 
MOV A,R7 ; 計(jì)算R3R4×R6R7－→R3R4 
MOV B,R4 
MUL AB 
MOV A,B 
XCH A,R7 
MOV B,R3 
MUL AB 
ADD A,R7 
MOV R7,A 
CLR A 
ADDC A,B 
XCH A,R4 
MOV B,R6 
MUL AB 
ADD A,R7 
MOV R7,A 
MOV A,B 
ADDC A,R4 
MOV R4,A 
CLR A 
RLC A 
XCH A,R3 
MOV B,R6 
MUL AB 
ADD A,R4 
MOV R4,A 
MOV A,B 
ADDC A,R3 
MOV R3,A 
JB ACC.7,MUL2; 積為規(guī)格化數(shù)否？ 
MOV A,R7 ; 左規(guī)一次 
RLC A 
MOV R7,A 
LCALL RL1 
MUL2: MOV A,R7 
JNB ACC.7,MUL3 
INC R4 
MOV A,R4 
JNZ MUL3 
INC R3 
MOV A,R3 
JNZ MUL3 
MOV R3,#80H 
INC R2 
MUL3: MOV A,R2 ; 求積的階碼 
ADD A,R5 
MD: MOV R2,A ; 階碼溢出判斷 
JB ACC.7,MUL4 
JNB ACC.6,MUL6 
MOV R2,#3FH ; 階碼上溢，設(shè)立標(biāo)志 
SETB OV 
RET 
MUL4: JB ACC.6,MUL6 
MUL5: CLR A ; 結(jié)果清零（因子為零或階碼下溢） 
MOV R3,A 
MOV R4,A 
MOV R2,#41H 
MUL6: CLR OV 
RET 

;（５） 標(biāo)號(hào)： ＦＤＩＶ 功能：浮點(diǎn)數(shù)除法 

;入口條件：被除數(shù)在[R0]中，除數(shù)在[R1]中。 
;出口信息：OV=0時(shí)，商仍在[R0]中，OV=1時(shí)，溢出。 
;影響資源：PSW、A、B、R2～R7、位1EH、1FH 堆棧需求： ５字節(jié) 
FDIV: INC R0 
MOV A,@R0 
INC R0 
ORL A,@R0 
DEC R0 
DEC R0 
JNZ DIV1 
MOV @R0,#41H; 被除數(shù)為零，不必運(yùn)算 
CLR OV 
RET 
DIV1: INC R1 
MOV A,@R1 
INC R1 
ORL A,@R1 
DEC R1 
DEC R1 
JNZ DIV2 
SETB OV ; 除數(shù)為零，溢出 
RET 
DIV2: LCALL MVR0 ; 將[R0]傳送到第一工作區(qū)中 
MOV A,@R0 
XRL A,@R1 ; 比較兩個(gè)操作數(shù)的符號(hào) 
RLC A 
MOV 1FH,C ; 保存結(jié)果的符號(hào) 
LCALL MVR1 ; 將[R1]傳送到第二工作區(qū)中 
LCALL DIV3 ; 調(diào)用工作區(qū)浮點(diǎn)除法 
LJMP MOV0 ; 回傳結(jié)果 
DIV3: CLR C ; 比較尾數(shù)的大小 
MOV A,R4 
SUBB A,R7 
MOV A,R3 
SUBB A,R6 
JC DIV4 
LCALL RR1 ; 被除數(shù)右規(guī)一次 
SJMP DIV3 
DIV4: CLR A ; 借用R0R1R2作工作寄存器 
XCH A,R0 ; 清零并保護(hù)之 
PUSH ACC 
CLR A 
XCH A,R1 
PUSH ACC 
MOV A,R2 
PUSH ACC 
MOV B,#10H ; 除法運(yùn)算，R3R4／R6R7－→R0R1 
DIV5: CLR C 
MOV A,R1 
RLC A 
MOV R1,A 
MOV A,R0 
RLC A 
MOV R0,A 
MOV A,R4 
RLC A 
MOV R4,A 
XCH A,R3 
RLC A 
XCH A,R3 
MOV F0,C 
CLR C 
SUBB A,R7 
MOV R2,A 
MOV A,R3 
SUBB A,R6 
ANL C,/F0 
JC DIV6 
MOV R3,A 
MOV A,R2 
MOV R4,A 
INC R1 
DIV6: DJNZ B,DIV5 
MOV A,R6 ; 四舍五入