unit operatorinfo;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, frame, StdCtrls, Buttons, Grids, DBGrids, ExtCtrls,
  DB;

type
  Tf_operatorinfo = class(Tf_frame)
    Panel1: TGroupBox;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Level: TComboBox;
    DBGrid1: TDBGrid;
    Add: TBitBtn;
    Cancel: TBitBtn;
    Update: TBitBtn;
    Delete: TBitBtn;
    Image1: TImage;
    OperatorSource: TDataSource;
    Operatorname: TEdit;
    Password: TEdit;
    procedure CancelClick(Sender: TObject);
    procedure AddClick(Sender: TObject);
    procedure DeleteClick(Sender: TObject);
    procedure UpdateClick(Sender: TObject);
    procedure OperatornameKeyDown(Sender: TObject; var Key: Word;
      Shift: TShiftState);
    procedure DBGrid1DblClick(Sender: TObject);
  private
    { Private declarations }
  public
    Procedure ClearEdit;//清空編輯框中的文本
    Function TextIsNull: Boolean;//判斷編輯框中的文本是否為空
    Procedure Editvalue;//將數據集中的數據顯示在編輯框中
    { Public declarations }
  end;

var
  f_operatorinfo: Tf_operatorinfo;

implementation
  uses data;
{$R *.dfm}

{ Tf_operatorinfo }
//自定義過程,用于清空編輯框中的文本
procedure Tf_operatorinfo.ClearEdit;
var
  i: Integer;
begin
  For i := 0 to Panel1.ControlCount-1 do
    if Panel1.Controls[i]is TEdit then
      TEdit(Panel1.Controls[i]).Clear;
end;
//為編輯框賦值
procedure Tf_operatorinfo.Editvalue;
begin
  with t_data.Query1 do
  begin
    Operatorname.Text := Trim(FieldByName('Operatorname').AsString);
    Password.Text := Trim(FieldByName('password').AsString);
    Level.ItemIndex := Level.Items.IndexOf(Trim(FieldByName('Level').AsString));
  end;
end;
//判斷信息是否為空
function Tf_operatorinfo.TextIsNull: Boolean;
var
  i: Integer;
begin
  Result := False;
  For i := 0 to Panel1.ControlCount-1 do
    if Panel1.Controls[i] is TEdit then
    begin
      if Trim(TEdit(Panel1.Controls[i]).Text)='' then
      begin
        Result := True;
        Exit;
      end;
    end
    else if Panel1.Controls[i] is TComboBox then
    begin
      if Trim(TComboBox(Panel1.Controls[i]).Text)='' then
      begin
        Result := True;
        Exit;
      end;
    end;
end;
//取消按鈕單擊事件
procedure Tf_operatorinfo.CancelClick(Sender: TObject);
begin
  inherited;
  ClearEdit; //請空編輯框文本
  With t_data.Query1 do //顯示當前操作員信息
  begin
    CLose;
    SQL.Clear;
    SQL.Add('Select * from tb_operatorinfo');
    Open;
  end;
  if t_data.Query1.RecordCount>0 then
    OperatorSource.DataSet := t_data.Query1
  else
  begin
    t_data.Query1.Close;
    OperatorSource.DataSet := Nil;
  end;
  Level.ItemIndex := 0;
end;
//添加按鈕單擊事件
procedure Tf_operatorinfo.AddClick(Sender: TObject);
begin
  inherited;
  if TextIsNull = False then //如果基礎信息不為空
  begin
    With t_data.Query2 do //判斷操作員信息是否在員工信息表中存在
    begin
      CLose;
      SQL.Clear;
      SQL.Add('Select * from tb_employeeinfo where workername = :name');
      Parameters.ParamByName('name').Value := Trim(Operatorname.Text);
      Open;
    end;
    if t_data.Query2.RecordCount<1 then //如果操作員信息在員工信息表中不存在,進行提示并退出
    begin
      Application.MessageBox('該操作員在員工信息表中不存在,請重新輸入.','提示',64);
      Operatorname.SelectAll;
      Operatorname.SetFocus;
      Exit;
    end;
    With t_data.Query2 do  //判斷操作員信息在操作員信息表中是否存在
    begin
      CLose;
      SQL.Clear;
      SQL.Add('Select * from tb_operatorinfo where operatorname = :name');
      Parameters.ParamByName('name').Value := Trim(Operatorname.Text);
      Open;
    end;
    if t_data.Query2.RecordCount>0 then //如果操作員信息在操作員信息表中存在,進行退出并退出
    begin
      Application.MessageBox('該操作員已經存在,請重新輸入.','提示',64);
      Operatorname.SelectAll;
      Operatorname.SetFocus;
      Exit;
    end;
    Try
      with t_data.Add1 do //將操作員工信息添加到操作員信息表中
      begin
        Close;
        SQL.Clear;
        SQL.Add('Insert into tb_operatorinfo Values (:operatorname,:password,:level)');
        Parameters.ParamByName('operatorname').Value := Trim(Operatorname.Text);
        Parameters.ParamByName('password').Value := Trim(Password.Text);
        Parameters.ParamByName('level').Value := Trim(Level.Text);
        ExecSQL;
      end;
      Application.MessageBox('操作成功.','提示',64);
      Cancel.Click;
    Except
      On E: Exception do
        ShowMessage(E.Message);
    End;
  end
  else
  begin
    Application.MessageBox('操作員信息不能為空.','提示',64);
  end;
end;
//處理刪除按鈕單擊事件
procedure Tf_operatorinfo.DeleteClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then
  begin
    if Application.MessageBox(Pchar('確實要刪除操作員名稱為: ' + Trim(t_data.Query1.FieldByName('operatorname').AsString)+' 的操作員信息嗎?'),'提示',mb_YesNo)= ID_Yes then
    begin
      Try
        t_data.Query1.Delete;
        Cancel.Click;
      Except
        On E: Exception do
          ShowMessage(E.Message);
      End;
    end
  end
  else
    Application.MessageBox('當前沒有可刪除的信息.','提示',64);
end;
//處理修改按鈕單擊事件
procedure Tf_operatorinfo.UpdateClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then //判斷數據集是否激活
  begin
    if TextIsNull = False then //判斷信息是否為空
    begin
      //提示是否修改數據
      if Application.MessageBox(Pchar('確實要修改操作員名稱為: '+t_data.Query1.FieldByName('Operatorname').AsString+' 的操作員信息嗎?'),'提示',mb_YesNo)= ID_Yes then
      begin
        Try
          With t_data.update1 do  //利用SQL語句修改數據
          begin
            CLose;
            SQL.Clear;
            SQL.Add('update tb_operatorinfo set operatorname = :operatorname,password = :password,level = :level where operatorname = :oldname');
            Parameters.ParamByName('operatorname').Value := Trim(Operatorname.Text);
            Parameters.ParamByName('password').Value := Trim(password.Text);
            Parameters.ParamByName('level').Value := Trim(Level.Text);
            Parameters.ParamByName('oldname').Value := Trim(t_data.Query1.FieldByName('Operatorname').AsString);
            ExecSQL;
          end;
          Application.MessageBox('修改成功.','提示',64);
          Cancel.Click;
        Except //如果出現異常,顯示異常信息
          On E: Exception do
            ShowMessage(E.Message);
        End;
      end;
    end
    else
      Application.MessageBox('職務信息不能為空.','提示',64);
  end
  else
    Application.MessageBox('當前沒有可修改的數據.','提示',64);
end;

procedure Tf_operatorinfo.OperatornameKeyDown(Sender: TObject;
  var Key: Word; Shift: TShiftState);
begin
  inherited;
  if Key = vk_Return then //按回車鍵控制焦點移動
    FindNext(True);
end;
//雙擊表格,將當前記錄信息顯示在編輯框中
procedure Tf_operatorinfo.DBGrid1DblClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then
    Editvalue;
end;

end.