?? providerinfo.pas

?? 物流管理系統是一個典型的數據庫應用程序
?? PAS
字號:

unit providerinfo;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, frame, DB, Grids, DBGrids, StdCtrls, Buttons,
  ExtCtrls;

type
  Tf_providerinfo = class(Tf_frame)
    Label6: TLabel;
    Panel2: TPanel;
    Label7: TLabel;
    Label8: TLabel;
    Add: TBitBtn;
    Cancel: TBitBtn;
    Update: TBitBtn;
    Delete: TBitBtn;
    Field: TComboBox;
    Query: TBitBtn;
    DBGrid1: TDBGrid;
    ProviderSource: TDataSource;
    Panel1: TPanel;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Label5: TLabel;
    Label9: TLabel;
    providername: TEdit;
    Nameshort: TEdit;
    Phone: TEdit;
    Principal: TEdit;
    Address: TEdit;
    Web: TEdit;
    Value: TEdit;
    procedure providernameKeyDown(Sender: TObject; var Key: Word;
      Shift: TShiftState);
    procedure FormShow(Sender: TObject);
    procedure CancelClick(Sender: TObject);
    procedure AddClick(Sender: TObject);
    procedure UpdateClick(Sender: TObject);
    procedure DeleteClick(Sender: TObject);
    procedure QueryClick(Sender: TObject);
    procedure DBGrid1DblClick(Sender: TObject);
    procedure PhoneKeyPress(Sender: TObject; var Key: Char);
  private
    { Private declarations }
  public
    Procedure ClearEdit;//清空編輯框中的文本
    Function TextIsNull: Boolean;//判斷編輯框中的文本是否為空
    Procedure Editvalue;//將數據集中的數據顯示在編輯框中

    { Public declarations }
  end;

var
  f_providerinfo: Tf_providerinfo;

implementation
  uses data;
{$R *.dfm}
//按回車鍵控制焦點移動
procedure Tf_providerinfo.providernameKeyDown(Sender: TObject;
  var Key: Word; Shift: TShiftState);
begin
  inherited;
  if Key = vk_Return then
    Findnext(True);
end;
//窗體顯示時調用取消按鈕的單擊事件代碼初始化
procedure Tf_providerinfo.FormShow(Sender: TObject);
begin
  inherited;
  Cancel.Click;
end;
//自定義過程,用于清空編輯框中的文本
procedure Tf_providerinfo.ClearEdit;
var
  i: Integer;
begin
  For i := 0 to Panel1.ControlCount-1 do
    if Panel1.Controls[i]is TEdit then
      TEdit(Panel1.Controls[i]).Clear;
end;
//取消按鈕單擊事件,用于進行初始化
procedure Tf_providerinfo.CancelClick(Sender: TObject);
begin
  inherited;
  ClearEdit; //清空編輯框文本
  Field.ItemIndex := 0;
  With t_data.Query1 do //向表格中加載供應商信息
  begin
    CLose;
    SQL.Clear;
    SQL.Add('Select * from tb_providerinfo');
    Open;
  end;
  if t_data.Query1.RecordCount>0 then
    ProviderSource.DataSet := t_data.Query1
  else
  begin
    t_data.Query1.Close;
    ProviderSource.DataSet := Nil;
  end;
end;
//自定義過程,將當前記錄數據顯示在編輯框中
procedure Tf_providerinfo.Editvalue;
begin
  with t_data.Query1 do
  begin
    Providername.Text := Trim(FieldByName('Providername').AsString);
    Nameshort.Text := Trim(FieldByName('nameshort').AsString);
    Phone.Text := Trim(FieldByName('phone').AsString);
    Principal.Text := Trim(FieldByName('Principal').AsString);
    Address.Text := Trim(FieldByName('Address').AsString);
    Web.Text := Trim(FieldByName('web').AsString);
  end;
end;
//自定義函數,用于判斷編輯框文本是否空,如果為空,返回值為True,否則為False
function Tf_providerinfo.TextIsNull: Boolean;
var
  i: Integer;
begin
  Result := False;
  For i := 0 to Panel1.ControlCount-1 do
    if Panel1.Controls[i] is TEdit then
    begin
      if Trim(TEdit(Panel1.Controls[i]).Text)='' then
      begin
        Result := True;
        Break;
      end;
    end;
end;
//處理添加按鈕的單擊事件,
procedure Tf_providerinfo.AddClick(Sender: TObject);
begin
  inherited;
  if TextIsNull = False then //判斷編輯框文本是否為空
  begin
    With t_data.Query2 do  //判斷供應商是否存在
    begin
      CLose;
      SQL.Clear;
      SQL.Add('Select * from tb_providerinfo where providername = :name');
      Parameters.ParamByName('name').Value := Trim(Providername.Text);
      Open;
    end;
    if t_data.Query2.RecordCount>0 then
    begin
      Application.MessageBox('該供應商已經存在,請重新輸入.','提示',64);
      Providername.SelectAll;
      Providername.SetFocus;
      Exit;
    end;
    Try
      with t_data.Add1 do  //保存供應商信息
      begin
        Close;
        SQL.Clear;
        SQL.Add('Insert into tb_providerinfo Values (:providername,:shortname,:principal,:phone,:address,:web)');
        Parameters.ParamByName('providername').Value := Trim(Providername.Text);
        Parameters.ParamByName('shortname').Value := Trim(Nameshort.Text);
        Parameters.ParamByName('principal').Value := Trim(Principal.Text);
        Parameters.ParamByName('phone').Value := Trim(Phone.Text);
        Parameters.ParamByName('address').Value := Trim(Address.Text);
        Parameters.ParamByName('web').Value := Trim(Web.Text);
        ExecSQL;
      end;
      Application.MessageBox('操作成功.','提示',64);
      Cancel.Click;
    Except
      On E: Exception do    //如果產生異常,顯示異常信息
        ShowMessage(E.Message);
    End;
  end
  else
  begin
    Application.MessageBox('供應商信息不能為空.','提示',64);
  end;
end;
//處理修改按鈕的單擊事件
procedure Tf_providerinfo.UpdateClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then //判斷當前是否有可修改的數據
  begin
    if TextIsNull = False then //判斷基礎信息是否為空
    begin
      //提示是否修改數據
      if Application.MessageBox(Pchar('確實要修改供應商名稱為: '+t_data.Query1.FieldByName('Providername').AsString+' 的供應商信息嗎?'),'提示',mb_YesNo)= ID_Yes then
      begin
        Try
          With t_data.update1 do
          begin
            CLose;
            SQL.Clear;
            SQL.Add('update tb_providerinfo set providername = :name,nameshort = :short,principal =:principal,phone = :phone,address = :address,web = :web where providername = :oldname');
            Parameters.ParamByName('name').Value := Trim(Providername.Text);
            Parameters.ParamByName('short').Value := Trim(Nameshort.Text);
            Parameters.ParamByName('principal').Value := Trim(principal.Text);
            Parameters.ParamByName('phone').Value := Trim(phone.Text);
            Parameters.ParamByName('address').Value := Trim(address.Text);
            Parameters.ParamByName('web').Value := Trim(web.Text);
            Parameters.ParamByName('oldname').Value := Trim(t_data.Query1.FieldByName('providername').AsString);
            ExecSQL;
          end;
          Application.MessageBox('修改成功.','提示',64);
          Cancel.Click;
        Except
          On E: Exception do //如果產生異常則顯示錯誤提示
            ShowMessage(E.Message);
        End;
      end;
    end
    else
      Application.MessageBox('供應商信息不能為空.','提示',64);
  end
  else
    Application.MessageBox('當前沒有可修改的數據.','提示',64);
end;
//處理刪除按鈕的單擊事件
procedure Tf_providerinfo.DeleteClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then  //如果當前有可刪除的數據
  begin
    //提示是否刪除數據
    if Application.MessageBox(Pchar('確實要刪除供應商名稱為: ' + Trim(t_data.Query1.FieldByName('providername').AsString)+' 的供應商信息嗎?'),'提示',mb_YesNo)= ID_Yes then
    begin
      Try
        t_data.Query1.Delete;
        Cancel.Click;
      Except
        On E: Exception do  //如果產生異常則顯示錯誤提示
          ShowMessage(E.Message);
      End;
    end
  end
  else
    Application.MessageBox('當前沒有可刪除的信息.','提示',64);
end;
procedure Tf_providerinfo.QueryClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then //是否有可查詢的信息
  begin
    With t_data.Query1 do
    begin
      CLose;
      SQL.Clear;
      SQL.Add('select * from tb_providerinfo where ');
      if Field.ItemIndex = 0 then
      begin
        SQL.Add('providername Like :Value');
        Parameters.ParamByName('Value').Value := '%'+Trim(Value.Text)+'%';
      end
      else
      begin
        if Field.ItemIndex = 1 then
          SQL.Add('nameshort ')
        else
          SQL.Add('principal ');
        SQL.Add(' = :Value');
        Parameters.ParamByName('value').Value := Trim(Value.Text);
      end;
      Open;
    end;
    if t_data.Query1.RecordCount<1 then
    begin
      Cancel.Click;
      Application.MessageBox('沒有找到符合條件的記錄.','提示',64);
    end;
  end
  else
    Application.MessageBox('當前沒有可查詢的數據.','提示',64);
end;
//雙擊表格,將當前記錄信息顯示在編輯框中
procedure Tf_providerinfo.DBGrid1DblClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then
    Editvalue;
end;
//防止在電話號碼中輸入非法字符
procedure Tf_providerinfo.PhoneKeyPress(Sender: TObject; var Key: Char);
begin
  inherited;
  if Not(key in ['0'..'9','-',#8]) then
    Key := #0;
end;

end.
?? 文件大小 5665 K
?? 上傳用戶 jccg1000146752
?? 所屬分類數據庫系統
??? 相關標簽

#物流管理系統 #典型 #數據庫 #應用程序
?? 快捷鍵說明

復制代碼 Ctrl + C
搜索代碼 Ctrl + F
全屏模式 F11
切換主題 Ctrl + Shift + D
顯示快捷鍵 ?
增大字號 Ctrl + =
減小字號 Ctrl + -
亚洲欧美第一页_禁久久精品乱码_粉嫩av一区二区三区免费野_久草精品视频

?? providerinfo.pas

?? 快捷鍵說明
