//////////利用8051單片機串行口串并轉換輸出程序/////// 
//利用8051串行口，和并行輸出串行移位寄存器74LS164///
//擴展一位數碼顯示在數碼顯示器上循環顯示0-9這10個數字。
/////////////////晶振頻率為11.0592MHZ////////////////
////////////////////4C00為50ms定時常數///////////////
                             ORG   0000H
                             LJMP START
                             ORG   000BH        ;定時器0中斷程序入口地址
                             AJMP INTT0
                             ORG   0040H
START:
                             MOV SP,#60H
                             MOV TMOD,#01H        ;定時器0方式 1
                             MOV TL0,#00H         ;延時 50mS 的常數
                             MOV TH0,#4CH
                             MOV R0,#0
                             MOV R1,#20
                             MOV SCON,#00H       ;置串口工作方式 0
                             CLR TI
                             CLR  RI
                             SETB TR0               ;開中斷
                             SETB ET0
                             SETB EA
                             SJMP $
INTT0:                                        ;定時器0中斷子程序
                             PUSH ACC                 ;保護現場
                             PUSH PSW
                             CLR  ET0                ;關定時器0中斷
                             CLR  TR0
                             MOV  TL0,#00H        ;延時 50mS 的常數
                             MOV  TH0,#4CH        
                             DJNZ R1,EXIT
                             MOV  R1,#20              ;延時一秒的常數
                             MOV  DPTR,#DATAb          ;置表格基址
                             MOV  A,R0                 ;置表格偏移量
                             MOVC A,@A+DPTR           ;讀表格數據
                             CLR  TI
                             MOV  SBUF,A               ;串行發送數據
                             INC  R0
                             CJNE R0,#0AH,EXIT ;判斷是否到表尾
                             MOV  R0,#00H              ;調整表格偏移量
EXIT:
                             SETB TR0
                             SETB ET0                 ;開定時器0中斷
                             POP  PSW
                             POP  ACC                 ;恢復現場
                             RETI
DATAb:                                          ;數碼管顯示常數表
                             DB 03H,9FH,25H,0DH,99H,49H,41H,1FH,01H,09H                        ;0 1 2 3 4 5 6 7 8 9
                             END