;******************************************************************
;/* 這是DS18B20的匯編程序,  文件名DS18B203.ASM                    */
;/* 功能：本程序主要是讀出單個DS18B20芯片轉換后的溫度值，并把它轉 */
;/*    換成十六進制碼，實際范圍－55℃～125℃，十六進制碼的表示范  */
;/*    圍是（37H~7DH）。單片機的P1.0 接DS18B20 的BQ。             */
;/*    FLAG1:標志位,為"1"時表示檢測到DS18B20;FLAG2:標志位,        */
;/*    為"1"時表示檢測到的溫度值為負值，為"0"時表示檢測到的溫度   */
;/*    值為正值；DQ:DS18B20的數據總線接腳 ;                       */
;/*    TEMPER_NUM:保存讀出的溫度數據。 本程序僅適合單個DS18B20    */
;/*    和51單片機的連接,晶振為12MHZ左右。                         */
;******************************************************************
TEMPER_L        EQU    36H
TEMPER_H        EQU    35H
TEMPER_NUM      EQU    33H
FLAG1           EQU    0D5H
FLAG2           EQU    00H
DQ              EQU    P1.0
SkipDs18b20	    EQU    0CCH
StartDs18b20	  EQU    44H
ReadDs		      EQU    0BEH

            ORG 0000H
            SJMP MAIN
            ORG 0040H
 MAIN:      MOV SP,#60H
            CLR EA
            CLR  FLAG2        ;清負號標志位FLAG2
            LCALL RE_CONFIG   ;重新寫DS18B20暫存存儲器設定值
            LCALL GET_TEMPER  ;讀出轉換后的溫度值
            ;將從DS18B20中讀出的溫度數據轉換成單字節值（-55~125℃）
            LCALL TEMPER_COV
            LJMP $


;讀出轉換后的溫度值
GET_TEMPER:
	      SETB  DQ                  ; 定時入口
   	    LCALL InitDs18b20
        JB   FLAG1,S22
	      RET
 S22:   LCALL Delay64uS
	      MOV A,#SkipDs18b20        ; 跳過ROM匹配-0CC
        LCALL WriteByteDs1820
        MOV  A,#StartDs18b20      ; 發出溫度轉換命令
        LCALL WriteByteDs1820
        LCALL DELAY1s
	      LCALL InitDs18b20
        JB   FLAG1,ABC
	    RET
 ABC:   LCALL Delay64uS
        MOV  A,#SkipDs18b20        ; 跳過ROM匹配
        LCALL WriteByteDs1820
        MOV  A,#ReadDs             ; 發出讀溫度命令
        LCALL WriteByteDs1820
        LCALL ReadDs18b20           ;READ_1820
        RET
;讀DS18B20的程序,從DS18B20中讀出一個字節的數據
ReadByteDs1820:
       MOV    R2,#8
RE1:
       CLR    C
       SETB    DQ
       NOP
       NOP
       CLR    DQ
       NOP
       NOP
       NOP
       SETB    DQ
       MOV    R3,#7
       DJNZ    R3,$
       MOV    C,DQ
       MOV    R3,#23
       DJNZ    R3,$
       RRC    A
       DJNZ    R2,RE1
       RET
;寫DS18B20的程序
WriteByteDs1820:
       MOV    R2,#8
       CLR    C
WR1:
       CLR    DQ
       MOV    R3,#6
       DJNZ    R3,$
       RRC    A
       MOV    DQ,C
       MOV    R3,#23
       DJNZ    R3,$
       SETB    DQ
       NOP
       DJNZ    R2,WR1
       SETB    DQ
       RET
;讀DS18B20的程序,從DS18B20中讀出兩個字節的溫度數據
ReadDs18b20:
	      LCALL ReadByteDs1820
       	MOV  TEMPER_L ,A
	      LCALL ReadByteDs1820
       	MOV  TEMPER_H,A
        RET
;重新寫DS18B20暫存存儲器設定值
RE_CONFIG:
        JB FLAG1,RE_CONFIG1  ; 若DS18B20存在,轉RE_CONFIG1
        RET
RE_CONFIG1:
        MOV    A,#0CCH        ; 發SKIP ROM命令
        LCALL    WriteByteDs1820
        MOV    A,#4EH        ; 發寫暫存存儲器命令
        LCALL    WriteByteDs1820
        MOV    A,#00H        ; TH(報警上限)中寫入00H
        ;LCALL    WriteByteDs1820
        MOV    A,#00H        ; TL(報警下限)中寫入00H
        ;LCALL    WriteByteDs1820
        MOV    A,#7FH        ; 選擇12位溫度分辨率
        LCALL    WriteByteDs1820
        RET
;延時子程序
Delay500uS:
        MOV   R6,#00H
        DJNZ  R6,$
        RET
Delay64uS:
	      MOV   R6,#20H
        DJNZ  R6,$
        RET
Delay1S:
	     MOV B,#130
Dela11:
	     PUSH B
	     POP  B
	     DJNZ B,Dela11
	     RET
;DS18B20初始化程序
InitDs18b20:
        CLR    DQ
        MOV    R7,#80h
        DJNZ    R7,$       ; 延時
        SETB    DQ
        MOV    R7,#25h
        DJNZ    R7,$
        SETB    FLAG1      ; 置標志位,表示DS1820存在
        JNB    DQ,TSR5
        CLR    FLAG1       ; 清標志位,表示DS1820不存在
        LJMP    TSR7
TSR5:
        MOV    R7,#06BH    ;200US
        DJNZ   R7,$        ; 延時
TSR7:
        SETB    DQ
        RET

; 將從DS18B20中讀出的溫度數據進行轉換
TEMPER_COV:
    MOV    A,TEMPER_H
    SUBB    A,#0F8H
    JC      TEM0              ; 看溫度值是否為負？不是，轉
    SETB  FLAG2               ; 是，置標志位FLAG2,
    MOV    A,TEMPER_H
    CPL A
    MOV    TEMPER_H,A
    MOV    A,TEMPER_L
    CPL A
    INC A
    MOV    TEMPER_L,A
TEM0:
    MOV    A,#0F0H
    ANL    A,TEMPER_L        ; 舍去溫度低位中小數點后的四位溫度數值
    SWAP    A
    MOV    TEMPER_NUM,A
    MOV    A,TEMPER_L
    JNB    ACC.3,TEMPER_COV1 ; 四舍五入去溫度值
    INC    TEMPER_NUM
TEMPER_COV1:
    MOV    A,TEMPER_H
    ANL    A,#07H
    SWAP    A
    ORL    A,TEMPER_NUM
    MOV    TEMPER_NUM,A      ; 保存變換后的溫度數據
    RET
    END