VERSION 5.00
Begin VB.Form frmUser 
   BorderStyle     =   3  'Fixed Dialog
   Caption         =   "管理員信息"
   ClientHeight    =   2775
   ClientLeft      =   2760
   ClientTop       =   3750
   ClientWidth     =   5235
   LinkTopic       =   "Form1"
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   2775
   ScaleWidth      =   5235
   ShowInTaskbar   =   0   'False
   Begin VB.CommandButton OKButton 
      Caption         =   "確定"
      Height          =   330
      Left            =   2280
      TabIndex        =   4
      Top             =   2280
      Width           =   1215
   End
   Begin VB.CommandButton CancelButton 
      Caption         =   "取消"
      Height          =   330
      Left            =   3720
      TabIndex        =   5
      Top             =   2280
      Width           =   1215
   End
   Begin VB.Frame fraMerchType 
      Caption         =   "管理員信息"
      Height          =   1815
      Left            =   240
      TabIndex        =   0
      Top             =   240
      Width           =   4455
      Begin VB.TextBox txtConfirmPwd 
         Height          =   375
         IMEMode         =   3  'DISABLE
         Left            =   1320
         MaxLength       =   20
         PasswordChar    =   "*"
         TabIndex        =   3
         Text            =   "txtRemark"
         Top             =   1200
         Width           =   2535
      End
      Begin VB.TextBox txtPwd 
         Height          =   375
         IMEMode         =   3  'DISABLE
         Left            =   1320
         MaxLength       =   20
         PasswordChar    =   "*"
         TabIndex        =   2
         Text            =   "txtRemark"
         Top             =   731
         Width           =   2535
      End
      Begin VB.TextBox txtName 
         Height          =   375
         Left            =   1320
         MaxLength       =   18
         TabIndex        =   1
         Text            =   "txtName"
         Top             =   263
         Width           =   2535
      End
      Begin VB.Label Label3 
         AutoSize        =   -1  'True
         Caption         =   "確認密碼"
         Height          =   180
         Left            =   360
         TabIndex        =   8
         Top             =   1320
         Width           =   720
      End
      Begin VB.Label Label1 
         AutoSize        =   -1  'True
         Caption         =   "用戶名"
         Height          =   180
         Left            =   360
         TabIndex        =   7
         Top             =   360
         Width           =   540
      End
      Begin VB.Label Label2 
         AutoSize        =   -1  'True
         Caption         =   "密碼"
         Height          =   180
         Left            =   360
         TabIndex        =   6
         Top             =   840
         Width           =   360
      End
   End
End
Attribute VB_Name = "frmUser"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False

Option Explicit
Private OK As Boolean             '確定用戶按了OK還是CANCEL按鈕
Private m_obj As clsAdmin         '數據對象，用來存儲用戶輸入數據
Public m_ViewType As gxcViewType  '顯示狀態，指添加還是修改

'根據是“新增”還是修改，確定顯示內容
Private Sub SetStatus()
  
  '設置控件默認值
  Call SetDefaultValue
  
  txtName.Locked = True
  
  '設置狀態
  Select Case m_ViewType
  Case vtadd    '添加
    txtName.Locked = False
    CancelButton.Visible = True
    OKButton.Caption = "確定"
  Case vtModify '修改
    CancelButton.Visible = True
    OKButton.Caption = "保存"
  Case vtInfo   '查看
    CancelButton.Visible = False
    OKButton.Caption = "關閉"

  End Select

End Sub

'打開對話框，并傳出用戶輸入數據
Public Function ShowDlg(ByRef obj As Object, _
                        ByVal eViewType As gxcViewType) As Boolean
  '保存數據
  Set m_obj = obj         '用戶輸入數據存放于此對象中
  m_ViewType = eViewType  '對話框狀態
  
  '根據新增、編輯或查看設置顯示內容
  SetStatus
  
  '顯示對話框
  OK = False
  Me.Show vbModal
  If OK = False Then
    ShowDlg = False
    Exit Function
  End If
  
  '保存數據
  Set obj = m_obj
  
  '返回并釋放對話框
  ShowDlg = True
  Unload Me
  
End Function

'設置控件默認值
Private Sub SetDefaultValue()
  Dim ctl As Control
  Dim i As Integer
  
 
 '如果是新增，則清空所有文本框
 '此處判斷 m_obj為空與判斷m_ViewType = vtAdd等效，但更安全
  If m_obj Is Nothing Then
    For Each ctl In Controls
      If TypeOf ctl Is TextBox Then
        ctl.Text = ""
      End If
    Next
  Else  '用傳入對象的值更新數據
    With m_obj
      txtName.Text = .Account
      txtPwd.Text = .Pwd
      txtConfirmPwd.Text = .Pwd
    End With
  End If
  
End Sub

'檢查輸入有效性
Private Function CheckValid() As Boolean
  If txtName.Text = "" _
    Or txtPwd.Text = "" _
    Or txtConfirmPwd.Text = "" Then
    MsgBox "請填寫完畢以上各項內容"
    CheckValid = False
    Exit Function
  End If
  If txtConfirmPwd.Text <> txtPwd Then
    MsgBox "兩次密碼輸入不一致"
    CheckValid = False
    Exit Function
  End If

  CheckValid = True
  
End Function

'保存數據
Private Sub SaveValue()
  '給“成員變量”對象賦值
  With m_obj
    '注意以下利用RealString函數替換去除輸入中的單引號
    .Account = RealString(txtName.Text)
    .Pwd = RealString(txtPwd.Text)
  End With

End Sub

'取消按鈕
Private Sub CancelButton_Click()
  Me.Hide
End Sub


'確定按鈕
Private Sub OKButton_Click()
  OK = True
  
  '檢測輸入有效性
  If Not CheckValid Then Exit Sub
  
  '如果是新增狀態，則初始化一個數據對象
  If m_ViewType = vtadd Then Set m_obj = New clsAdmin
  
  '保存用戶輸入
  SaveValue
  Me.Hide
  
End Sub