VERSION 5.00
Begin VB.Form frmProvider 
   BorderStyle     =   3  'Fixed Dialog
   Caption         =   "供貨商信息"
   ClientHeight    =   3660
   ClientLeft      =   2760
   ClientTop       =   3750
   ClientWidth     =   6510
   LinkTopic       =   "Form1"
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   3660
   ScaleWidth      =   6510
   ShowInTaskbar   =   0   'False
   Begin VB.Frame fraMerchType 
      Caption         =   "供貨商信息"
      Height          =   2655
      Left            =   240
      TabIndex        =   5
      Top             =   240
      Width           =   6015
      Begin VB.TextBox txtRemark 
         Height          =   735
         Left            =   1200
         MultiLine       =   -1  'True
         TabIndex        =   2
         Text            =   "frmProvider.frx":0000
         Top             =   1680
         Width           =   4695
      End
      Begin VB.TextBox txtIntro 
         Height          =   735
         Left            =   1200
         MultiLine       =   -1  'True
         TabIndex        =   1
         Text            =   "frmProvider.frx":000A
         Top             =   791
         Width           =   4695
      End
      Begin VB.TextBox txtName 
         Height          =   375
         Left            =   1200
         MaxLength       =   18
         TabIndex        =   0
         Text            =   "txtName"
         Top             =   263
         Width           =   2535
      End
      Begin VB.Label Label3 
         AutoSize        =   -1  'True
         Caption         =   "備注"
         Height          =   180
         Left            =   360
         TabIndex        =   8
         Top             =   1680
         Width           =   360
      End
      Begin VB.Label Label1 
         AutoSize        =   -1  'True
         Caption         =   "廠商名"
         Height          =   180
         Left            =   360
         TabIndex        =   7
         Top             =   360
         Width           =   540
      End
      Begin VB.Label Label2 
         AutoSize        =   -1  'True
         Caption         =   "廠商信息"
         Height          =   180
         Left            =   360
         TabIndex        =   6
         Top             =   840
         Width           =   720
      End
   End
   Begin VB.CommandButton OKButton 
      Caption         =   "確定"
      Height          =   330
      Left            =   3360
      TabIndex        =   3
      Top             =   3120
      Width           =   1215
   End
   Begin VB.CommandButton CancelButton 
      Caption         =   "取消"
      Height          =   330
      Left            =   4800
      TabIndex        =   4
      Top             =   3120
      Width           =   1215
   End
End
Attribute VB_Name = "frmProvider"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False

Option Explicit
Private OK As Boolean             '確定用戶按了OK還是CANCEL按鈕
Private m_obj As clsProvider           '數據對象，用來存儲用戶輸入數據
Public m_ViewType As gxcViewType  '顯示狀態，指添加還是修改

'根據是“新增”還是修改，確定顯示內容
Private Sub SetStatus()
  
  '設置控件默認值
  Call SetDefaultValue
  
  '設置狀態
  Select Case m_ViewType
  Case vtadd    '添加
    CancelButton.Visible = True
    OKButton.Caption = "確定"
  Case vtModify '修改
    CancelButton.Visible = True
    OKButton.Caption = "保存"
  Case vtInfo   '查看
    CancelButton.Visible = False
    OKButton.Caption = "關閉"

  End Select

End Sub

'打開對話框，并傳出用戶輸入數據
Public Function ShowDlg(ByRef obj As Object, _
                        ByVal eViewType As gxcViewType) As Boolean
  '保存數據
  Set m_obj = obj         '用戶輸入數據存放于此對象中
  m_ViewType = eViewType  '對話框狀態
  
  '根據新增、編輯或查看設置顯示內容
  SetStatus
  
  '顯示對話框
  OK = False
  Me.Show vbModal
  If OK = False Then
    ShowDlg = False
    Exit Function
  End If
  
  '保存數據
  Set obj = m_obj
  
  '返回并釋放對話框
  ShowDlg = True
  Unload Me
  
End Function

'設置控件默認值
Private Sub SetDefaultValue()
  Dim ctl As Control
  Dim i As Integer
  
 
 '如果是新增，則清空所有文本框
 '此處判斷 m_obj為空與判斷m_ViewType = vtAdd等效，但更安全
  If m_obj Is Nothing Then
    For Each ctl In Controls
      If TypeOf ctl Is TextBox Then
        ctl.Text = ""
      End If
    Next
  Else  '用傳入對象的值更新數據
    With m_obj
      txtName.Text = .ProviderName
      txtIntro.Text = .Introduce
      txtRemark.Text = .Remark
      
    End With
  End If
  
End Sub

'檢查輸入有效性
Private Function CheckValid() As Boolean
  If txtName.Text = "" _
    Or txtIntro.Text = "" _
    Or txtRemark.Text = "" Then
    MsgBox "請填寫完畢以上各項內容"
    CheckValid = False
    Exit Function
  End If
  
  CheckValid = True
  
End Function

'保存數據
Private Sub SaveValue()
  '給“成員變量”對象賦值
  With m_obj
    '注意以下利用RealString函數替換去除輸入中的單引號
    .ProviderName = RealString(txtName.Text)
    .Introduce = RealString(txtIntro.Text)
    .Remark = RealString(txtRemark.Text)
  End With

End Sub

'取消按鈕
Private Sub CancelButton_Click()
  Unload Me
End Sub

'確定按鈕
Private Sub OKButton_Click()
  OK = True
  
  '檢測輸入有效性
  If Not CheckValid Then Exit Sub
  
  '如果是新增狀態，則初始化一個數據對象
  If m_ViewType = vtadd Then Set m_obj = New clsProvider
  
  '保存用戶輸入
  SaveValue
  Me.Hide
  
End Sub