End
   End
End
Attribute VB_Name = "C用戶管理"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Dim rs As ADODB.Recordset
Dim SQL As String
Dim msg As String
Dim index As Integer
Dim flag As String '判斷是新增加的記錄還是修改記錄
Private Sub Form_Load()
    Dim strItem As String
    '初始化下拉框
    CboSelect.AddItem "教師"
    CboSelect.AddItem "管理人員"
    CboSelect.ListIndex = 0
    Call LoadData '裝載用戶數(shù)據(jù)
End Sub
Private Sub LoadData()
    Dim strItem As String
    '得到用戶信息
    SQL = " select * from 用戶信息表 order by 用戶ID"
    Set rs = Nothing
    Set rs = SelectSQL(SQL, msg)
    ListUser.Clear
    If rs.RecordCount > 0 Then
        Do While (Not rs.EOF) And (Not rs.BOF)
            strItem = Trim(rs.Fields(0)) & ":" & Trim(rs.Fields(1))
            ListUser.AddItem (strItem)
            rs.MoveNext
        Loop
        rs.MoveFirst
        ListUser.ListIndex = 0
    Else
        MsgBox ("目前沒有用戶信息！")
        '控件可用性
        CmdAdd.Enabled = True: CmdModify.Enabled = False: CmdDelete.Enabled = False
        cmdCancel.Enabled = False: CmdSave.Enabled = False
        Exit Sub
    End If
    Call FixData '在文本框中顯示詳細(xì)信息
    '控件可用性
    CmdAdd.Enabled = True: CmdModify.Enabled = True: CmdDelete.Enabled = True
    cmdCancel.Enabled = False: CmdSave.Enabled = False
End Sub
Private Sub FixData()
    Dim UserID As String
    '顯示具體信息
    If ListUser.ListCount > 0 Then
        UserID = Left(Trim(ListUser.Text), 6)
    Else
        Exit Sub
    End If
    '查找數(shù)據(jù)
    rs.MoveFirst
    rs.Find ("用戶ID='" & UserID & "'")
    '顯示數(shù)據(jù)
    txtUserId.Text = Trim(rs.Fields("用戶ID"))
    txtName.Text = Trim(rs.Fields("用戶名稱"))
    txtPassword.Text = Trim(rs.Fields("密碼"))
    CboSelect.Text = Trim(rs.Fields("用戶類別"))
    txtPhone.Text = Trim(rs.Fields("電話"))
    txtEmail.Text = Trim(rs.Fields("郵箱"))
    '控件可用性
    CmdModify.Enabled = True: CmdDelete.Enabled = True: CmdAdd.Enabled = True
    CmdSave.Enabled = False: cmdCancel.Enabled = False
End Sub

Private Sub ControlActiveX(kind As String, flag As Boolean)
    '控制控件
    If kind = "Add" Or kind = "Delete" Or kind = "Save" Then
        txtUserId.Text = ""
        txtName.Text = ""
        txtPassword.Text = ""
        CboSelect.ListIndex = 0
        txtPhone.Text = ""
        txtEmail.Text = ""
    End If
    If kind = "Modify" Then
        txtUserId.Enabled = False
    Else
        txtUserId.Enabled = flag
    End If
    txtName.Enabled = flag
    txtPassword.Enabled = flag
    CboSelect.Enabled = flag
    txtPhone.Enabled = flag
    txtEmail.Enabled = flag
    ListUser.Enabled = Not flag
End Sub

Private Sub CboStu_Click()
    Call LoadData  '重新裝載數(shù)據(jù)
End Sub
Private Sub CmdAdd_Click()
    '可用性，清空數(shù)據(jù)
    Call ControlActiveX("Add", True)
    '設(shè)置標(biāo)志flag
    flag = "Add"
    '添加、修改、刪除按鈕不可用，取消、保存按鈕可用
    CmdAdd.Enabled = False: CmdModify.Enabled = False: CmdDelete.Enabled = False
    cmdCancel.Enabled = True: CmdSave.Enabled = True
End Sub
Private Sub CmdModify_Click()
    '修改操作
    If rs.RecordCount > 0 Then
        '可用性
        Call ControlActiveX("Modify", True)
        '設(shè)置標(biāo)志flag
        flag = "Modify"
        '添加、修改、刪除按鈕不可用，取消、保存按鈕可用
        cmdCancel.Enabled = True: CmdSave.Enabled = True
        CmdAdd.Enabled = False: CmdModify.Enabled = False: CmdDelete.Enabled = False
    Else
        MsgBox ("沒有可以修改的數(shù)據(jù)!")
    End If
End Sub
Private Sub CmdDelete_Click()
'刪除操作
    On Error GoTo ErrMsg
    If txtUserId.Text = "" Then
        MsgBox ("選擇需要刪除的用戶信息！")
        Exit Sub
    End If
    If rs.RecordCount > 0 Then
         msg = MsgBox("刪除該條記錄嗎?", vbYesNo)
         If msg = vbYes Then
            rs.Delete
            Call LoadData '重新裝載數(shù)據(jù)
            '清空文本框,重新設(shè)置下拉框
            Call ControlActiveX("Delete", False)
            '按鈕可用性處理
            CmdAdd.Enabled = True: CmdModify.Enabled = False: CmdDelete.Enabled = True
            CmdSave.Enabled = False: cmdCancel.Enabled = False
            MsgBox ("成功刪除的數(shù)據(jù)!")
         End If
     Else
         MsgBox ("沒有可刪除的數(shù)據(jù)!")
    End If
    Exit Sub
ErrMsg:
         MsgBox Err.Description, vbExclamation, "出錯"
End Sub
Private Sub cmdCancel_Click()
    '取消操作
    Call FixData '設(shè)置數(shù)據(jù)
    ListUser.Enabled = True
    '修改、刪除、添加按鈕可用,保存和取消按鈕不可用
    CmdModify.Enabled = True: CmdDelete.Enabled = True: CmdAdd.Enabled = True
    CmdSave.Enabled = False: cmdCancel.Enabled = False
End Sub
Private Function CheckData() As Boolean
    '檢查數(shù)據(jù)的合法性
    Dim rst As ADODB.Recordset
    '檢查非空性
    If (Trim(txtUserId.Text) = "") Then
        MsgBox ("用戶ID不能為空！")
        CheckData = False
        Exit Function
    ElseIf Len(Trim(txtUserId.Text)) <> 6 Then
        MsgBox ("用戶ID不是6位！")
        CheckData = False
        Exit Function
    End If
    '檢查唯一性
    SQL = " select 用戶ID from 用戶信息表 where 用戶ID='" & Trim(txtUserId.Text) & "'"
    Set rst = SelectSQL(SQL, msg)
    If flag = "Add" And rst.RecordCount > 0 Then
        MsgBox ("用戶ID，重復(fù)添加!")
        rst.Close
        CheckData = False
        Exit Function
    End If
    CheckData = True '合法
End Function
Private Sub setData()
    rs.Fields("用戶ID") = Trim(txtUserId.Text)
    rs.Fields("用戶名稱") = Trim(txtName.Text)
    rs.Fields("密碼") = Trim(txtPassword.Text)
    rs.Fields("用戶類別") = Trim(CboSelect.Text)
    rs.Fields("電話") = Trim(txtPhone.Text)
    rs.Fields("郵箱") = Trim(txtEmail.Text)
End Sub
Private Sub CmdSave_Click()
    On Error GoTo ErrMsg
    If Not CheckData Then Exit Sub '如果數(shù)據(jù)不合法退出
    If flag = "Modify" Then '如果是修改數(shù)據(jù)
        msg = MsgBox("您確實(shí)要修改這條數(shù)據(jù)嗎?", vbYesNo)
        If msg = vbYes Then
            Call setData '賦值
        Else
            Exit Sub
        End If
    ElseIf flag = "Add" Then '如果是添加新數(shù)據(jù)
        rs.AddNew
        Call setData
    End If
    '更新數(shù)據(jù)
    rs.Update
    Call LoadData '重新裝載數(shù)據(jù)
    '控件清空和可用性
    Call ControlActiveX("Save", False)
    CmdModify.Enabled = True: CmdDelete.Enabled = True: CmdAdd.Enabled = True
    CmdSave.Enabled = False: cmdCancel.Enabled = False
    If flag = "Add" Then
        MsgBox ("成功添加數(shù)據(jù)!")
    Else
        MsgBox ("成功更新數(shù)據(jù)!")
    End If
    Exit Sub
ErrMsg:
    MsgBox Err.Description, vbExclamation, "出錯"
End Sub
Private Sub CmdExit_Click()
'退出操作
    排課系統(tǒng).Enabled = True
    rs.Close
    Unload Me
End Sub

Private Sub Form_Unload(Cancel As Integer)
'退出操作
    排課系統(tǒng).Enabled = True
    Unload Me
End Sub
Private Sub ListUser_Click()
    Call FixData
End Sub