`timescale 1ns / 1ps
////////////////////////////////////////////////////////////////////////////////
// Company: 
// Engineer:
//
// Create Date:    
// Design Name:    
// Module Name:    
// Project Name:   
// Target Device:  
// Tool versions:  
// Description:
//
// Dependencies:
// 
// Revision:
// Revision 0.01 - File Created
// Additional Comments:
// 
////////////////////////////////////////////////////////////////////////////////
module vga_dis(
			clk,rst_n,
			hsync,vsync,
			vga_r,vga_g,vga_b
		);

input clk;		//50MHz
input rst_n;	//低電平復(fù)位
output hsync;	//行同步信號
output vsync;	//場同步信號
output vga_r;
output vga_g;
output vga_b;

//--------------------------------------------------
reg[10:0] x_cnt;	//行坐標(biāo)
reg[9:0] y_cnt;	//列坐標(biāo)

always @ (posedge clk or negedge rst_n)
	if(!rst_n) x_cnt <= 11'd0;
	else if(x_cnt == 11'd1039) x_cnt <= 11'd0;
	else x_cnt <= x_cnt+1'b1;

always @ (posedge clk or negedge rst_n)
	if(!rst_n) y_cnt <= 10'd0;
	else if(y_cnt == 10'd665) y_cnt <= 10'd0;
	else if(x_cnt == 11'd1039) y_cnt <= y_cnt+1'b1;

//--------------------------------------------------
wire valid;	//有效顯示區(qū)標(biāo)志

assign valid = (x_cnt >= 11'd187) && (x_cnt < 11'd987) 
					&& (y_cnt >= 10'd31) && (y_cnt < 10'd631); 

wire[9:0] xpos,ypos;	//有效顯示區(qū)坐標(biāo)

assign xpos = x_cnt-11'd187;
assign ypos = y_cnt-10'd31;

//--------------------------------------------------
reg hsync_r,vsync_r;	//同步信號產(chǎn)生

always @ (posedge clk or negedge rst_n)
	if(!rst_n) hsync_r <= 1'b1;
	else if(x_cnt == 11'd0) hsync_r <= 1'b0;	//產(chǎn)生hsync信號
	else if(x_cnt == 11'd120) hsync_r <= 1'b1;
 
always @ (posedge clk or negedge rst_n)
	if(!rst_n) vsync_r <= 1'b1;
	else if(y_cnt == 10'd0) vsync_r <= 1'b0;	//產(chǎn)生vsync信號
	else if(y_cnt == 10'd6) vsync_r <= 1'b1;

assign hsync = hsync_r;
assign vsync = vsync_r;

//--------------------------------------------------
	//顯示一個矩形框
wire a_dis,b_dis,c_dis,d_dis;	//矩形框顯示區(qū)域定位

assign a_dis = ( (xpos>=200) && (xpos<=220) ) 
				&&	( (ypos>=140) && (ypos<=460) );
				
assign b_dis = ( (xpos>=580) && (xpos<=600) )
				&& ( (ypos>=140) && (ypos<=460) );

assign c_dis = ( (xpos>=220) && (xpos<=580) ) 
				&&	( (ypos>140)  && (ypos<=160) );
				
assign d_dis = ( (xpos>=220) && (xpos<=580) )
				&& ( (ypos>=440) && (ypos<=460) );

	//顯示一個小矩形
wire e_rdy;	//矩形的顯示有效矩形區(qū)域

assign e_rdy = ( (xpos>=385) && (xpos<=415) )
				&&	( (ypos>=285) && (ypos<=315) );

//-------------------------------------------------- 
	//r,g,b控制液晶屏顏色顯示，背景顯示藍(lán)色，矩形框顯示紅藍(lán)色
assign vga_r = valid ? e_rdy : 1'b0;
assign vga_g = valid ?  (a_dis | b_dis | c_dis | d_dis) : 1'b0;
assign vga_b = valid ? ~(a_dis | b_dis | c_dis | d_dis) : 1'b0;	  

endmodule