?? 6t.asm
字號:
; *************************************
; * （SEND.ASM） *
; * 十五路遙控發送控制器 *
; * 2001.7.18 *
; *************************************
;
;**********************************************************************
;* *
;* KEYX0 P1.0 1 40 VCC *
;* KEYX1 P1.1 2 39 P0.0 KEYY0 *
;* KEYX2 P1.2 3 38 P0.1 KEYY1 *
;* KEYX3 P1.3 4 37 P0.2 KEYY2 *
;* P1.4 5 36 P0.3 KEYY3 *
;* P1.5 6 35 P0.4 KEYY4 *
;* P1.6 7 34 P0.5 KEYY5 *
;* P1.7 8 33 P0.6 KEYY6 *
;* RST 9 32 P0.7 KEYY7 *
;* P3.0 10 MCS-51 31 EA VDD *
;* P3.1 11 30 ALE *
;* P3.2 12 29 PSEN *
;* P3.3 13 28 P2.7 *
;* P3.4 14 27 P2.6 *
;* REMOTEOUT T1 P3.5 15 26 P2.5 *
;* P3.6 16 25 P2.4 *
;* P3.7 17 24 P2.3 *
;* XTAL2 18 23 P2.2 *
;* XTAL1 19 22 P2.1 *
;* VSS 20 21 P2.0 *
;* *
;* *
;**********************************************************************
;
;
;
;偽定義
KEYX0 EQU P1.0 ;P1.0 -- P1.3位鍵盤行掃描
KEYX1 EQU P1.1 ;本系統采用4 * 8 鍵盤陣列
KEYX2 EQU P1.2
KEYX3 EQU P1.3
KEYY EQU P0 ;P0 口鍵盤列掃描
;
;
;
;
;*************************************
;* *
;* 主程序和中斷程序入口 *
;* *
;*************************************
ORG 0000H ;程序執行開始地址
AJMP START ;跳至START執行
ORG 0003H ;外中斷0中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 000BH ;定時器T0中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 0013H ;外中斷1中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 001BH ;定時器T1中斷入口地址
LJMP INTT1 ;跳至INTT1中斷服務程序
ORG 0023H ;串行口中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 002BH ;定時器T2中斷入口地址
RETI ;中斷返回（不開中斷）
;
;*************************************
;* *
;* 初 始 化 程 序 *
;* *
;*************************************
CLEARMEMIO: CLR A ;A清0
DEC A ;A為#0FFH
MOV P0,A ;P0-P3口置1
MOV P1,A ;
MOV P2,A ;
MOV P3,A ;
CLR P3.5 ;關遙控輸出
CLEARMEM:
MOV IE,#00H ;關所有中斷
MOV IP,#01H ;設優先級
MOV TMOD,#22H ;8位自動重裝初值模式
MOV TH1,#0F3H ;定時為13微秒初值
MOV TL1,#0F3H ;
SETB EA ;開總中斷允許
RET ;返回
;
;
;
;
;*************************************
;* *
;* 主 程 序 *
;* *
;*************************************
START: MOV SP,#70H ;設堆棧基址為70H
LCALL CLEARMEMIO ;調用初始化子程序
;
MAIN: LCALL KEYWORK ;主體程序。調用查鍵子程序
LJMP MAIN ;轉MAIN循環
NOP ;PC值出錯處理
NOP
NOP
LJMP START ;重新初始化
;
;*************************************
;* *
;* T1中斷服務程序 *
;* *
;*************************************
INTT1: CPL P3.5 ;40kHZ紅外線遙控信號產生
RETI ;中斷返回
;
;
;*************************************
;* *
;* 鍵盤工作子程序(4 * 8 陣列) *
;* 出口為各鍵工作程序入口 *
;*************************************
KEYWORK: MOV KEYY,#0FFH ;置列線輸入狀態
CLR KEYX0 ;行線(P1口)全置0
CLR KEYX1
CLR KEYX2
CLR KEYX3
MOV A,KEYY ;讀入P0口值
MOV B,A ;KEYY口值暫存B中
CJNE A,#0FFH,KEYHIT ;不等于#0FFH，轉KEYHIT（有鍵按下）
KEYOUT: RET ;沒有鍵按下返回
;
KEYHIT: LCALL DL10MS ;延時去抖動
MOV A,KEYY ;再讀入P0口值至A
CJNE A,B,KEYOUT ;A不等于B(是干擾)，子程序返回
SETB KEYX1 ;有鍵按下，找鍵號開始，查0行
SETB KEYX2
SETB KEYX3
MOV A,KEYY ;讀入P0口值
CJNE A,#0FFH,KEYVAL0 ;P0不等于#0FFH，按下鍵在第0行
SETB KEYX0 ;不在第0行，開始查1行
CLR KEYX1
MOV A,KEYY ;讀入P0口值
CJNE A,#0FFH,KEYVAL1 ;P0口不等于#0FFH，按下鍵在第1行
SETB KEYX1 ;不在第1行，開始查2行
CLR KEYX2
MOV A,KEYY ;讀入P0口值
CJNE A,#0FFH,KEYVAL2 ;P0口不等于#0FFH，按下鍵在第2行
SETB KEYX2 ;不在第2行，開始查3行
CLR KEYX3
MOV A,KEYY ;讀入P0口值
CJNE A,#0FFH,KEYVAL3 ;P0口不等于#0FFH，按下鍵在第3行
LJMP KEYOUT ;不在第3行，子程序返回
;
KEYVAL0: MOV R2,#00H ;按下鍵在第0行，R2賦行號初值0
LJMP KEYVAL4 ;跳到KEYVAL4
;
KEYVAL1: MOV R2,#08H ;按下鍵在第1行，R2賦行號初值8
LJMP KEYVAL4 ;跳到KEYVAL4
;
KEYVAL2: MOV R2,#10H ;按下鍵在第2行，R2賦行號初值16
LJMP KEYVAL4 ;跳到KEYVAL4
;
KEYVAL3: MOV R2,#18H ;按下鍵在第3行，R2賦行號初值24
LJMP KEYVAL4 ;跳到KEYVAL4
;
KEYVAL4: MOV DPTR,#KEYVALTAB ; 鍵值翻譯成連續數字
MOV B,A ;P0口值暫存B內
CLR A ;清A
MOV R0,A ;清R0
KEYVAL5: MOV A,R0 ;查列號開始，R0數據放入A
SUBB A,#08H ;A中數減8
JNC KEYOUT ;借位C為0，查表出錯，返回
MOV A,R0 ;查表次數小于8，繼續查，
MOVC A,@A+DPTR ;查列號表
INC R0 ;R0加1
CJNE A,B,KEYVAL5 ;查得值和P0口值不等，轉KEYVAL5再查
DEC R0 ;查得值和P0口值相等，R0減1
MOV A,R0 ;放入A（R0中數值即為列號值）
ADD A,R2 ; 與行號初值相加成為鍵號值（0-31）
MOV B,A ;鍵號乘3處理用于JMP散轉指令
RL A ;鍵號乘3處理用于JMP散轉指令
ADD A,B ;鍵號乘3處理用于JMP散轉指令
MOV DPTR,#KEYFUNTAB ; 取散轉功能程序（表）首址
JMP @A+DPTR ;散轉至對應功能程序標號
KEYFUNTAB: LJMP KEYFUN00 ;跳到鍵號0對應功能程序標號
LJMP KEYFUN01 ;跳到鍵號1對應功能程序標號
LJMP KEYFUN02 ;跳到鍵號2對應功能程序標號
LJMP KEYFUN03 ;跳到鍵號3對應功能程序標號
LJMP KEYFUN04 ;跳到鍵號4對應功能程序標號
LJMP KEYFUN05 ;跳到鍵號5對應功能程序標號
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -