;矩陣按鍵/動態掃描移位顯示程序，開機顯示000000，按鍵后顯示鍵名，并移位 
;***************************************************************************
;*  sxj1974@163.com		     (51c51 test web)     www.8951.com     *
;*  Create by :石學軍      www.51c51.com 更多例程請登陸網站        	   *
;***************************************************************************

org	0000h
ajmp	main
org	0030h
main:
	mov	dptr,#tab                           ;將表頭位置送入DPTR
	mov   30h,#00h                          ;將30H個位顯示緩沖單元清零
	mov   31h,#00h                          ;將31H十位顯示緩沖單元清零
	mov   32h,#00h                          ;將32H百位顯示緩沖單元清零
	mov   33h,#00h                          ;將33H千位顯示緩沖單元清零
    mov   34h,#00h                           	;將33H萬位顯示緩沖單元清零
    mov 35h,#00h                             	;將33H十萬位顯示緩沖單元清零
loop:
	lcall display		                    ;調用顯示程序
	lcall	key		                    ;調用鍵盤描程序
	cpl	a                                   ;將A的值取反
jz		loop                                ;無鍵鍵按下則返回
mov 35h,34h
mov 34h,33h

	mov	33h,32h                             ;將32H顯示單元的內容送入33H
	mov 	32h,31h                             ;將31H顯示單元的內容送入32H
	mov 	31h,30h                             ;將30H單元的內容送入31H
	mov	a,36h                               ;將鍵值送入ACC
	mov	30h,a                               ;將ACC的值送入30H
	ljmp	loop                            ;返回主程序循環
display:
	mov  p2,#0ffh               		;將P2口置高電平
	mov r7,#100                 		;軟件計數器賦值

dd1:    mov a,30h                   		;將顯示緩沖區30H中的值送入ACC
	movc a,@a+dptr              		;查表取要顯示的數并把查表的結果送入ACC
	mov p0,a                    		;將要顯示的數送入P0口
	clr p2.6                    		;開個位顯示單元
	lcall delay100us            		;延時100US
	setb p2.6                   		;關個位顯示單

	mov a,31h                   		;將顯示緩沖區別31H中的值送入A
	movc a,@a+dptr              		;查表取要顯示的數并把查表的結果送入ACC
	mov p0,a                    		;將要顯示的數送入P0口
	clr p2.5                    		;開十位顯示單元
	lcall delay100us            		;延時100US
	setb p2.5                   		;關十位顯示單元

	mov a,32h                   		;將顯示緩沖區32H中的值送入ACC
	movc a,@a+dptr              		;查表取要顯示的數并把查表的結果送入ACC
	mov p0,a                    		;將要顯示的數送入P0口
	clr p2.4                    		;開百位顯示單元
	lcall delay100us            		;延時100US
	setb p2.4                   		;關百位顯示單元

	mov a,33h                   		;將顯示緩沖區33H中的值送入ACC
	movc a,@a+dptr              		;查表取要顯示的數并把查表的結果送入ACC
	mov p0,a                    		;將要顯示的數送入P0口
	clr p2.3                    		;開千位顯示單元
	lcall delay100us            		;延時100US
	setb p2.3                   		;關千位顯示單元
 
    mov a,34h                   		;將顯示緩沖區33H中的值送入ACC
	movc a,@a+dptr              		;查表取要顯示的數并把查表的結果送入ACC
	mov p0,a                    		;將要顯示的數送入P0口
	clr p2.2                    		;開萬位顯示單元
	lcall delay100us            		;延時100US
	setb p2.2                   		;關萬位顯示單元
 
    mov a,35h                   		;將顯示緩沖區33H中的值送入ACC
	movc a,@a+dptr              		;查表取要顯示的數并把查表的結果送入ACC
	mov p0,a                    		;將要顯示的數送入P0口
	clr p2.1                    		;開十萬位顯示單元
	lcall delay100us            		;延時100US
	setb p2.1                   		;關十萬位顯示單元
	djnz r7,dd1                 		;R7不等于0返回至DD1處
	ret                         		;R7等于0子程序返回

KEY: LCALL KS				            ;調用檢測按鍵子程序
     JNZ K1                             	;有鍵按下繼續
	  ljmp	key_exit                    	;無鍵按下退出KEY子程序
K1:  LCALL delay4ms                     	;返回繼續檢測有無按鍵按下
     LCALL delay4ms
     LCALL KS                                   ;有鍵按下繼續延時去抖動
     JNZ K2                                     ;再一次調用檢測按鍵程序
	  ljmp	key_exit                        ;無鍵按下退出KEY子程序
K2:	MOV R2,#0EFH                            ;將掃描值送入 R2暫存
     MOV R4,#00H                         	;將第一列的列值00H送入R4暫存,R4用于存放列
K3:	MOV P1,R2                            ;將R2的值送入P1口
L6:	JB P1.0,L1                           ;P1.0等于1跳轉到L1
     MOV A,#00H                              ;將第一行的行值00H送入ACC
     AJMP LK                                 ;跳轉到鍵值處理程序
L1:	JB P1.1,L2                           ;P1.1等于1跳轉到L2
     MOV A,#04H                           ;將第二行的行值送入ACC
     AJMP LK                              ;跳轉到鍵值理程序進行鍵值處理
L2: JB P1.2,L3                            ;P1.2等于1跳轉到L3
     MOV A,#08H                           ;將第三行的行值送入ACC
     AJMP LK                              ;跳轉到鍵值處理程序
L3:	JB P1.3,NEXT                          ;P1.3等于1跳轉到NEXT處
     MOV A,#0cH                               ;將第四行的行值送入ACC
LK:	ADD A,R4                              ;行值與列值相加后的鍵值送入A
		mov	36h,a                 ;將A中的值送入34h暫存
K4:
		lcall display                 ;調用動態顯示子程序
     LCALL KS                                    
     JNZ K4                              ;按鍵沒有松開繼續返回檢測
     RET                                 ;按鍵松開返回

NEXT:
    INC  R4                             ;將列值加一
    MOV A,R2                            ;將R2的值送入A
    JNB ACC.7,key_exit                  ;掃描完成跳至KEY處進行下一回合的掃描
    RL A                                ;掃描未完成將A中的值右移一位進行下一列的掃
    MOV R2,A                            ;將ACC的值送入R2暫存
    AJMP K3                             ;跳轉到K3繼續
key_exit:
		mov a,#0ffh                     ;無鍵按下則將A賦成0FFH。
		ret

KS:	MOV P1,#0FH                         ;將P1口高四位置0低四位值1
     MOV A,P1                           ;讀P1口
     XRL A,#0FH                         ;將A中的值與A中的值相異或
     RET                                ;子程序返回
delay4ms:				                ;4ms延時程序
      MOV R5,#08H
L7:	MOV R6,#0FAH
L8:	DJNZ R6,L8
     DJNZ R5,L7
     RET

delay100us:                              ;100US延時程序
			mov r5,#50
			djnz	r5,$
			ret



tab:	db 28h,34h,28h,34h,0a9h,60h,20h,7ah,20h,21h,61h,74h,30h,62h,0a2h,7eh
end