;小喇叭的爬音演奏，即do，rui，mi，fa，so，la，xi，do
;30h=步進值，21h低8位 22h高8位
;***************************************************************************
;*  sxj1974@163.com		     (51c51 test web)     www.8951.com     *
;*  Create by :石學軍      www.51c51.com 更多例程請登陸網站        	   *
;***************************************************************************
	org	0000h
	ajmp	main
	org	000bh
	jmp	tim0
	org	0030h
main:					;主程序
	mov	tmod,#01h		;設定時方式
	mov	ie,#82h			;開中斷
start0:
	mov	30h,#00h		;
next:	mov	a,30h

	jnz	sing			;根據音調決定是否演奏.
 clr	tr0
	jmp	d1
sing:	dec	a
	mov	22h,a			;將音調存入22H.
	rl	a
	mov	dptr,#table1
	movc	a,@a+dptr	;根據音調決定定時器初值.
	mov	th0,a			;放入TH0
	mov	21h,a
	mov	a,22h
	rl	a
	inc	a
	movc	a,@a+dptr
	mov	tl0,a			;放入TL0
	mov	20h,a
    jz end0            ;如果到了00則停止發音
	setb	tr0			;啟動定時
d1:	call	delay
	inc	30h          ;取下一個碼
	jmp	next
end0:	clr	tr0
	jmp	start0   ;重新開始

tim0:					;定時器中斷服務程序
	push	acc
	push	psw
	mov	tl0,20h			;重賦初值.
	mov	th0,21h
	cpl	p3.3
	pop	psw
	pop	acc
	reti

delay:	mov	r7,#03h			;延時子程序 決定每個音的時間
d2:	mov	r4,#187
d3:	mov	r3,#248
	djnz	r3,$
	djnz	r4,d3
	djnz	r7,d2
	ret
table1:					;決定音調的定時初值.
	dw	64260,64400,64524,64580
	dw	64684,64777,64820,64898
	dw	64968,65030,65058,65110
	dw	65157,65178,65217,00
	end