/**
  * Project: 用以過場轉(zhuǎn)換的自定義效果 效果生成類
  * 原庫類為 com.oreilly.programmingflex.effects 此處引用略有修改
  * Author : dmh2002 Blog:http://dmh2002.com/
  * QQ:122054933 MSN:shangxinyu2002@msn.com 
  * Date : 2008.04.05 
  */   
package com.dmh2002.games.cardgame.effects {

	import mx.core.UIComponent;
	import mx.effects.Effect;
	import mx.effects.IEffectInstance;
	import mx.events.EffectEvent;
	
	public class SceneChangeEffect extends Effect
	{
		/** 定義屬性 */		
		private var _toX:Number;
		private var _toY:Number;
		private var _toWidth:Number;
		private var _toHeight:Number;
		private var _toComp:UIComponent;
		private var _formComp:UIComponent;
                
        /** get/set 存儲器 */
        public function set toX(value:Number):void 
        {
			_toX = value;
		}		
		public function set toY(value:Number):void 
		{
			_toY = value;
		}
		public function set toWidth(value:Number):void 
		{
			_toWidth = value;
		}
		public function set toHeight(value:Number):void 
		{
			_toHeight = value;
		}
		public function set toComp(value:UIComponent):void 
		{
			_toComp = value;
		}
		
		/** 構(gòu)造函數(shù) 
		 * 繼承Effect必須定義的方法
		 * 必須調(diào)用super()方法來調(diào)用父類的構(gòu)造函數(shù)
		 * 并且必須接收一個參數(shù)來指定目標對象
		 */
		public function SceneChangeEffect(newTarget:Object = null) {
			super(newTarget);
			instanceClass = SceneChangeEffectInstance;
		}
		
		/** initInstance()方法
		 * 繼承Effect必須定義的方法
		 * 將生成類的屬性轉(zhuǎn)到實例對象中，這個方法由
		 * 并且必須接收一個參數(shù)來指定目標對象Effect對象內(nèi)部調(diào)用，不在外部使用。
		 * 另外，覆蓋的函數(shù)體中必須執(zhí)行函數(shù):super.initInstance(instance);
		 */		
		override protected function initInstance(instance:IEffectInstance):void 
		{
			super.initInstance(instance);
            SceneChangeEffectInstance(instance).toX = _toX;
            SceneChangeEffectInstance(instance).toY = _toY;
            SceneChangeEffectInstance(instance).toWidth = _toWidth;
            SceneChangeEffectInstance(instance).toHeight = _toHeight;
            SceneChangeEffectInstance(instance).toComp = _toComp;    
		}
		
		/** getAffectedProperties()方法
		 * 繼承Effect必須定義的方法
		 * 返回一個字符串數(shù)組，包括目標對象被改變的屬性名。
		 * 如果沒有改變，則返回空數(shù)組
		 */	
		override public function getAffectedProperties():Array
		{
			return ["toX","toY","toWidth","toHeight"];
		}
	}
}