//============================================================
// 文件名稱：flash.asm     
// 實現功能: SPCE061 32K flash 的讀寫
// 維護記錄： 2003-6-9 V1.0
//============================================================



.INCLUDE hardware.inc

.DEFINE C_FLASH_SIZE			0x8000
.DEFINE C_FLASH_BLOCK_SIZE		0x100
.DEFINE C_FLASH_MATCH			0xAAAA
.DEFINE C_FLASH_PAGE_ERASE		0x5511		//擦除一頁
.DEFINE C_FLASH_MASS_ERASE		0x5522		//
.DEFINE C_FLASH_1WORD_PGM		0x5533		//寫一個字
.DEFINE C_FLASH_SEQUENT_PGM		0x5544		//寫多個字
.DEFINE C_FLASH_MAIN_BLOCK		0x5555		
.DEFINE C_FLASH_INFORM_BLOCK	0x5566		


.CODE
//============================================================================================
//語法：void F_FlashWrite1Word(int addr,int Value )
//描述：寫一個字到FLASH中
//參數：addr-被寫數據的存儲地址  Value-被寫數據
//返回：無
//===============================================================================================
.PUBLIC _F_FlashWrite1Word
.DEFINE  P_Flash_Ctrl  0x7555
_F_FlashWrite1Word:	 .proc 
	push bp to [sp]
	bp = sp+1
	r1 = C_FLASH_MATCH				//AAAA
	[P_Flash_Ctrl] = r1
	r1 = C_FLASH_1WORD_PGM			//5533
	[P_Flash_Ctrl] = r1
	r1 =  [bp+3]					//flash address
	r2 =  [bp+4]					//data
	[r1] = r2
	
	pop bp from [sp]
	retf
	.ENDP

//=============================================================================================
//語法：F_FlashWrite(int sector,int &num, int size)
//描述：順序寫多個字
//參數：sector-被寫數據的起始地址 &num-被寫數據 size-寫數據的數量
//返回：無
//============================================================================================= 
.PUBLIC _F_FlashWrite
_F_FlashWrite: .proc 
	push bp to [sp]
	bp = sp+1
	r1 = [bp+3]						//flash base address
	r2 = [bp+4]						//data
	r3 = [bp+5]						//多個字節	
	r4 = C_FLASH_MATCH				//AAAA
	[P_Flash_Ctrl] = r4
L_FlashWriteLoop:
	r4 = C_FLASH_SEQUENT_PGM		//5544
	[P_Flash_Ctrl] = r4
	r4 = [r2++]
	[r1++] = r4

	r3 -= 1
	jnz L_FlashWriteLoop
	[P_Flash_Ctrl] = r3				//寫結束
	pop bp from [sp]
	retf
	.ENDP


// ============================================================================================
//語法：void F_FlashErase(sector)
//描述：擦除256字節
//參數: sector-擦除頁的起始地址
//返回：無
// ============================================================================================
.PUBLIC _F_FlashErase
_F_FlashErase: .proc 
	push bp to [sp]
	bp = sp + 1
	r1 = C_FLASH_MATCH				//AAAA
	[P_Flash_Ctrl] = r1
	r1 = C_FLASH_PAGE_ERASE			//5511
	[P_Flash_Ctrl] = r1
	r1 = [bp+3]						//擦除一頁
	[r1] = r1

	pop bp from [sp]
	retf
	.ENDP
    .END