?? 4×4key-lcd1602.asm
字號:
;*******************************************************************
;* *
;* ME500單片機開發系統演示程序 - 矩陣鍵盤鍵值顯示 *
;* *
;* LCD1602顯示 *
;* *
;* 版本： V1.0 (2006/11/20) *
;* 作者： gguoqing (Email: gguoqing@willar.com) *
;* 網站： www.willar.com(偉納電子) www.mcusj.com(偉納單片機世界) *
;* 郵箱： support@willar.com *
;* *
;*【版權】Copyright(C)偉納電子 www.willar.com All Rights Reserved *
;*【聲明】此程序僅用于學習與參考，引用請注明版權和作者信息！ *
;* *
;*******************************************************************
;矩陣鍵盤定義：
;P1.0-P1.3為列線,P1.4-P1.7為行線
;-----------------------------------------------------
RELAY EQU P1.3
BEEP EQU P3.7
;-----------------------------------------------------
RS EQU P2.0
RW EQU P2.1
EN EQU P2.2
X EQU 26H ;LCD 地址變量
;-----------------------------------------------------
ORG 0000H
JMP MAIN
;-----------------------------------------------------
MAIN: MOV SP,#30H
CLR EN
CALL SET_LCD
CALL MENU1
LOOP:
CALL KEY_SCAN
JMP LOOP
;-----------------------------------------------------
; LCD 初始化設置
;-----------------------------------------------------
SET_LCD:
CLR EN
CALL INIT_LCD ;初始化 LCD
CALL DELAY1
MOV DPTR,#INFO1 ;指針指到顯示信息1
MOV A,#1 ;顯示在第一行
CALL LCD_SHOW
MOV DPTR,#INFO2 ;指針指到顯示信息2
MOV A,#2 ;顯示在第二行
CALL LCD_SHOW
RET
;-----------------------------------------------------
INIT_LCD: ;8位I/O控制 LCD 接口初始化
MOV A,#38H ;雙列顯示，字形5*7點陣
CALL WCOM
CALL DELAY1
MOV A,#38H ;雙列顯示，字形5*7點陣
CALL WCOM
CALL DELAY1
MOV A,#38H ;雙列顯示，字形5*7點陣
CALL WCOM
CALL DELAY1
MOV A,#0CH ;開顯示，關光標，
CALL WCOM
CALL DELAY1
MOV A,#01H ;清除 LCD 顯示屏
CALL WCOM
CALL DELAY1
RET
;----------------------------------------------------
LCD_SHOW: ;在LCD的第一行或第二行顯示信息字符
CJNE A,#1,LINE2 ;判斷是否為第一行
LINE1: MOV A,#80H ;設置 LCD 的第一行地址
CALL WCOM ;寫入命令
CALL CLR_LINE ;清除該行字符數據
MOV A,#80H ;設置 LCD 的第一行地址
CALL WCOM ;寫入命令
JMP FILL
LINE2: MOV A,#0C0H ;設置 LCD 的第二行地址
CALL WCOM ;寫入命令
CALL CLR_LINE ;清除該行字符數據
MOV A,#0C0H ;設置 LCD 的第二行地址
CALL WCOM
FILL: CLR A ;填入字符
MOVC A,@A+DPTR ;由信息區取出字符
CJNE A,#0,LC1 ;判斷是否為結束碼
RET
LC1: CALL WDATA ;寫入數據
INC DPTR ;指針加1
JMP FILL ;繼續填入字符
RET
;---------------------------------------------------
CLR_LINE: ;清除該行 LCD 的字符
MOV R0,#24
CL1: MOV A,#' '
CALL WDATA
DJNZ R0,CL1
RET
;----------------------------------------------------
MENU1: ;LCD 顯示工作菜單信息
MOV DPTR,#MENU2
MOV A,#1 ;在第一行顯示信息
CALL LCD_SHOW
RET
MENU2: DB " KEY NUMBER ",0
;-----------------------------------------------------
INFO1: DB " ",0 ;LCD 第一行顯示信息
INFO2: DB " KEY-CODE: - H ",0 ;LCD 第二行顯示信息
;-----------------------------------------------------
;-----------------------------------------------------
; 寫指令、數據使能子程序
;-----------------------------------------------------
WCOM: ;寫指令使能
MOV P0,A
CLR RS ;RS=L,RW=L,D0-D7=指令碼，E=高脈沖
CLR RW
SETB EN
CALL DELAY0
CLR EN
RET
WDATA: ;寫數據使能
MOV P0,A
SETB RS ;RS=H,RW=L,D0-D7=數據，E=高脈沖
CLR RW
SETB EN
CALL DELAY0
CLR EN
RET
DELAY0: MOV R7,#250 ;延時500微秒
DJNZ R7,$
RET
;---------------------------------------------------
;在 LCD 第二行顯示字符
;A=ASC DATA, B=LINE X POS
;---------------------------------------------------
LCDP2: ;在LCD的第二行顯示字符
PUSH ACC ;
MOV A,B ;設置顯示地址
ADD A,#0C0H ;設置LCD的第二行地址
CALL WCOM ;寫入命令
POP ACC ;由堆棧取出A
CALL WDATA ;寫入數據
RET
;=====================================================
;矩陣鍵盤鍵值查找程序
;鍵值存入30H單元
;=====================================================
;識別鍵盤有無鍵按下子程序
KEY_SCAN:
MOV P1,#0F0H ;置列線為0，行線為1
MOV A,P1
ANL A,#0F0H
MOV B,A
MOV P1,#0FH ;置列線為1，行線為0
MOV A,P1
ANL A,#0FH
ORL A,B ;高四位與低四位重新組合
CJNE A,#0FFH,KEY_IN1 ;0FFH為末按鍵
RET
;識別具體按鍵值子程序
KEY_IN1: MOV B,A
MOV DPTR,#KEYTABLE
MOV R3,#0FFH ;
KEY_IN2: INC R3 ;順序碼加1
MOV A,R3
MOVC A,@A+DPTR
CJNE A,B,KEY_IN3
MOV A,R3 ;找到，取順序碼
CALL CONV
CALL BEEP_BL
RET
KEY_IN3: CJNE A,#00H,KEY_IN2 ;末完，繼續查
RET ;00H為結束碼
KEYTABLE:
DB 0EEH,0EDH,0EBH,0E7H,0DEH ;0,1,2,3,4, 順序碼
DB 0DDH,0DBH,0D7H,0BEH,0BDH ;5,6,7,8,9,
DB 0BBH,0B7H,07EH,07DH,07BH ;A,B,C,D,E,
DB 077H,00H ;F 00為結束碼
;-------------------------------------------------
CONV:
MOV X,#11 ;設置顯示起始位置
MOV A,R3
ANL A,#0FH ;取出低四位二進制數
PUSH ACC
CLR C
SUBB A,#0AH ;減10
POP ACC
JC ASCII1 ;該數小于10，轉ASCII1
ADD A,#07H ;大于10的數加上37H
ASCII1: ADD A,#30H ;小于10的數加上30H
MOV B,X
CALL LCDP2
RET
;--------------------------------------------------------
;蜂鳴器響一聲子程序
;--------------------------------------------------------
BEEP_BL:
MOV R6,#100
BL1: CALL DEX1
CPL BEEP
DJNZ R6,BL1
MOV R5,#50
CALL DELAY
RET
DEX1: MOV R7,#180
DEX2: NOP
DJNZ R7,DEX2
RET
DELAY: ;延時R5×10MS
MOV R6,#50
D1: MOV R7,#100
DJNZ R7,$
DJNZ R6,D1
DJNZ R5,DELAY
RET
;-----------------------------------------------------
DELAY1: ;延時5MS
MOV R6,#25
D2: MOV R7,#100
DJNZ R7,$
DJNZ R6,D2
RET
;-----------------------------------------------------
END
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -