<%
Class Ok3w_Class
    Public ID
    Public ChannelID
    Public SortName
    Public ParentID
    Public SortPath
    Public OrderID
	Public IsOpen
	
	Public Function IsHaveNextClass(ClassId)
		Sql = "select count(ID) from Ok3w_Class where ParentID=" & ClassId
		If Conn.Execute(Sql)(0)=0 Then 
			IsHaveNextClass = False
			Else
				IsHaveNextClass = True
		End If
	End Function
	
    '添加記錄
    Public Sub Add()
        Call GetFormData()
        Sql = "select count(*) from Ok3w_Class where SortName='" & SortName & "' and ParentID=" & ParentID
        If Conn.Execute(Sql)(0)<>0 Then
			Session("ErrMsg") = "相同的分類已經存在，請不要重復添加。"
			Call ActionOk("Class_Manage.asp")
        End If
        Set oRs = Server.CreateObject("Adodb.RecordSet")
        Sql = "select * from Ok3w_Class where 1=2"
        oRs.Open Sql,Conn,1,3
        oRs.AddNew()
        Call UpdateRs(oRs)
        oRs.Update()
		oRs("SortPath") = oRs("SortPath") & oRs("ID") & ","
		oRs.Update()
        oRs.Close()
        Set oRs = Nothing
    End Sub
	
    '修改記錄
    Public Sub Edit()
        Call GetFormData()
        Sql = "select count(*) from Ok3w_Class where SortName='" & SortName & "'  and ParentID=" & ParentID & " and ID<>" & ID
        If Conn.Execute(Sql)(0)<>0 Then
           	Session("ErrMsg") = "相同的分類已經存在，請不要重復添加。"
			Call ActionOk("Class_Manage.asp")
        End If
        Set oRs = Server.CreateObject("Adodb.RecordSet")
        Sql = "select * from Ok3w_Class where ID= " & ID
        oRs.Open Sql,Conn,1,3
        Call UpdateRs(oRs)
        oRs.Update
        oRs.Close
        Set oRs = Nothing
    End Sub
	
    '刪除記錄
    Public Sub Del()
		Call GetFormData()
		
		Sql="select ID,ChannelID,PicFile from Ok3w_Article where SortPath like '%," & ID & ",%'"
		Rs.Open Sql,Conn,0,1
		Do While Not Rs.Eof
			If Rs("PicFile")<>"" Then Call DeleteFile("../" & Rs("PicFile"))
			If Rs("ChannelID")=1 Then
				Call DeleteFile("../article/" & Rs("ID") & ".html")
				Else
					Call DeleteFile("../about/" & Rs("ID") & ".html")
			End If
			Rs.MoveNext
		Loop
		Rs.Close
			
		Sql = "delete from Ok3w_Class where  SortPath like '%," & ID & ",%'"
		Conn.Execute Sql
		
		Sql = "delete from Ok3w_Article where  SortPath like '%," & ID & ",%'"
		Conn.Execute Sql
    End Sub
	
    '接收表單
    Private Sub GetFormData()
		ID = Request.Form("ID")
        ChannelID = Request.Form("ChannelID")
		OrderID = Request.Form("OrderID")
		ParentID = Request.Form("ParentID")
        SortName = Request.Form("SortName")
        SortPath = Request.Form("SortPath")
		IsOpen = Request.Form("IsOpen")
		If IsOpen = "" Then IsOpen = 0
    End Sub
	
    '更新記錄集
    Private Sub UpdateRs(ByRef Rs)
        Rs("ChannelID") = ChannelID
        Rs("SortName") = SortName
        Rs("ParentID") = ParentID
        Rs("SortPath") = SortPath
        Rs("OrderID") = OrderID
		Rs("IsOpen") = IsOpen
    End Sub
	
    '從記錄集中讀數據
    Private Sub GetRs(ByRef Rs)
        ID = Rs("ID")
        ChannelID = Rs("ChannelID")
        SortName = Rs("SortName")
        ParentID = Rs("ParentID")
        SortPath = Rs("SortPath")
        OrderID = Rs("OrderID")
		IsOpen = Rs("IsOpen")
    End Sub
End Class
%>