VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "clsIniOp"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
'*************************************************************************
'**模 塊 名：clsIniOp
'**說    明：星河霸業 版權所有2007 - 2008(C) Xinghe8.vicp.Net/bBs .All Rights Reserved
'**創 建 人：水木之
'**日    期：2007-08-25 14:52:41
'**描    述：好用的ini操作類,對ini文件的操作進行了封裝
'**版    本：V1.0.0
'*************************************************************************
Option Explicit

Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
Private Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long

Private mvarInipath As String

Public Property Let Inipath(ByVal vData As String)
    mvarInipath = vData
End Property

'*************************************************************************
'**函 數 名：Getstr
'**輸    入：ByVal SectionName(String) -
'**        ：ByVal KeyWord(String)     -
'**        ：ByVal DefString(String)   -
'**輸    出：(String) -
'**功能描述：從ini文件中讀信息 SectionName:區段名 KeyWord:具體鍵名 DefString:讀取失敗后返回默認
'**補    充：讀出的都是String類型的,如果你想讀數字型的,可用VB的val()函數將其轉化
'**作    者：水木之
'**日    期：2007-08-25 14:55:24
'**版    本：V1.0.0
'*************************************************************************
Public Function Getstr(ByVal SectionName As String, ByVal KeyWord As String, ByVal DefString As String) As String
Dim ResultString As String * 255
If GetPrivateProfileString(SectionName, KeyWord, "", ResultString, 144, mvarInipath) > 0 Then '關鍵詞的值不為空
    Getstr = Left(ResultString, InStr(ResultString, Chr(0)) - 1)
Else    '將缺省值寫入INI文件
    WritePrivateProfileString SectionName, KeyWord, DefString, mvarInipath
    Getstr = DefString
End If
End Function

'*************************************************************************
'**函 數 名：Setstr
'**輸    入：ByVal SectionName(String) -
'**        ：ByVal KeyWord(String)     -
'**        ：ByVal ValStr(String)      -
'**輸    出：(Boolean) -
'**功能描述：向ini文件中寫信息 SectionName:區段名 KeyWord:具體鍵名 ValStr:具體鍵值
'**作    者：水木之
'**日    期：2007-08-25 14:57:49
'**版    本：V1.0.0
'*************************************************************************
Public Function Setstr(ByVal SectionName As String, ByVal KeyWord As String, ByVal ValStr As String) As Boolean
   Setstr = CBool(WritePrivateProfileString(SectionName, KeyWord, ValStr, mvarInipath))
End Function


Public Function DelKeyWord(ByVal SectionName As String, ByVal KeyWord As String) As Boolean
   DelKeyWord = CBool(WritePrivateProfileString(SectionName, KeyWord, vbNullString, mvarInipath))
End Function

Public Function DelSection(ByVal SectionName As String) As Boolean
   DelSection = CBool(WritePrivateProfileString(SectionName, vbNullString, vbNullString, mvarInipath))
End Function