ＢＴＯＦ                                                        BTOF: INC R0 ；判斷是否為零。
INC R0
MOV A,@R0
MOV R7,A
DEC R0
MOV A,@R0
MOV R6,A
DEC R0
ORL A,R7
JNZ BTF0
MOV @R0,#41H；為零，轉換結束。
RET
BTF0: MOV A,@R0
MOV C,ACC.7
MOV 1DH,C ；保存數符。
CLR 1FH ；以絕對值進行轉換。
MOV C,ACC.6 ；擴充階碼為八位。
MOV ACC.7,C
MOV @R0,A
JNC BTF1
ADD A,#19 ；是否小于１Ｅ－１９？
JC BTF2
MOV @R0,#41H；小于１Ｅ－１９時以０計。
INC R0
MOV @R0,#0
INC R0
MOV @R0,#0
DEC R0
DEC R0
RET
BTF1: SUBB A,#19
JC BTF2
MOV A,#3FH ；大于１Ｅ１９時封頂。
MOV C,1DH
MOV ACC.7,C
MOV @R0,A
INC R0
MOV @R0,#0FFH
INC R0
MOV @R0,#0FFH
DEC R0
DEC R0
RET
BTF2: CLR A ；準備將ＢＣＤ碼尾數轉換成十六進制浮點數。
MOV R4,A
MOV R3,A
MOV R2,#10H ；至少兩個字節。
BTF3: MOV A,R7
ADD A,R7
DA A
MOV R7,A
MOV A,R6
ADDC A,R6
DA A
MOV R6,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
DEC R2
JNB ACC.7,BTF3；直到尾數規格化。
MOV A,R6 ；四舍五入。
ADD A,#0B0H
CLR A
ADDC A,R4
MOV R4,A
CLR A
ADDC A,R3
MOV R3,A
JNC BTF4
MOV R3,#80H
INC R2
BTF4: MOV DPTR,#BTFL；準備查表得到十進制階碼對應的浮點數。
MOV A,@R0
ADD A,#19 ；計算表格偏移量。
MOV B,#3
MUL AB
ADD A,DPL
MOV DPL,A
JNC BTF5
INC DPH
BTF5: CLR A ；查表。
MOVC A,@A+DPTR
MOV C,ACC.6
MOV ACC.7,C
MOV R5,A
MOV A,#1
MOVC A,@A+DPTR
MOV R6,A
MOV A,#2
MOVC A,@A+DPTR
MOV R7,A
LCALL MUL1 ；將階碼對應的浮點數和尾數對應的浮點數相乘。
MOV C,1DH ；取出數符。
MOV 1FH,C
LJMP MOV0 ；傳送轉換結果
                                                            入口條件：浮點ＢＣＤ碼操作數在[R0]中。
出口信息：轉換成的格式化浮點數仍在[R0]中。
影響資源：PSW、A、B、R2～R7、位1DH～1FH 堆棧需求：６字節
                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                              功能：浮點ＢＣＤ碼轉換成格式化浮點數                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                        代碼轉換