?? keyscan_2.asm
字號:
;本程序按下矩陣鍵盤的按鈕實現數碼管的0123456789....移位顯示,并在按下矩陣鍵盤的"P1.3*1.6"鍵后個位實現閃爍功能
;按鍵行列值表示如下：
;----P1.7---P1.6---P1.5---P1.4-------
;----03H----02H----01H----00H----P1.0
;----07H----06H----05H----04H----P1.1
;----0BH----0AH----09H----08H----P1.2
;----0FH----0EH----0DH----0CH----P1.3
;///////////////////////////////////////////
org 0000h
ajmp main
org 0030h
CLR P3.3
setb p2.4;
setb p2.5;
setb p2.6;
setb p2.7;
MOV P2,#0001111B
main:
mov dptr,#tab ;將表頭位置送入DPT
mov 30h,#00h ;將30顯示單元清零
mov 31h,#00h ;將30顯示單元清零
mov 32h,#00h ;將30顯示單元清零
mov 33h,#00h ;將30顯示單元清零
mov 35h,#00h ;將30顯示單元清零
loop:
jb f0,kk1 ;f0若等于一則跳到KK1處
mov 35h,#00h
kk2:
lcall display ;調用顯示程序
lcall key ;調用鍵盤描程序
cpl a ;將A的值取反
jz loop ;無鍵按下則返回
mov a,34h ;有鍵按下將鍵值送入ACC
cjne a,#0ah,norp ;若A鍵未按下則返回到LOOP處
setb f0 ;若A鍵按下則將F0值1
ljmp loop ;返回LOOP處不斷的循環
kk1:
inc 35h ;將35H向上加一
mov a,35h ;將35H中的值送入ACC
cjne a,#10,kk2 ;ACC中的值與10相等則跳轉至KK2
mov 35h,#00h ;若ACC等于零則將35H清零
cpl 00h ;將00H位取反
ajmp kk2 ;跳轉至KK2處
norp:
mov 33h,32h ;將32H顯示單元的內容送入33H
mov 32h,31h ;將31H顯示單元的內容送入32H
mov 31h,30h ;將30H單元的內容送入31H
mov a,34h ;將鍵值送入ACC
mov 30h,a ;將ACC的值送入30H
ljmp loop ;返回主程序循環
display:
mov p2,#0ffh ;將P2口置高電平
mov r7,#100 ;軟件計數器賦值
dd1:
jnb 00h,dd1d ;若00H等0跳至DD1D
ajmp dd1b ;若00H等于1則跳轉至DD1B
dd1d: mov a,30h ;將顯示緩沖區30H中的值送入ACC
movc a,@a+dptr ;查表取要顯示的數并把查表的結果送入ACC
mov p0,a ;將要顯示的數送入P0口
clr p2.3 ;開個位顯示單元
lcall delay100us ;延時100US
setb p2.3 ;關個位顯示單
ajmp dd1c
dd1b:
mov a,30h ;將顯示緩沖區30H中的值送入ACC
movc a,@a+dptr ;查表取要顯示的數并把查表的結果送入ACC
mov p0,a ;將要顯示的數送入P0口
setb p2.3 ;開個位顯示單元
lcall delay100us ;延時100US
setb p2.3 ;開個位顯示單元
dd1c:
mov a,31h ;將顯示緩沖區別31H中的值送入A
movc a,@a+dptr ;查表取要顯示的數并把查表的結果送入ACC
mov p0,a ;將要顯示的數送入P0口
clr p2.2 ;開十位顯示單元
lcall delay100us ;延時100US
setb p2.2 ;關十位顯示單元
mov a,32h ;將顯示緩沖區32H中的值送入ACC
movc a,@a+dptr ;查表取要顯示的數并把查表的結果送入ACC
mov p0,a ;將要顯示的數送入P0口
clr p2.1 ;開百位顯示單元
lcall delay100us ;延時100US
setb p2.1 ;關百位顯示單元
mov a,33h ;將顯示緩沖區33H中的值送入ACC
movc a,@a+dptr ;查表取要顯示的數并把查表的結果送入ACC
mov p0,a ;將要顯示的數送入P0口
clr p2.0 ;開千位顯示單元
lcall delay100us ;延時100US
setb p2.0 ;關千位顯示單元
djnz r7,dd1 ;R7不等于0返回至DD1處
ret ;R7等于0子程序返回
KEY: LCALL KS ;調用檢測按鍵子程序
JNZ K1 ;有鍵按下繼續
ljmp key_exit ;無鍵按下退出KEY子程序
K1: LCALL delay4ms ;返回繼續檢測有無按鍵按下
LCALL delay4ms
LCALL KS ;有鍵按下繼續延時去抖動
JNZ K2 ;再一次調用檢測按鍵程序
ljmp key_exit ;無鍵按下退出KEY子程序
K2: MOV R2,#0EFH ;將掃描值送入 R2暫存
MOV R4,#00H ;將第一列的列值00H送入R4暫存,R4用于存放列
K3: MOV P1,R2 ;將R2的值送入P1口
L6: JB P1.0,L1 ;P1.0等于1跳轉到L1
MOV A,#00H ;將第一行的行值00H送入ACC
AJMP LK ;跳轉到鍵值處理程序
L1: JB P1.1,L2 ;P1.1等于1跳轉到L2
MOV A,#04H ;將第二行的行值04H送入ACC
AJMP LK ;跳轉到鍵值理程序進行鍵值處理
L2: JB P1.2,L3 ;P1.2等于1跳轉到L3
MOV A,#08H ;將第三行的行值08H送入ACC
AJMP LK ;跳轉到鍵值處理程序
L3: JB P1.3,NEXT ;P1.3等于1跳轉到NEXT處
MOV A,#0cH ;將第四行的行值0CH送入ACC
LK: ADD A,R4 ;行值與列值相加后的鍵值送入A
mov 34h,a ;將A中的值送入34h暫存
K4: ;LCALL delay4ms ;
lcall display ;調用動態顯示子程序
LCALL KS ;
JNZ K4 ;按鍵沒有松開繼續返回檢測
RET ;按鍵松開返回
NEXT:
INC R4 ;將列值加一
MOV A,R2 ;將R2的值送入A
JNB ACC.7,key_exit ;掃描完成跳至KEY處進行下一回合的掃描
RL A ;掃描未完成將A中的值右移一位進行下一列的掃描
MOV R2,A ;將ACC的值送入R2暫存
AJMP K3 ;跳轉到K3繼續
key_exit:
mov a,#0ffh ;無鍵按下則將A賦成0FFH。
ret
KS: MOV P1,#0FH ;將P1口高四位置0低四位值1
MOV A,P1 ;讀P1口
XRL A,#0FH ;將A中的值與A中的值相異或
RET ;子程序返回
delay4ms: ;4ms延時
MOV R5,#08H
L7: MOV R6,#0FAH
L8: DJNZ R6,L8
DJNZ R5,L7
RET
delay100us: ;100us延時
mov r5,#50
djnz r5,$
ret
tab: db 0c0h,0f9h,0a4h,0b0h,99h,92h,82h,0f8h,80h,90h,88h,83h,0c6h,0a1h,86h,8eh
end
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -