MOV A,R3 ；將平方根的尾數(shù)回傳到[R0]中
MOV @R0,A
DEC R0
MOV A,R2
MOV @R0,A
SQR9: DEC R0 ；數(shù)據(jù)指針回歸原位
CLR OV ；開方結(jié)果有效
RET 

（１８） 標(biāo)號： ＦＰＬＮ 功能：浮點數(shù)多項式計算

入口條件：自變量在[R0]中，多項式系數(shù)在調(diào)用指令之后，以４０Ｈ結(jié)束。
出口信息：OV=0時，結(jié)果仍在[R0]中，OV=1時，溢出。
影響資源：DPTR、PSW、A、B、R2～R7、位1EH、1FH 堆棧需求： ４字節(jié)
FPLN: POP DPH ；取出多項式系數(shù)存放地址
POP DPL
XCH A,R0 ；R0、R1交換角色，自變量在[R1]中
XCH A,R1
XCH A,R0
CLR A ；清第一工作區(qū)
MOV R2,A
MOV R3,A
MOV R4,A
CLR 1FH
PLN1: CLR A ；讀取一個系數(shù)，并裝入第二工作區(qū)
MOVC A,@A+DPTR
MOV C,ACC.7
MOV 1EH,C
MOV C,ACC.6
MOV ACC.7,C
MOV R5,A
INC DPTR
CLR A
MOVC A,@A+DPTR
MOV R6,A
INC DPTR
CLR A
MOVC A,@A+DPTR
MOV R7,A
INC DPTR ；指向下一個系數(shù)
MOV C,1EH ；比較兩個數(shù)符
RRC A
XRL A,23H
RLC A
MOV F0,C ；保存比較結(jié)果
LCALL AS1 ；進(jìn)行代數(shù)加法運算
CLR A ；讀取下一個系數(shù)的第一個字節(jié)
MOVC A,@A+DPTR
CJNE A,#40H,PLN2；是結(jié)束標(biāo)志嗎？
XCH A,R0 ；運算結(jié)束，恢復(fù)R0、R1原來的角色
XCH A,R1
XCH A,R0
LCALL MOV0 ；將結(jié)果回傳到[R0]中
CLR A
INC DPTR
JMP @A+DPTR ；返回主程序
PLN2: MOV A,@R1 ；比較自變量和中間結(jié)果的符號
XRL A,23H
RLC A
MOV 1FH,C ；保存比較結(jié)果
LCALL MUL0 ；進(jìn)行乘法運算
SJMP PLN1 ；繼續(xù)下一項運算

（１９） 標(biāo)號： ＦＬＯＧ 功能：以１０為底的浮點對數(shù)函數(shù)

入口條件：操作數(shù)在[R0]中。
出口信息：OV=0時，結(jié)果仍在[R0]中，OV=1時，負(fù)數(shù)或零求對數(shù)出錯。
影響資源：DPTR、PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：９字節(jié)
FLOG: LCALL FLN ；先以ｅ為底求對數(shù)
JNB OV,LOG
RET ；如溢出則停止計算
LOG: MOV R5,#0FFH；系數(shù)０．４３４３０（１／Ｌｎ１０）
MOV R6,#0DEH
MOV R7,#5CH
LCALL MUL1 ；通過相乘來換底
LJMP MOV0 ；傳回結(jié)果
　
（２０） 標(biāo)號： ＦＬＮ 功能：以ｅ為底的浮點對數(shù)函數(shù)

入口條件：操作數(shù)在[R0]中。
出口信息：OV=0時，結(jié)果仍在[R0]中，OV=1時，負(fù)數(shù)或零求對數(shù)出錯。
影響資源：DPTR、PSW、A、B、R2～R7、位1EH、1FH 堆棧需求： ７字節(jié)
　
FLN: LCALL MVR0 ；將[R0]傳送到第一工作區(qū)
JB 1FH,LNOV；負(fù)數(shù)或零求對數(shù)，出錯
MOV A,R3
ORL A,R4
JNZ LN0
LNOV: SETB OV
RET
LN0: CLR C
LCALL RL1 ；左規(guī)一次
CLR A
XCH A,R2 ；保存原階碼，清零工作區(qū)的階碼
PUSH ACC
LCALL RLN ；規(guī)格化
LCALL MOV0 ；回傳
LCALL FPLN ；用多項式計算尾數(shù)的對數(shù)
DB 7BH,0F4H,30H；０．０２９８０８
DB 0FEH,85H,13H；－０．１２９９６
DB 7FH,91H,51H；０．２８３８２
DB 0FFH,0FAH,0BAH；－０．４８９７
DB 0,0FFH,0CAH；０．９９９１８
DB 70H,0C0H,0；１．１４４２×１０-5
DB 40H ；結(jié)束
POP ACC ；取出原階碼
JNZ LN1
RET ；如為零，則結(jié)束
LN1: CLR 1EH ；清第二區(qū)數(shù)符
MOV C,ACC.7
MOV F0,C ；保存階符
JNC LN2
CPL A ；當(dāng)階碼為負(fù)時，求其絕對值
INC A
LN2: MOV R2,A ；階碼的絕對值乘以０．６９３１５
MOV B,#72H
MUL AB
XCH A,R2
MOV R7,B
MOV B,#0B1H
MUL AB
ADD A,R7
MOV R7,A ；乘積的尾數(shù)在R6R7R2中
CLR A
ADDC A,B
MOV R6,A
MOV R5,#8 ；乘積的階碼初始化（整數(shù)部分為一字節(jié)）
LN3: JB ACC.7,LN4；乘積格式化
MOV A,R2
RLC A
MOV R2,A
MOV A,R7
RLC A
MOV R7,A
MOV A,R6
RLC A
MOV R6,A
DEC R5
SJMP LN3
LN4: MOV C,F0 ；取出階符，作為乘積的數(shù)符
MOV ACC.7,C
LJMP ASN ；與尾數(shù)的對數(shù)合并，得原操作數(shù)的對數(shù)
　
（２１） 標(biāo)號： ＦＥ１０ 功能：以１０為底的浮點指數(shù)函數(shù)

入口條件：操作數(shù)在[R0]中。
出口信息：OV=0時，結(jié)果仍在[R0]中，OV=1時，溢出。
影響資源：DPTR、PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：６字節(jié)
FE10: MOV R5,#2 ；加權(quán)系數(shù)為３．３２１９（Ｌｏｇ2１０）
MOV R6,#0D4H
MOV R7,#9AH
SJMP EXP ；先進(jìn)行加權(quán)運算，后以２為底統(tǒng)一求冪

（２２） 標(biāo)號： ＦＥＸＰ 功能：以ｅ為底的浮點指數(shù)函數(shù)

入口條件：操作數(shù)在[R0]中。
出口信息：OV=0時，結(jié)果仍在[R0]中，OV=1時，溢出。
影響資源：DPTR、PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：６字節(jié)
FEXP: MOV R5,#1 ；加權(quán)系數(shù)為１．４４２７２（Ｌｎｇ2ｅ）
MOV R6,#0B8H
MOV R7,#0ABH
EXP: CLR 1EH ；加權(quán)系數(shù)為正數(shù)
LCALL MVR0 ；將[R0]傳送到第一工作區(qū)
LCALL MUL1 ；進(jìn)行加權(quán)運算
SJMP E20 ；以２為底統(tǒng)一求冪

（２３） 標(biāo)號： ＦＥ２ 功能：以２為底的浮點指數(shù)函數(shù)

入口條件：操作數(shù)在[R0]中。
出口信息：OV=0時，結(jié)果仍在[R0]中，OV=1時，溢出。
影響資源：DPTR、PSW、A、B、R2～R7、位1EH、1FH 堆棧需求：６字節(jié)
FE2: LCALL MVR0 ；將[R0]傳送到第一工作區(qū)
E20: MOV A,R3
ORL A,R4
JZ EXP1 ；尾數(shù)為零
MOV A,R2
JB ACC.7,EXP2；階符為負(fù)？
SETB C
SUBB A,#6 ；階碼大于６否？
JC EXP2
JB 1FH,EXP0；數(shù)符為負(fù)否？
MOV @R0,#3FH；正指數(shù)過大，冪溢出
INC R0
MOV @R0,#0FFH
INC R0
MOV @R0,#0FFH
DEC R0
DEC R0
SETB OV
RET
EXP0: MOV @R0,#41H；負(fù)指數(shù)過大，冪下溢，清零處理
CLR A
INC R0
MOV @R0,A
INC R0
MOV @R0,A
DEC R0
DEC R0
CLR OV
RET 
EXP1: MOV @R0,#1 ；指數(shù)為零，冪為１．００
INC R0
MOV @R0,#80H
INC R0
MOV @R0,#0
DEC R0
DEC R0
CLR OV
RET 
EXP2: MOV A,R2 ；將指數(shù)復(fù)制到第二工作區(qū)
MOV R5,A
MOV A,R3
MOV R6,A
MOV A,R4
MOV R7,A
MOV C,1FH
MOV 1EH,C
LCALL INT ；對第一區(qū)取整
MOV A,R3
JZ EXP4
EXP3: CLR C ；使尾數(shù)高字節(jié)R3對應(yīng)一個字節(jié)整數(shù)
RRC A
INC R2
CJNE R2,#8,EXP3
EXP4: MOV R3,A
JNB 1FH,EXP5
CPL A ；并用補碼表示
INC A
EXP5: PUSH ACC ；暫時保存之
LCALL RLN ；重新規(guī)格化
CPL 1FH
SETB F0
LCALL AS1 ；求指數(shù)的小數(shù)部分
LCALL MOV0 ；回傳指數(shù)的小數(shù)部分
LCALL FPLN ；通過多項式計算指數(shù)的小數(shù)部分的冪
DB 77H,0B1H,0C9H；１．３５６４×１０-3
DB 7AH,0A1H,68H；９．８５１４×１０-3
DB 7CH,0E3H,4FH；０．０５５４９５
DB 7EH,0F5H,0E7H；０．２４０１４
DB 0,0B1H,72H；０．６９３１５
DB 1,80H,0 ；１．０００００
DB 40H ；結(jié)束
POP ACC ；取出指數(shù)的整數(shù)部分
ADD A,R2 ；按補碼加到冪的階碼上
MOV R2,A
CLR 1FH ；冪的符號為正
LJMP MOV0 ；將冪傳回[R0]中
　
（２４）標(biāo)號： ＤＴＯＦ 功能：雙字節(jié)十六進(jìn)制定點數(shù)轉(zhuǎn)換成格式化浮點數(shù)

入口條件：雙字節(jié)定點數(shù)的絕對值在[R0]中，數(shù)符在位1FH中，整數(shù)部分的位數(shù)在A中。
出口信息：轉(zhuǎn)換成格式化浮點數(shù)在[R0]中（三字節(jié)）。
影響資源：PSW、A、R2、R3、R4、位1FH 堆棧需求： ６字節(jié)
DTOF: MOV R2,A ；按整數(shù)的位數(shù)初始化階碼
MOV A,@R0 ；將定點數(shù)作尾數(shù)
MOV R3,A
INC R0
MOV A,@R0
MOV R4,A
DEC R0
LCALL RLN ；進(jìn)行規(guī)格化
LJMP MOV0 ；傳送結(jié)果到[R0]中

（２５） 標(biāo)號： ＦＴＯＤ 功能：格式化浮點數(shù)轉(zhuǎn)換成雙字節(jié)定點數(shù)

入口條件：格式化浮點操作數(shù)在[R0]中。
出口信息：OV=1時溢出，OV=0時轉(zhuǎn)換成功：定點數(shù)的絕對值在[R0]中（雙字節(jié)），數(shù)符
在位1FH中，F(xiàn)0=1 時為整數(shù)，CY=1時為一字節(jié)整數(shù)一字節(jié)小數(shù)，否則為純小數(shù)。
影響資源：PSW、A、B、R2、R3、R4、位1FH 堆棧需求： ６字節(jié)
FTOD: LCALL MVR0 ；將[R0]傳送到第一工作區(qū)
MOV A,R2
JZ FTD4 ；階碼為零，純小數(shù)
JB ACC.7,FTD4；階碼為負(fù)，純小數(shù)
SETB C
SUBB A,#10H
JC FTD1
SETB OV ；階碼大于１６，溢出
RET
FTD1: SETB C
MOV A,R2
SUBB A,#8 ；階碼大于８否？
JC FTD3
FTD2: MOV B,#10H ；階碼大于８，按雙字節(jié)整數(shù)轉(zhuǎn)換
LCALL FTD8
SETB F0 ；設(shè)立雙字節(jié)整數(shù)標(biāo)志
CLR C
CLR OV
RET
FTD3: MOV B,#8 ；按一字節(jié)整數(shù)一字節(jié)小數(shù)轉(zhuǎn)換
LCALL FTD8
SETB C ；設(shè)立一字節(jié)整數(shù)一字節(jié)小數(shù)標(biāo)志
CLR F0
CLR OV
RET
FTD4: MOV B,#0 ；按純小數(shù)轉(zhuǎn)換
LCALL FTD8
CLR OV ；設(shè)立純小數(shù)標(biāo)志
CLR F0
CLR C
RET
FTD8: MOV A,R2 ；按規(guī)定的整數(shù)位數(shù)進(jìn)行右規(guī)
CJNE A,B,FTD9
MOV A,R3 ；將雙字節(jié)結(jié)果傳送到[R0]中
MOV @R0,A
INC R0
MOV A,R4
MOV @R0,A
DEC R0
RET 
FTD9: CLR C
LCALL RR1 ；右規(guī)一次
SJMP FTD8

（２６） 標(biāo)號： ＢＴＯＦ 功能：浮點ＢＣＤ碼轉(zhuǎn)換成格式化浮點數(shù)

入口條件：浮點ＢＣＤ碼操作數(shù)在[R0]中。
出口信息：轉(zhuǎn)換成的格式化浮點數(shù)仍在[R0]中。
影響資源：PSW、A、B、R2～R7、位1DH～1FH 堆棧需求：６字節(jié)
BTOF: INC R0 ；判斷是否為零。
INC R0
MOV A,@R0
MOV R7,A
DEC R0
MOV A,@R0
MOV R6,A
DEC R0
ORL A,R7
JNZ BTF0
MOV @R0,#41H；為零，轉(zhuǎn)換結(jié)束。
RET
BTF0: MOV A,@R0
MOV C,ACC.7
MOV 1DH,C ；保存數(shù)符。
CLR 1FH ；以絕對值進(jìn)行轉(zhuǎn)換。
MOV C,ACC.6 ；擴充階碼為八位。
MOV ACC.7,C
MOV @R0,A
JNC BTF1
ADD A,#19 ；是否小于１Ｅ－１９？
JC BTF2
MOV @R0,#41H；小于１Ｅ－１９時以０計。
INC R0
MOV @R0,#0
INC R0
MOV @R0,#0
DEC R0
DEC R0
RET
BTF1: SUBB A,#19
JC BTF2
MOV A,#3FH ；大于１Ｅ１９時封頂。
MOV C,1DH
MOV ACC.7,C
MOV @R0,A
INC R0
MOV @R0,#0FFH
INC R0
MOV @R0,#0FFH
DEC R0
DEC R0
RET
BTF2: CLR A ；準(zhǔn)備將ＢＣＤ碼尾數(shù)轉(zhuǎn)換成十六進(jìn)制浮點數(shù)。
MOV R4,A
MOV R3,A
MOV R2,#10H ；至少兩個字節(jié)。
BTF3: MOV A,R7
ADD A,R7
DA A
MOV R7,A
MOV A,R6
ADDC A,R6
DA A
MOV R6,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
DEC R2
JNB ACC.7,BTF3；直到尾數(shù)規(guī)格化。
MOV A,R6 ；四舍五入。
ADD A,#0B0H
CLR A
ADDC A,R4
MOV R4,A
CLR A
ADDC A,R3
MOV R3,A
JNC BTF4
MOV R3,#80H
INC R2
BTF4: MOV DPTR,#BTFL；準(zhǔn)備查表得到十進(jìn)制階碼對應(yīng)的浮點數(shù)。
MOV A,@R0
ADD A,#19 ；計算表格偏移量。
MOV B,#3
MUL AB
ADD A,DPL
MOV DPL,A
JNC BTF5
INC DPH
BTF5: CLR A ；查表。
MOVC A,@A+DPTR
MOV C,ACC.6
MOV ACC.7,C
MOV R5,A
MOV A,#1
MOVC A,@A+DPTR
MOV R6,A
MOV A,#2
MOVC A,@A+DPTR
MOV R7,A
LCALL MUL1 ；將階碼對應(yīng)的浮點數(shù)和尾數(shù)對應(yīng)的浮點數(shù)相乘。
MOV C,1DH ；取出數(shù)符。
MOV 1FH,C
LJMP MOV0 ；傳送轉(zhuǎn)換結(jié)果。

（２７） 標(biāo)號： ＦＴＯＢ 功能：格式化浮點數(shù)轉(zhuǎn)換成浮點ＢＣＤ碼

入口條件：格式化浮點操作數(shù)在[R0]中。
出口信息：轉(zhuǎn)換成的浮點ＢＣＤ碼仍在[R0]中。
影響資源：PSW、A、B、R2～R7、位1DH～1FH 堆棧需求：６字節(jié)
FTOB: INC R0
MOV A,@R0
INC R0
ORL A,@R0
DEC R0
DEC R0
JNZ FTB0
MOV @R0,#41H
RET
FTB0: MOV A,@R0
MOV C,ACC.7
MOV 1DH,C
CLR ACC.7
MOV @R0,A
LCALL MVR0
MOV DPTR,#BFL0；絕對值大于或等于１時的查表起點。
MOV B,#0 ；十的０次冪。
MOV A,R2
JNB ACC.7,FTB1
MOV DPTR,#BTFL；絕對值小于１Ｅ－６時的查表起點。
MOV B,#0EDH ；十的－１９次冪。
ADD A,#16
JNC FTB1
MOV DPTR,#BFLN；絕對值大于或等于１Ｅ－６時的查表起點。
MOV B,#0FAH ；十的－６次冪。
FTB1: CLR A ；查表，找到一個比待轉(zhuǎn)換浮點數(shù)大的整數(shù)冪。
MOVC A,@A+DPTR
MOV C,ACC.6
MOV ACC.7,C
MOV R5,A
MOV A,#1
MOVC A,@A+DPTR
MOV R6,A
MOV A,#2
MOVC A,@A+DPTR
MOV R7,A
MOV A,R5 ；和待轉(zhuǎn)換浮點數(shù)比較。
CLR C
SUBB A,R2
JB ACC.7,FTB2；差為負(fù)數(shù)。 
JNZ FTB3
MOV A,R6
CLR C
SUBB A,R3
JC FTB2
JNZ FTB3
MOV A,R7
CLR C
SUBB A,R4
JC FTB2
JNZ FTB3
MOV R5,B ；正好是表格中的