ORG　　 0000H 
MAIN:　 MOV　　 SP,#60H
　　　　MOV　　 P0,#0FFH
　　　　MOV　　 P1,#0FFH
　　　　MOV　　 P2,#0FFH
　　　　MOV　　 P3,#0FFH
　　　　JNB　　 P3.2,$　　　　;等待遙控信號出現(xiàn)
　　　　MOV　　 R6,#10
SB: 　　ACALL　 YS1　　　　　 ;調(diào)用882微秒延時子程序
　　　　JB　　　P3.2,MAIN　　 ;延時882微秒后判斷P3.2腳是否出現(xiàn)高電平如果有就退出解碼程序
　　　　DJNZ　　R6, SB　　　　;重復(fù)10次，目的是檢測在8820微秒內(nèi)如果出現(xiàn)高電平就退出解碼程序
　　　　　　　　　　　　　　　;以上完成對遙控信號的9000微秒的初始低電平信號的識別。
　　　　JNB　　 P3.2, $ 　　　;等待高電平避開9毫秒低電平引導(dǎo)脈沖
　　　　ACALL　 YS2 　　　　　;延時4.74毫秒避開4.5毫秒的結(jié)果碼
　　　　MOV　　 R1,#1AH 　　　;設(shè)定1AH為起始RAM區(qū)
　　　　MOV　　 R2,#4 
PP: 　　MOV　　 R3,#8
JJJJ: 　JNB　　 P3.2,$　　　　;等待地址碼第一位的高電平信號
　　　　LCALL　 YS1　　　　　 ;高電平開始后用882微秒的時間尺去判斷信號此時的高低電平狀態(tài)
　　　　MOV　　 C,P3.2　　　　;將P3.2引腳此時的電平狀態(tài)0或1存入C中
　　　　JNC　　 UUU　　　　　 ;如果為0就跳轉(zhuǎn)到UUU
　　　　JB　　　P3.2,$　　　　;如果為1就等待高電平信號結(jié)束
UUU: 　 MOV　　 A,@R1　　　　 ;將R1中地址的給A
　　　　RRC　　 A　　　　　　 ;將C中的值0或1移入A中的最低位
　　　　MOV　　 @R1,A　　　　 ;將A中的數(shù)暫時存放在R1中
　　　　DJNZ　　R3,JJJJ　　　 ;接收地址碼的高8位
　　　　INC　　 R1　　　　　　;對R1中的值加1，換成下一個RAM
　　　　DJNZ　　R2,PP 　　　　;接收完16位地址碼和8位數(shù)據(jù)碼和8位數(shù)據(jù)反碼，存放在1AH/1BH/1CH/1DH的RAM中
　　　　　　　　　　　　　　　;以下對代碼是否正確和定義進行識別
　　　　MOV　　 A,1AH　　　　 ;比較高8位地址碼
　　　　XRL　　 A,#00000000B　;判斷1AH的值是否等于00000000，相等的話A為0
　　　　JNZ　　 MAIN　　　　　;如果不相等說明解碼失敗退出解碼程序
　　　　MOV　　 A,1BH　　　　 ;比較低8位地址
　　　　XRL　　 A,#11111111B　;再判斷高8位地址是否正確
　　　　JNZ　　 MAIN　　　　　;如果不相等說明解碼失敗退出解碼程序
　　　　MOV　　 A,1CH　　　　 ;比較數(shù)據(jù)碼和數(shù)據(jù)反碼是否正確?
　　　　CPL　　 A
　　　　XRL　　 A,1DH 　　　　;將1CH的值取反后和1DH比較 不同則無效丟棄，核對數(shù)據(jù)是否準確
　　　　JNZ　　 MAIN　　　　　;如果不相等說明解碼失敗退出解碼程序
　　　　LCALL　 SOUND　　　　 ;解碼成功，聲音提示
　　　　MOV　　 A,1AH
　　　　CPL　　 A
　　　　MOV　　 P1,A　　　　　;遙控碼十六進制值通過P1口LED顯示出來

;-------- 下面為0～9鍵碼判斷并在實驗板的5位數(shù)碼管中顯示鍵值 --------
JZPD: 　MOV　　 A,1AH
IRD0: 　CJNE　　A,#00H,IRD1　 ;按鍵"0"判斷顯示
　　　　MOV　　 P0,#0C0H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD1: 　CJNE　　A,#01H,IRD2　 ;按鍵"1"判斷顯示
　　　　MOV　　 P0,#0F9H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD2:　 CJNE　　A,#02H,IRD3　 ;按鍵"2"判斷顯示
　　　　MOV　　 P0,#0A4H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD3:　 CJNE　　A,#03H,IRD4　 ;按鍵"3"判斷顯示
　　　　MOV　　 P0,#0B0H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD4: 　CJNE　　A,#04H,IRD5　 ;按鍵"4"判斷顯示
　　　　MOV　　 P0,#99H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD5: 　CJNE　　A,#05H,IRD6　 ;按鍵"5"判斷顯示
　　　　MOV　　 P0,#92H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD6: 　CJNE　　A,#06H,IRD7　 ;按鍵"6"判斷顯示
　　　　MOV　　 P0,#82H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD7:　 CJNE　　A,#07H,IRD8　 ;按鍵"7"判斷顯示
　　　　MOV　　 P0,#0F8H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD8: 　CJNE　　A,#08H,IRD9　 ;按鍵"8"判斷顯示
　　　　MOV　　 P0,#80H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN
IRD9:　 CJNE　　A,#09H,IRDOR　 ;按鍵"9"判斷顯示
　　　　MOV　　 P0,#90H
　　　　MOV　　 P2,#11100000B
　　　　AJMP　　MAIN

IRDOR:　MOV　　 P2,#0FFH　 　 　;關(guān)閉數(shù)碼管使能。"0～9"以外的非數(shù)字功能按鍵鍵值不采用數(shù)碼管顯示，直接從P1口輸出鍵值
　　　　AJMP　　MAIN

YS1: 　 MOV　　 R4,#19 ;延時子程序1
D1: 　　MOV　　 R5,#18
　　　　DJNZ　　R5,$
　　　　DJNZ　　R4,D1 
　　　　RET

YS2: 　 MOV　　 R4,#10 ;延時子程序2
D2: 　　MOV　　 R5,#216
　　　　DJNZ　　R5,$
　　　　DJNZ　　R4,D2 
　　　　RET

SOUND:　MOV　　 R7,#228 ;音效延時子程序
SDL1: 　CPL　　 P3.7
　　　　MOV　　 R6,#0FFH
SDL0: 　DJNZ　　R6,SDL0
　　　　DJNZ　　R7,SDL1
　　　　RET