內(nèi)容 
    目前已有若干版本的子程序庫(kù)公開(kāi)發(fā)表，它們各有特色。本程序庫(kù)中的開(kāi)平方算法為快速逼近算法，它能達(dá)到牛頓迭代法同樣的精度，而速度加快二十倍左右，超過(guò)雙字節(jié)定點(diǎn)除法的速度。

本子程序庫(kù)對(duì)《單片機(jī)應(yīng)用程序設(shè)計(jì)技術(shù)》一書(shū)附錄中的子程序庫(kù)作了重大修訂：

（１）按當(dāng)前流行的以 IBM PC 為主機(jī)的開(kāi)發(fā)系統(tǒng)對(duì)匯編語(yǔ)言的規(guī)定，讀者不必再進(jìn)行修改，便可直接使用。
（２）對(duì)浮點(diǎn)運(yùn)算子程序庫(kù)進(jìn)行了進(jìn)一步的測(cè)試和優(yōu)化，對(duì)十進(jìn)制浮點(diǎn)數(shù)和二進(jìn)制浮點(diǎn)數(shù)的相互轉(zhuǎn)換子程序進(jìn)行了徹底改寫(xiě)，提高了運(yùn)算精度和可靠性。
（３）新增添了若干個(gè)浮點(diǎn)子程序（傳送、比較、清零、判零等），使編寫(xiě)數(shù)據(jù)處理程序的工作變得更簡(jiǎn)單直觀。

在使用說(shuō)明中開(kāi)列了最主要的幾項(xiàng)：標(biāo)號(hào)、入口條件、出口信息、影響資源、堆棧需求，各項(xiàng)目的意義請(qǐng)參閱《單片機(jī)應(yīng)用程序設(shè)計(jì)技術(shù)》第六章 6.3.7 節(jié)的內(nèi)容。程序清單中開(kāi)列了四個(gè)欄目：標(biāo)號(hào)、指令、操作數(shù)、注釋。為方便讀者理解，注釋盡力詳細(xì)。

子程序庫(kù)的使用方法如下：

１．將子程序庫(kù)全部?jī)?nèi)容鏈接在應(yīng)用程序之后，統(tǒng)一編譯即可。優(yōu)點(diǎn)是簡(jiǎn)單方便，缺點(diǎn)是程序太長(zhǎng)，大量無(wú)關(guān)子程序也包含在其中。
２．僅將子程序庫(kù)中的有關(guān)部分內(nèi)容鏈接在應(yīng)用程序之后，統(tǒng)一編譯即可。有些子程序需要調(diào)用一些低級(jí)子程序，這些低級(jí)子程序也應(yīng)該包含在內(nèi)。優(yōu)點(diǎn)是程序緊湊，缺點(diǎn)是需要對(duì)子程序庫(kù)進(jìn)行仔細(xì)刪節(jié)。

（一） ＭＣＳ－５１定點(diǎn)運(yùn)算子程序庫(kù)及其使用說(shuō)明 

定點(diǎn)運(yùn)算子程序庫(kù)文件名為DQ51.ASM，為便于使用，先將有關(guān)約定說(shuō)明如下：
１．多字節(jié)定點(diǎn)操作數(shù)：用[R0]或[R1]來(lái)表示存放在由R0或R1指示的連續(xù)單元中的數(shù)
據(jù)。地址小的單元存放數(shù)據(jù)的高字節(jié)。例如：[R0]=123456H，若(R0)=30H，則(30H)=12H，
(31H)=34H，(32H)=56H。
２．運(yùn)算精度：?jiǎn)未味c(diǎn)運(yùn)算精度為結(jié)果最低位的當(dāng)量值。
３．工作區(qū)：數(shù)據(jù)工作區(qū)固定在PSW、A、B、R2～R7，用戶只要不在工作區(qū)中存放無(wú)關(guān)的或非消耗性的信息，程序就具有較好的透明性。
（１） 標(biāo)號(hào)： ＢＣＤＡ 功能：多字節(jié)ＢＣＤ碼加法
入口條件：字節(jié)數(shù)在R7中，被加數(shù)在[R0]中，加數(shù)在[R1]中。
出口信息：和在[R0]中，最高位進(jìn)位在CY中。
影響資源：PSW、A、R2 堆棧需求： ２字節(jié)
BCDA: MOV A,R7 ；取字節(jié)數(shù)至R2中
MOV R2,A
ADD A,R0 ；初始化數(shù)據(jù)指針
MOV R0,A
MOV A,R2
ADD A,R1
MOV R1,A
CLR C
BCD1: DEC R0 ；調(diào)整數(shù)據(jù)指針
DEC R1
MOV A,@R0
ADDC A,@R1 ；按字節(jié)相加
DA A ；十進(jìn)制調(diào)整
MOV @R0,A ；和存回[R0]中
DJNZ R2,BCD1 ；處理完所有字節(jié)
RET

（２） 標(biāo)號(hào)： ＢＣＤＢ 功能：多字節(jié)ＢＣＤ碼減法
入口條件：字節(jié)數(shù)在R7中，被減數(shù)在[R0]中，減數(shù)在[R1]中。
出口信息：差在[R0]中，最高位借位在CY中。
影響資源：PSW、A、R2、R3 堆棧需求： ６字節(jié)
BCDB: LCALL NEG1 ；減數(shù)[R1]十進(jìn)制取補(bǔ)
LCALL BCDA ；按多字節(jié)ＢＣＤ碼加法處理
CPL C ；將補(bǔ)碼加法的進(jìn)位標(biāo)志轉(zhuǎn)換成借位標(biāo)志
MOV F0,C ；保護(hù)借位標(biāo)志
LCALL NEG1 ；恢復(fù)減數(shù)[R1]的原始值
MOV C,F0 ；恢復(fù)借位標(biāo)志
RET
NEG1: MOV A,R0 ；[R1]十進(jìn)制取補(bǔ)子程序入口
XCH A,R1 ；交換指針
XCH A,R0
LCALL NEG ；通過(guò)[R0]實(shí)現(xiàn)[R1]取補(bǔ)
MOV A,R0
XCH A,R1 ；換回指針
XCH A,R0
RET
　
（３） 標(biāo)號(hào)： ＮＥＧ 功能：多字節(jié)ＢＣＤ碼取補(bǔ)

入口條件：字節(jié)數(shù)在R7中，操作數(shù)在[R0]中。
出口信息：結(jié)果仍在[R0]中。
影響資源：PSW、A、R2、R3 堆棧需求： ２字節(jié)
NEG: MOV A,R7 ；取（字節(jié)數(shù)減一）至R2中
DEC A
MOV R2,A
MOV A,R0 ；保護(hù)指針
MOV R3,A
NEG0: CLR C 
MOV A,#99H
SUBB A,@R0 ；按字節(jié)十進(jìn)制取補(bǔ)
MOV @R0,A ；存回[R0]中
INC R0 ；調(diào)整數(shù)據(jù)指針
DJNZ R2,NEG0 ；處理完（R2）字節(jié)
MOV A,#9AH ；最低字節(jié)單獨(dú)取補(bǔ)
SUBB A,@R0
MOV @R0,A
MOV A,R3 ；恢復(fù)指針
MOV R0,A
RET

（４） 標(biāo)號(hào)： ＢＲＬＮ 功能：多字節(jié)ＢＣＤ碼左移十進(jìn)制一位（乘十）
　
入口條件：字節(jié)數(shù)在R7中，操作數(shù)在[R0]中。
出口信息：結(jié)果仍在[R0]中，移出的十進(jìn)制最高位在R3中。
影響資源：PSW、A、R2、R3 堆棧需求： ２字節(jié)
BRLN: MOV A,R7 ；取字節(jié)數(shù)至R2中
MOV R2,A
ADD A,R0 ；初始化數(shù)據(jù)指針
MOV R0,A
MOV R3,#0 ；工作單元初始化
BRL1: DEC R0 ；調(diào)整數(shù)據(jù)指針
MOV A,@R0 ；取一字節(jié)
SWAP A ；交換十進(jìn)制高低位
MOV @R0,A ；存回
MOV A,R3 ；取低字節(jié)移出的十進(jìn)制高位
XCHD A,@R0 ；換出本字節(jié)的十進(jìn)制高位
MOV R3,A ；保存本字節(jié)的十進(jìn)制高位
DJNZ R2,BRL1 ；處理完所有字節(jié)
RET
　
（５） 標(biāo)號(hào)： ＭＵＬＤ 功能：雙字節(jié)二進(jìn)制無(wú)符號(hào)數(shù)乘法
　
入口條件：被乘數(shù)在R2、R3中，乘數(shù)在R6、R7中。
出口信息：乘積在R2、R3、R4、R5中。
影響資源：PSW、A、B、R2～R7 堆棧需求： ２字節(jié)
MULD: MOV A,R3 ；計(jì)算R3乘R7
MOV B,R7
MUL AB
MOV R4,B ；暫存部分積
MOV R5,A
MOV A,R3 ；計(jì)算R3乘R6
MOV B,R6
MUL AB
ADD A,R4 ；累加部分積
MOV R4,A
CLR A
ADDC A,B
MOV R3,A
MOV A,R2 ；計(jì)算R2乘R7
MOV B,R7
MUL AB
ADD A,R4 ；累加部分積
MOV R4,A
MOV A,R3
ADDC A,B
MOV R3,A
CLR A
RLC A
XCH A,R2 ；計(jì)算R2乘R6
MOV B,R6
MUL AB
ADD A,R3 ；累加部分積
MOV R3,A
MOV A,R2
ADDC A,B
MOV R2,A
RET

（６） 標(biāo)號(hào)： ＭＵＬ２ 功能：雙字節(jié)二進(jìn)制無(wú)符號(hào)數(shù)平方
　
入口條件：待平方數(shù)在R2、R3中。
出口信息：結(jié)果在R2、R3、R4、R5中。
影響資源：PSW、A、B、R2～R5 堆棧需求： ２字節(jié)
MUL2: MOV A,R3 ；計(jì)算R3平方
MOV B,A
MUL AB
MOV R4,B ；暫存部分積
MOV R5,A
MOV A,R2 ；計(jì)算R2平方
MOV B,A
MUL AB
XCH A,R3 ；暫存部分積，并換出R2和R3
XCH A,B
XCH A,R2
MUL AB ；計(jì)算2×R2×R3
CLR C
RLC A
XCH A,B
RLC A
JNC MU20
INC R2 ；累加溢出量
MU20: XCH A,B ；累加部分積
ADD A,R4
MOV R4,A
MOV A,R3
ADDC A,B
MOV R3,A
CLR A
ADDC A,R2
MOV R2,A
RET

（７） 標(biāo)號(hào)： ＤＩＶＤ 功能：雙字節(jié)二進(jìn)制無(wú)符號(hào)數(shù)除法

入口條件：被除數(shù)在R2、R3、R4、R5中，除數(shù)在R6、R7中。
出口信息：OV=0 時(shí)，雙字節(jié)商在R2、R3中，OV=1 時(shí)溢出。
影響資源：PSW、A、B、R1～R7 堆棧需求： ２字節(jié)
DIVD: CLR C ；比較被除數(shù)和除數(shù)
MOV A,R3 
SUBB A,R7
MOV A,R2
SUBB A,R6
JC DVD1
SETB OV ；溢出
RET
DVD1: MOV B,#10H ；計(jì)算雙字節(jié)商
DVD2: CLR C ；部分商和余數(shù)同時(shí)左移一位
MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
XCH A,R2
RLC A
XCH A,R2
MOV F0,C ；保存溢出位
CLR C
SUBB A,R7 ；計(jì)算（R2R3－R6R7）
MOV R1,A
MOV A,R2
SUBB A,R6
ANL C,/F0 ；結(jié)果判斷
JC DVD3
MOV R2,A ；夠減，存放新的余數(shù)
MOV A,R1
MOV R3,A
INC R5 ；商的低位置一
DVD3: DJNZ B,DVD2 ；計(jì)算完十六位商（R4R5）
MOV A,R4 ；將商移到R2R3中
MOV R2,A
MOV A,R5
MOV R3,A
CLR OV ；設(shè)立成功標(biāo)志
RET
　
（８） 標(biāo)號(hào)： Ｄ４５７ 功能：雙字節(jié)二進(jìn)制無(wú)符號(hào)數(shù)除以單字節(jié)二進(jìn)制數(shù)

入口條件：被除數(shù)在R4、R5中，除數(shù)在R7中。
出口信息：OV=0 時(shí)，單字節(jié)商在R3中，OV=1 時(shí)溢出。
影響資源：PSW、A、R3～R7 堆棧需求： ２字節(jié)
D457: CLR C
MOV A,R4
SUBB A,R7
JC DV50
SETB OV ；商溢出
RET
DV50: MOV R6,#8 ；求平均值（R4R5／R7－→R3）
DV51: MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV F0,C
CLR C
SUBB A,R7
ANL C,/F0
JC DV52
MOV R4,A
DV52: CPL C
MOV A,R3
RLC A
MOV R3,A
DJNZ R6,DV51
MOV A,R4 ；四舍五入
ADD A,R4
JC DV53
SUBB A,R7
JC DV54
DV53: INC R3
DV54: CLR OV
RET
　
（９） 標(biāo)號(hào)： ＤＶ３１ 功能：三字節(jié)二進(jìn)制無(wú)符號(hào)數(shù)除以單字節(jié)二進(jìn)制數(shù)

入口條件：被除數(shù)在R3、R4、R5中，除數(shù)在R7中。
出口信息：OV=0 時(shí)，雙字節(jié)商在R4、R5中，OV=1 時(shí)溢出。
影響資源：PSW、A、B、R2～R7 堆棧需求： ２字節(jié)
DV31: CLR C
MOV A,R3
SUBB A,R7
JC DV30
SETB OV ；商溢出
RET
DV30: MOV R2,#10H ；求R3R4R5／R7－→R4R5
DM23: CLR C
MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
MOV F0,C
CLR C
SUBB A,R7
ANL C,/F0
JC DM24
MOV R3,A
INC R5
DM24: DJNZ R2,DM23
MOV A,R3 ；四舍五入
ADD A,R3
JC DM25
SUBB A,R7
JC DM26
DM25: INC R5
MOV A,R5
JNZ DM26
INC R4
DM26: CLR OV
RET ；商在R4R5中 
　
（１０） 標(biāo)號(hào)： ＭＵＬＳ 功能：雙字節(jié)二進(jìn)制有符號(hào)數(shù)乘法（補(bǔ)碼）

入口條件：被乘數(shù)在R2、R3中，乘數(shù)在R6、R7中。
出口信息：乘積在R2、R3、R4、R5中。
影響資源：PSW、A、B、R2～R7 堆棧需求： ４字節(jié)
MULS: MOV R4,#0 ；清零R4R5
MOV R5,#0
LCALL MDS ；計(jì)算結(jié)果的符號(hào)和兩個(gè)操作數(shù)的絕對(duì)值
LCALL MULD ；計(jì)算兩個(gè)絕對(duì)值的乘積
SJMP MDSE ；用補(bǔ)碼表示結(jié)果
（１１） 標(biāo)號(hào)： ＤＩＶＳ 功能：雙字節(jié)二進(jìn)制有符號(hào)數(shù)除法（補(bǔ)碼）

入口條件：被除數(shù)在R2、R3、R4、R5中，除數(shù)在R6、R7中。
出口信息：OV=0時(shí)商在R2、R3中，OV=1時(shí)溢出。
影響資源：PSW、A、B、R1～R7 堆棧需求： ５字節(jié)
DIVS: LCALL MDS ；計(jì)算結(jié)果的符號(hào)和兩個(gè)操作數(shù)的絕對(duì)值
PUSH PSW ；保存結(jié)果的符號(hào)
LCALL DIVD ；計(jì)算兩個(gè)絕對(duì)值的商
JNB OV,DVS1 ；溢出否？
POP ACC ；溢出，放去結(jié)果的符號(hào)，保留溢出標(biāo)志
RET
DVS1: POP PSW ；未溢出，取出結(jié)果的符號(hào)
MOV R4,#0
MOV R5,#0
MDSE: JB F0,MDS2 ；用補(bǔ)碼表示結(jié)果
CLR OV ；結(jié)果為正，原碼即補(bǔ)碼，計(jì)算成功
RET
MDS: CLR F0 ；結(jié)果符號(hào)初始化
MOV A,R6 ；判斷第二操作數(shù)的符號(hào)
JNB ACC.7,MDS1；為正，不必處理
CPL F0 ；為負(fù)，結(jié)果符號(hào)取反
XCH A,R7 ；第二操作數(shù)取補(bǔ)，得到其絕對(duì)值
CPL A
ADD A,#1
XCH A,R7
CPL A
ADDC A,#0
MOV R6,A
MDS1: MOV A,R2 ；判斷第一操作數(shù)或運(yùn)算結(jié)果的符號(hào)
JNB ACC.7,MDS3；為正，不必處理
CPL F0 ；為負(fù)，結(jié)果符號(hào)取反
MDS2: MOV A,R5 ；求第一操作數(shù)的絕對(duì)值或運(yùn)算結(jié)果的補(bǔ)碼
CPL A
ADD A,#1
MOV R5,A
MOV A,R4
CPL A
ADDC A,#0
MOV R4,A
MOV A,R3
CPL A
ADDC A,#0
MOV R3,A
MOV A,R2
CPL A
ADDC A,#0
MOV R2,A
MDS3: CLR OV ；運(yùn)算成功
RET
　
（１２） 標(biāo)號(hào)： ＳＨ２ 功能：雙字節(jié)二進(jìn)制無(wú)符號(hào)數(shù)開(kāi)平方（快速）

入口條件：被開(kāi)方數(shù)在R2、R3中。
出口信息：平方根仍在R2、R3中，整數(shù)部分的位數(shù)為原數(shù)的一半，其余為小數(shù)。
影響資源：PSW、A、B、R2～R7 堆棧需求： ２字節(jié)
SH2: MOV A,R2
ORL A,R3
JNZ SH20
RET ；被開(kāi)方數(shù)為零，不必運(yùn)算
SH20: MOV R7,#0 ；左規(guī)次數(shù)初始化
MOV A,R2
SH22: ANL A,#0C0H ；被開(kāi)方數(shù)高字節(jié)小于４０Ｈ否？
JNZ SQRH ；不小于４０Ｈ，左規(guī)格化完成，轉(zhuǎn)開(kāi)方過(guò)程
CLR C ；每左規(guī)一次，被開(kāi)方數(shù)左移兩位
MOV A,R3
RLC A
MOV F0,C
CLR C
RLC A
MOV R3,A
MOV A,R2
MOV ACC.7,C
MOV C,F0
RLC A
RLC A
MOV R2,A
INC R7 ；左規(guī)次數(shù)加一
SJMP SH22 ；繼續(xù)左規(guī)
　
（１３） 標(biāo)號(hào)： ＳＨ４ 功能：四字節(jié)二進(jìn)制無(wú)符號(hào)數(shù)開(kāi)平方（快速）

入口條件：被開(kāi)方數(shù)在R2、R3、R4、R5中。
出口信息：平方根在R2、R3中，整數(shù)部分的位數(shù)為原數(shù)的一半，其余為小數(shù)。
影響資源：PSW、A、B、R2～R7 堆棧需求： ２字節(jié)
SH4: MOV A,R2
ORL A,R3
ORL A,R4
ORL A,R5
JNZ SH40
RET ；被開(kāi)方數(shù)為零，不必運(yùn)算
SH40: MOV R7,#0 ；左規(guī)次數(shù)初始化
MOV A,R2
SH41: ANL A,#0C0H ；被開(kāi)方數(shù)高字節(jié)小于４０Ｈ否？
JNZ SQRH ；不小于４０Ｈ，左規(guī)格化完成
MOV R6,#2 ；每左規(guī)一次，被開(kāi)方數(shù)左移兩位
SH42: CLR C ；被開(kāi)方數(shù)左移一位
MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
MOV A,R2
RLC A
MOV R2,A
DJNZ R6,SH42 ；被開(kāi)方數(shù)左移完兩位
INC R7 ；左規(guī)次數(shù)加一
SJMP SH41 ；繼續(xù)左規(guī)
SQRH: MOV A,R2 ；規(guī)格化后高字節(jié)按折線法分為三個(gè)區(qū)間
ADD A,#57H
JC SQR2
ADD A,#45H
JC SQR1
ADD A,#24H
MOV B,#0E3H ；第一區(qū)間的斜率
MOV R4,#80H ；第一區(qū)間的平方根基數(shù)
SJMP SQR3
SQR1: MOV B,#0B2H ；第二區(qū)間的斜率
MOV R4,#0A0H；第二區(qū)間的平方根基數(shù)
SJMP SQR3
SQR2: MOV B,#8DH ；第三區(qū)間的斜率
MOV R4,#0D0H；第三區(qū)間的平方根基數(shù)
SQR3: MUL AB ；與區(qū)間基點(diǎn)的偏移量乘區(qū)間斜率
MOV A,B
ADD A,R4 ；累加到平方根的基數(shù)上
MOV R4,A
MOV B,A
MUL AB ；求當(dāng)前平方根的冪
XCH A,R3 ；求偏移量（存放在R2R3中）
CLR C
SUBB A,R3
MOV R3,A
MOV A,R2
SUBB A,B
MOV R2,A
SQR4: SETB C ；用減奇數(shù)法校正一個(gè)字節(jié)的平方根
MOV A,R4 ；當(dāng)前平方根的兩倍加一存入R5R6中
RLC A
MOV R6,A
CLR A
RLC A
MOV R5,A
MOV A,R3 ；偏移量小于該奇數(shù)否？
SUBB A,R6
MOV B,A
MOV A,R2
SUBB A,R5
JC SQR5 ；小于，校正結(jié)束，已達(dá)到一個(gè)字節(jié)的精度
INC R4 ；不小于，平方根加一
MOV R2,A ；保存新的偏移量
MOV R3,B
SJMP SQR4 ；繼續(xù)校正
SQR5: MOV A,R4 ；將一個(gè)字節(jié)精度的根存入R2
XCH A,R2
RRC A