;/******************************************************************/
;/*                                                                */
;/* ME500單片機開發系統演示程序 - 鍵控步進電機正反轉實驗           */
;/*                                                                */
;/*                                                                */
;/* 版本： V1.0 (2006/11/20)                                       */
;/* 作者： gguoqing (Email: gguoqing@willar.com)                   */
;/* 網站： www.willar.com(偉納電子)  www.mcusj.com(偉納單片機世界) */
;/* 郵箱： support@willar.com                                      */
;/*                                                                */
;/*【版權】Copyright(C)偉納電子 www.willar.com All Rights Reserved */
;/*【聲明】此程序僅用于學習與參考，引用請注明版權和作者信息！      */
;/*                                                                */
;/******************************************************************/

; 步進電機步進角為 7.5度，一圈 360 度。
; 單四拍工作方式：
; A-B-C-D (即一個脈沖,轉 7.5 度)
; 單雙八拍工作方式：
; A-AB-B-BC-C-CD-D-DA (即一個脈沖,轉 3.75 度)
; 一個取數工作周期，步進電機轉30度
; 步進電機轉一圈需要48個工作脈沖
;-------------------------------------------------------
; A組線圈對應 P1.0    （桔色）
; B組線圈對應 P1.1    （棕色）
; C組線圈對應 P1.2    （黃色）
; D組線圈對應 P1.3    （黑色）
;-------------------------------------------------------
         K1  BIT  P1.4     ;步進電機正轉
         K2  BIT  P1.5     ;步進電機反轉
         K3  BIT  P1.6
         K4  BIT  P1.7     ;步進電機停止轉動
       BEEP  BIT  P3.7
;-------------------------------------------------------
           ORG 0000H
           LJMP MAIN
           ORG 0030H
;-------------------------------------------------------
MAIN:
           MOV  SP,#60H
           MOV  P1,#0F0H   ;關閉步進電機，鍵輸入線置高
MAIN1:           
           JB  K1,MAIN2
           ACALL  BEEP_BL   ;步進電機正轉
	   JNB K1,$
           ACALL  FFW          
MAIN2:           
           JB  K2,MAIN1
          ACALL  BEEP_BL   ;步進電機反轉
	   JNB  K2,$
           ACALL  REV                     
           JMP  MAIN1
;------------------------正轉-------------------------           
FFW:
          ;MOV R3,#  64;7.5度電機正轉1圈共48個脈沖
           MOV  R3,#320       ;轉5圈需48*5=240個脈沖
FFW1:
           MOV R0,#00H
FFW2:
           JB  K4,FFW3         ;終止步進電機運行
           ACALL  BEEP_BL
           JMP  FFW4
FFW3:           
           MOV A,R0
           MOV DPTR,#TABLE1
           MOVC A,@A+DPTR
           JZ FFW1
           MOV P1,A
           LCALL DELAY
           INC R0
           DJNZ R3,FFW2
FFW4:
           MOV P1,#0F0H
           RET
;---------------------------反轉--------------------------
REV:
          ;MOV R3,#48           ;7.5度電機正轉1圈共48個脈沖
           MOV  R3,#320  ;轉5圈需48*5=240個脈沖
REV1:
           MOV R0,#00H
REV2:
           JB  K4,REV3          ;終止步進電機運行
           ACALL  BEEP_BL
           JMP  REV4
REV3:          
           MOV A,R0
           MOV DPTR,#TABLE2
           MOVC A,@A+DPTR          
           JZ  REV1
           MOV P1,A
           CALL DELAY
           INC R0
           DJNZ R3,REV2
REV4:
           MOV P1,#0F0H
           RET
           
;-------------------------------------------------------
DELAY:
           MOV R7,#40    ;步進電機的轉速
DEL1:      MOV R6,#248
           DJNZ R6,$
           DJNZ R7,DEL1
           RET
;-------------------------------------------------------
DELAY1:
           MOV   R5,#20    ;2S 延時子程序
DEL2:
           MOV   R7,#200
DEL3:
           MOV   R6,#250
           DJNZ  R6,$
           DJNZ  R7,DEL3
           DJNZ  R5,DEL2
           RET
;-------------------------------------------------------
; 單四拍工作方式：
TABLE1:
        DB   0F1H,0F2H,0F4H,0F8H  ;正轉表
        DB   00H  ;正轉結束
TABLE2:
        DB   0F8H,0F4H,0F2H,0F1H  ;反轉表
        DB   00H  ;反轉結束
;--------------------------------------------------------
;蜂鳴器響一聲子程序
;--------------------------------------------------------
BEEP_BL:
         MOV  R6,#100
  BL1:
         CALL  DEX1
         CPL  BEEP
         DJNZ  R6,BL1
         RET
 DEX1:
         MOV  R7,#180
 DEX2:
         NOP
         DJNZ  R7,DEX2
         RET
;--------------------------------------------------------- 
         END