<%
'===================================================================
'= ASP FILENAME	: /user/user_my_topic_list.asp
'= CREATED TIME : 2006-5-4
'= LAST MODIFIED: 2006-5-4
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 用戶所發表帖子
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/customer/include_customer_action_view.asp" -->
<!-- #include file = "../main_func.asp" -->
<!-- #include file = "./user_inc.asp" -->
<!-- #include file = "../inc/logic/logic_forum.asp" -->
<%
'========================================================
'==   Action參數設置
'========================================================
'== 頁面名
Const CONST_PAGE_FILE	= "user/user_my_topic_list.asp"

'== 頁面標題/功能
Const CONST_PAGE_TITLE	= "用戶所發表帖子"

'== 功能函數名字空間
Const CONST_ACTION_FUNC	= "ShowUserMyTopicListCtl"

'== 相對根目錄路徑 
GBL_strHomeURL			= "../"

'== 頁面構造
Call ActionBuild()

'== 在模板中引用的標簽變量
Dim TAG_objRS			'== 列表記錄集
Dim TAG_strPageNav		'== 翻頁導航
Dim TAG_strOrderUrl		'== 排序鏈接	

'== 請求校驗與過濾
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 頁面析構
Call ActionOver()
%>

<%

'===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-4
'= Description : 加載頁面模塊
'===================================================================
Function LoadPageTpl()
%>
	<!-- #include file = "../template_c/page_user_my_topic_list.html.asp" --> 
<%
End Function

'===================================================================
'= Function    : ShowUserMyTopicListCtl()
'= Time		   : Created At 2006-5-4
'= Input       : None
'= Description : 用戶所發表帖子
'===================================================================
Function ShowUserMyTopicListCtl()
	Dim strFileName 
	Dim intMaxPerPage
	Dim intCurPage,intTotalPut
	Dim strSql

	intMaxPerPage = GBL_intMaxPerPage
	TAG_intPerPage = GBL_intMaxPerPage

	strFileName = "user_my_topic_list.asp"
	
	'== 取記錄集
	strSql = " AND TOPICS_OWNER_ID=" & GBL_intUserId & GetOrder()
	If Not GetTopicsLogic(strSql) Then
		Exit Function
	End If

	If Not ResultExecute(GBL_objPubDB.intRSNum,"您收藏的論壇貼","ES_DB_NO") Then

		Set TAG_objRS = GBL_objPubDB.objPubRS
	
		intTotalPut = GBL_objPubDB.intRSNum

		intCurPage = GetCurPage(intMaxPerPage,intTotalPut)
		
		If intCurPage > 1 Then		
			If (intCurPage - 1) * intMaxPerPage < intTotalPut Then
				GBL_objPubDB.objPubRS.Move  (intCurPage - 1) * intMaxPerPage
				Dim BookMark
				BookMark = GBL_objPubDB.objPubRS.BookMark	
			End If
		End If
		
		strFileName = GetOrderUrl(strFileName)
		TAG_strPageNav = ShowPageNav(intTotalPut,intMaxPerPage,intCurPage,strFileName)

	End If
	
End Function

%>