<%
'===================================================================
'= ASP FILENAME	: /user/user_authen.asp
'= CREATED TIME : Feb,08,2004
'= LAST MODIFIED: Feb,08,2004
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : class member list
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/inc_class_def.asp" -->

<!-- #include file = "../inc/inc_db_func.asp" -->
<!-- #include file = "../class/class_db.asp" -->

<!-- #include file = "../inc/inc_pub_func.asp" -->

<%
Const CONST_PAGE_FILE = "user/user_authen.asp"
GBL_strHomeURL = "../"

Dim clsPubDB
Set clsPubDB = New classDBOprt

Call SiteHead("用戶登陸")
Call ExecOrShowSwitch(CONST_PAGE_FILE,"UL")
Set clsPubDB = Nothing

%>
<%
'====================================================================
'= Sub         : UpdateUserAuthen()
'= Time		   : Created At DEC,27,2003
'= Input       : None

'= Called by   : 
'= Calls       :
'= Table	   : UPDATE CLASS_USER,
'= Description : User's register info save
'====================================================================
Sub UpdateUserAuthen()

	Dim intErrId
	Dim strAddInfo
	Dim GetRSId

	If GBL_intUserRegMode <> 4 And GBL_intUserRegMode <> 3 Then
		Call ResultExecute(E_USER_PUB,"錯誤的用戶批準請求(模式)","ES_ERR")
		Exit Sub
	End If

	If GBL_intUserRegMode = 3 And GBL_strUserAuthen <> 1 Then
		Call ResultExecute(E_USER_PUB,"錯誤的用戶批準請求<br>(需要管理員或副管理員)","ES_ERR")
		Exit Sub
	End If

	intErrId = 0

	strAddInfo = "該用戶"
	GetRSId = Trim(Request.QueryString("UserId"))
	intErrId = DataCheck("DT_ID",GetRSId,strAddInfo,"")
	Call ResultExecute(intErrId,strAddInfo,"ES_ERR")

	clsPubDB.Clear()
	clsPubDB.TableName = "CLASS_USER"
	clsPubDB.SQLType = "UPDATE"
	clsPubDB.Where = "USER_ID=" & GetRSId & " AND USER_AUTHEN=8 "
	clsPubDB.AddField "USER_AUTHEN",0
	clsPubDB.SQLExecute()
	Call ResultExecute(clsPubDB.intErrNum,"update no verify user","ES_ERR")
	If clsPubDB.intRSNum < 0 Then
		Call ResultExecute(E_USER_PUB,"錯誤的用戶批準請求","ES_ERR")
	End If

	Call ResultExecute(244,"該用戶通過批準","ES_SUCC")

End Sub
'=============== End of Sub UpdateUserAuthen() ======================
'=============== End of Function UserLogin() ========================
%>