<%
''===================================================================
'= ASP FILENAME	: /user/user_info_show.asp
'= CREATED TIME : 2006-5-6
'= LAST MODIFIED: 2006-5-6
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 用戶個人信息
'= Change Log:
'==================================================================='
%>

<!-- #include file = "../inc/customer/include_customer_action_view.asp" -->
<!-- #include file = "../main_func.asp" -->
<!-- #include file = "../inc/inc_ubb.asp" -->
<!-- #include file = "./user_inc.asp" -->
<!-- #include file = "../inc/logic/logic_user.asp" -->
<%
'========================================================
'==   Action參數設置
'========================================================
'== 頁面名
Const CONST_PAGE_FILE	= "user/user_info_show.asp"

'== 頁面標題/功能
Const CONST_PAGE_TITLE	= "用戶個人信息"

'== 功能函數名字空間
Const CONST_ACTION_FUNC	= "ShowUserAllInfoCtl"

'== 相對根目錄路徑 
GBL_strHomeURL			= "../"

'== 頁面構造
Call ActionBuild()

'== 在模板中引用的標簽變量
Dim TAG_objDicUnit		'== 單列記錄


'== 請求校驗與過濾
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 頁面析構
Call ActionOver()
%>

<%
''===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-4
'= Description : 加載頁面模塊
'==================================================================='
Function LoadPageTpl()
%>
	<!-- #include file = "../template_c/page_user_info_show.html.asp" --> 
<%
End Function

''===================================================================
'= Function    : ShowUserAllInfoCtl()
'= Time		   : Created At 2006-5-6
'= Input       : None
'= Description : 用戶個人信息
'==================================================================='
Function ShowUserAllInfoCtl()
	Dim intSms,intNewSms,strTmp,arrTmp

	'== 短信數
	If Not GetUserSmsNumLogic(GBL_intUserId,intSms) Or Not GetUserNewSmsNumLogic(GBL_intUserId,intNewSms) Then
		Exit Function
	End If

	'== 取記錄
	If Not GetUserLogic(" AND USER_ID=" & GBL_intUserId) Then Exit Function

	Set TAG_objDicUnit = GBL_objPubDB.GetRsOneRow() 

	'== 簽名圖
	If GBL_objPubDB.objPubRS("USER_FACE_SELECT") = "QQ秀" Then
		TAG_objDicUnit.Item("USER_QQ_SHOW") = "<img src='" & MakeQQShow(GBL_objPubDB.objPubRS("USER_QQ")) & "'  title='" & GBL_objPubDB.objPubRS("USER_REALNAME") & "的簽名圖'>"
	Else
		TAG_objDicUnit.Item("USER_QQ_SHOW") = MakeImg( GBL_objPubDB.objPubRS("USER_NOW_FACE")& " onload='javascript:DrawImage(this," & GBL_strUserFaceWidth & "," & GBL_strUserFaceHeight & ",1);'",GBL_objPubDB.objPubRS("USER_REALNAME") & "的簽名圖")
	End If

	'== 短信
	TAG_objDicUnit.Item("USER_SMS") = intSms
	TAG_objDicUnit.Item("USER_NEW_SMS") = intNewSms

	'== 生肖/星座
	TAG_objDicUnit.Item("USER_ANIMAL") = DisplayBirthAnimal(GBL_objPubDB.objPubRS("USER_BIRTH"),strTmp)
	TAG_objDicUnit.Item("USER_CON") = Constellation(GBL_objPubDB.objPubRS("USER_BIRTH"),strTmp)

	'== 身份
	Select Case GBL_objPubDB.objPubRS("USER_AUTHEN")
		Case	0	: strTmp = "普通成員"
		Case	1	: strTmp = "管理員"
		Case	2	: strTmp = "副管理員"
		Case	3	: strTmp = "未通過認證的新用戶"
		Case	4	: strTmp = "鎖定用戶"
		Case	Else : strTmp = "不明用戶"
	End Select
	TAG_objDicUnit.Item("USER_AUTH") = strTmp

	'== 簽名檔
	strTmp = ""
	If GBL_objPubDB.objPubRS("USER_INFO") <> "" And GBL_objPubDB.objPubRS("USER_INFO") <> CONST_DIVIDER Then
		arrTmp = Split(GBL_objPubDB.objPubRS("USER_INFO"),CONST_DIVIDER)
		If Isarray(arrTmp) Then
			strTmp = UbbCode(arrTmp(0))
		Else
			strTmp = "未填"
		End If
	Else
		strTmp = "未填"
	End If
	TAG_objDicUnit.Item("USER_SIGN") = strTmp

	'== 生日祝福提示
	Call PopBirthCelebrate(GBL_objPubDB.objPubRS("USER_BIRTH"),GBL_objPubDB.objPubRS("USER_REALNAME"))

End Function
''===================================================================
'= Function     : PopBirthCelebrate(dateBirth,strUserName)
'= Time		    : Created At Nov,26,2003
'= Input        : dateBirth : user birth
'= Description  : your birth
'==================================================================='
Function PopBirthCelebrate(dateBirth,strUserName)

	Exit Function
	Dim strPopFile,strPopFile1

	strPopFile = "user_pop_birth.asp?pstName=" & strUserName

	if DAY(dateBirth) = Day(Now()) AND MONTH(dateBirth)= Month(Now()) Then
		Response.Write "<script language='JavaScript'>window.open('" & strPopFile & "','熱烈祝賀生日快樂','top=0,left=0,width=319,height=282,scrollbars=no,menubar=no,toolbar=no,resizable=no');window.title='生日快樂'</script>"
	End If 

End Function
%>