<%
'===================================================================
'= ASP FILENAME	: /admin/admin_link_del.asp
'= CREATED TIME : 2006-4-30
'= LAST MODIFIED: 2006-4-30
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 刪除友情鏈接管理
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/admin/include_admin_action_execute.asp" -->
<!-- #include file = "./admin_inc.asp" -->
<!-- #include file = "../inc/logic/logic_config.asp" -->
<!-- #include file = "../inc/inc_file_func.asp" -->

<%
'========================================================
'==   Action參數設置
'========================================================
'== 頁面名
Const CONST_PAGE_FILE	= "admin/admin_link_del.asp"

'== 頁面標題/功能
Const CONST_PAGE_TITLE	= "刪除友情鏈接"

'== 功能函數名字空間
Const CONST_ACTION_FUNC	= "DelLinkCtl"

'== 相對根目錄路徑 
GBL_strHomeURL			= "../"

'== 頁面構造
Call ActionBuild()

'== 請求校驗與過濾
Call ActionExecFilterAdmin(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 頁面析構
Call ActionOver()
%>

<%
'===================================================================
'= Function		: DelLinkCtl()  
'= Time		    : Created At 2006-5-2
'= Input        : None
'= Output       : None
'= Description  : 刪除友情鏈接
'===================================================================
Function DelLinkCtl()
	Dim strIds
	Dim intPageNow,strSql

	'== 服務器端數據校驗
	If Not ServerDataCheck(arrLinkDelDataChk) Then
		Exit Function
	End If

	'== 獲取表單數據
	strIds = Trim(Request.Form("selId"))
 
	'== 刪除友情鏈接邏輯處理
	strSql = " AND LINK_ID IN (" & strIds & ")"
	If Not RemoveLinksLogic(strSql) Then
		Exit Function
	End If

	'== 重新生成用戶select html
	Dim strFilePath
	strFilePath = GBL_strHomeUrl & GBL_strHtmlFolder & "make_link.html"
	If Not MakeHtmlLinkLogic("",strFilePath) Then Exit Function 

	'== Get now page
	intPageNow = FmtFormData(Request("intPageNow"))

	'== 成功處理
	Dim strHtmlCode,strSuccUrl
	strHtmlCode = "所選友情鏈接已被刪除"
	strSuccUrl = "admin/admin_link_manage.asp?intPageNow=" & intPageNow
	Call SuccExecute(strHtmlCode,strSuccUrl)

End Function
%>