?? admin_link.asp
字號:
<%
'===================================================================
'= ASP FILENAME : /admin/admin_link.asp
'= CREATED TIME : Feb,08,2004
'= LAST MODIFIED: Feb,08,2004
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION : friend link
'= Change Log:
'===================================================================
%>
<!-- #include file = "../inc/inc_class_def.asp" -->
<!-- #include file = "../inc/inc_db_func.asp" -->
<!-- #include file = "../class/class_db.asp" -->
<!-- #include file = "../inc/inc_pub_func.asp" -->
<!-- #include file = "../inc/inc_char_func.asp" -->
<!-- #include file = "../inc/inc_data_check.asp" -->
<!-- #include file = "../inc/inc_file_func.asp" -->
<!-- #include file = "../class/class_html_form.asp" -->
<!-- #include file = "../class/class_html_table.asp" -->
<!-- #include file = "../main_func.asp" -->
<!-- #include file = "./admin_func.asp" -->
<!-- #include file = "../js/comm_func.js" -->
<%
Const CONST_PAGE_FILE = "admin/admin_link.asp"
GBL_strHomeURL = "../"
Call AdminCheckExec()
Dim clsPubDB
Set clsPubDB = New classDBOprt
Call SiteHead("友情鏈接管理")
Call CheckPostExist("ShowLinkAdmin,FormAddLinkAdmin,FormSaveAddLinkAdmin,DelLinkAdmin")
Call ExeSysAdminQst()
Set clsPubDB = Nothing
%>
<%
'=============== FUNCTION BODY BEGIN ===============================
'===================================================================
'= Sub : ShowLinkAdmin()
'= Time : Created At Jan,03,2004
'= Input : None
'= Called by :
'= Calls :
'= Table : Qurey _LINK,
'= Description : Show the link
'===================================================================
Sub ShowLinkAdmin()
Dim i
Dim clsTable '== the object of table
Dim strTdClass '== td's css
Dim strHtmlCode
clsPubDB.Clear()
clsPubDB.TableName = "CLASS_LINK"
clsPubDB.SQLType = "SELECT"
clsPubDB.Order = "LINK_ID DESC"
clsPubDB.AddField "*",""
'== Get data
clsPubDB.SQLRSExecute()
Call ResultExecute(clsPubDB.intErrNum,"","ES_ERR")
If clsPubDB.intRSNum > 0 Then
Set clsTable = New classTable
'== Set table prameters
clsTable.Border = "0"
clsTable.CellPadding = "2"
clsTable.CellSpacing = "1"
clsTable.Width = "96%"
clsTable.ClassType = GBL_cssListTable
clsTable.Align = "center"
clsTable.MakeTable()
i = 0
'== Set table header
clsTable.AddTitleTr GBL_cssListTitleTr
clsTable.AddTitleTd "鏈接名稱",GBL_cssListTitleTd,"20%"
clsTable.AddTitleTd "鏈接描述",GBL_cssListTitleTd,"25%"
clsTable.AddTitleTd "鏈接地址",GBL_cssListTitleTd,"20%"
clsTable.AddTitleTd "顯示方式",GBL_cssListTitleTd,"20%"
clsTable.AddTitleTd "管理",GBL_cssListTitleTd,"15%"
While Not clsPubDB.objPubRS.Eof
i = i + 1
If (i Mod 2) = 0 Then
strTdClass = GBL_cssListTd1
Else
strTdClass = GBL_cssListTd2
End If
clsTable.AddTr GBL_cssListTr1
clsTable.AddTd clsPubDB.objPubRS("LINK_NAME"),strTdClass
clsTable.AddTd clsPubDB.objPubRS("LINK_DESC"),strTdClass
strHtmlCode = MakeLink("","地址顯示","本鏈接地址：<br>" & clsPubDB.objPubRS("LINK_URL"))
clsTable.AddTd strHtmlCode,strTdClass
If clsPubDB.objPubRS("LINK_LOGO_SET") = 0 Then
strTmp = "文本顯示"
Else
strTmp = MakeLink("","Logo顯示","Logo顯示：<br><img src=" & clsPubDB.objPubRS("LINK_LOGO_IMG") & ">")
End If
clsTable.AddTd strTmp,strTdClass
strHtmlCode1 = MakeImg(GBL_strImgIco & "Admin_top.gif","刪除該鏈接")
strHtmlCode1 = MakeLinkClew("admin/admin_link.asp?action=DelLinkAdmin&LinkId=" & clsPubDB.objPubRS("LINK_ID"),strHtmlCode1,"","onclick=""return confirm('確認刪除本鏈接？')""")
strHtmlCode2 = MakeImg(GBL_strImgIco & "Admin_comm.gif","編輯或查看該鏈接")
strHtmlCode2 = MakeLink("admin/admin_link.asp?action=FormAddLinkAdmin&LinkId=" & clsPubDB.objPubRS("LINK_ID"),strHtmlCode2,"")
clsTable.AddTd strHtmlCode1 & " " & strHtmlCode2,strTdClass
clsPubDB.objPubRS.MoveNext
Wend
clsTable.AddInfoTr "","TOP"
clsTable.AddInfoTd MakeTitle("友情鏈接列表"),GBL_cssListTd2
i = i + 1
If (i Mod 2) = 0 Then
strTdClass = GBL_cssListTd1
Else
strTdClass = GBL_cssListTd2
End If
i = i + 2
If (i Mod 2) = 0 Then
strTdClass = "CSS_TD_LEFT1"
Else
strTdClass = "CSS_TD_LEFT2"
End If
clsTable.AddInfoTr "","BOTTOM"
strHtmlCode = MakeImg(GBL_strImgIco & "Admin_top.gif","")
clsTable.AddInfoTd "圖例：" & strHtmlCode & " →刪除該鏈接",strTdClass
i = i + 1
If (i Mod 2) = 0 Then
strTdClass = "CSS_TD_LEFT1"
Else
strTdClass = "CSS_TD_LEFT2"
End If
clsTable.AddInfoTr "","BOTTOM"
strHtmlCode = MakeImg(GBL_strImgIco & "Admin_comm.gif","")
clsTable.AddInfoTd "圖例：" & strHtmlCode & " →編輯或查看該鏈接設置",strTdClass
i = i + 1
If (i Mod 2) = 0 Then
strTdClass = "CSS_TD_LEFT1"
Else
strTdClass = "CSS_TD_LEFT2"
End If
clsTable.AddInfoTr "","BOTTOM"
strHtmlCode = MakeLink("admin/admin_link.asp?action=FormAddLinkAdmin",MakeTitle("增加新的友情鏈接"),"增加新的友情鏈接,交換鏈接")
clsTable.AddInfoTd strHtmlCode,strTdClass
Response.Write "<br>"
clsTable.OutPutTable()
Response.Write "<br>"
Set clsTable = Nothing
Else
Response.Write "<center>本欄目：目前沒有友情鏈接記錄或已被刪除</center>"
strHtmlCode = MakeLink("admin/admin_link.asp?action=FormAddLinkAdmin",MakeTitle("增加新的友情鏈接"),"增加新的友情鏈接,交換鏈接")
Response.Write "<center>" & strHtmlCode & "</center>"
End If
End Sub
'================ End of Sub ShowLinkAdmin() =======================
'===================================================================
'= Sub : FormAddLinkAdmin()
'= Time : Created At Jan,03,2004
'= Input : None
'= Called by :
'= Calls :
'= Description : add a new link of your website
'===================================================================
Sub FormAddLinkAdmin()
Dim clsForm
Dim i
Dim strAddInfo
Dim intErrId
Dim GetRSId
Dim strLinkName,strLinkDesc,strLinkUrl,intLogoSet,strLogoLink
Dim LinkId
strLinkName = ""
strLinkDesc = ""
strLinkUrl = "http://"
intLogoSet = 0
strLogoLink = "http://"
LinkId = ""
If Trim(Request.QueryString("LinkId")) <> "" Then
'== edit link set
GetRSId = Trim(Request.QueryString("LinkId"))
strAddInfo = "鏈接"
intErrId = DataCheck("DT_ID",GetRSId ,strAddInfo,"")
Call ResultExecute(intErrId,strAddInfo,"ES_ERR")
LinkId = GetRSId
clsPubDB.Clear()
clsPubDB.TableName = "CLASS_LINK"
clsPubDB.SQLType = "SELECT"
clsPubDB.AddField "*",""
clsPubDB.Where = "LINK_ID=" & GetRSId
clsPubDB.SQLRSExecute()
Call ResultExecute(clsPubDB.intErrNum,"get rs before edit link","ES_ERR")
If clsPubDB.intRSNum <= 0 Then
Call ResultExecute(E_USER_PUB,"該鏈接記錄不存在","ES_ERR")
Else
strLinkName = clsPubDB.objPubRS("LINK_NAME")
strLinkDesc = clsPubDB.objPubRS("LINK_DESC")
strLinkUrl = clsPubDB.objPubRS("LINK_URL")
intLogoSet = clsPubDB.objPubRS("LINK_LOGO_SET")
If intLogoSet = 1 Then
strLogoLink = clsPubDB.objPubRS("LINK_LOGO_IMG")
End If
End If
End If
intErrId = 0
Set clsForm = New classForm
If LinkId <> "" Then
clsForm.Action = GBL_strHomeURL & "admin/admin_link.asp?action=FormSaveAddLinkAdmin&LinkId=" & LinkId
Else
clsForm.Action = GBL_strHomeURL & "admin/admin_link.asp?action=FormSaveAddLinkAdmin"
End If
clsForm.Id = "frmAddLinkAdmin"
clsForm.Name = "frmAddLinkAdmin"
clsForm.OnSubmit = "return CheckFormAddLinkAdmin()"
clsForm.ColumnScale = "30%"
clsForm.MakeForm()
clsForm.MakeTable "0","3","1","center","98%",GBL_cssFormTable
clsForm.AddTr GBL_cssFormTitleTr
If LinkId <> "" Then
clsForm.AddTitle "修改本友情鏈接",GBL_cssFormTitleTd
Else
clsForm.AddTitle "增加一個新的友情鏈接",GBL_cssFormTitleTd
End If
clsForm.AddTr GBL_cssFormTr
clsForm.AddTd "*鏈接名稱",GBL_cssFormTdOne,GBL_cssFormTdTwo
clsForm.AddText "iptLinkName",20,30
clsForm.AddValue strLinkName
clsForm.AddTr GBL_cssFormTr
clsForm.AddTd "*鏈接描述",GBL_cssFormTdOne,GBL_cssFormTdTwo
clsForm.AddText "iptLinkDesc",240,30
clsForm.AddValue strLinkDesc
clsForm.AddTr GBL_cssFormTr
clsForm.AddTd "*鏈接地址",GBL_cssFormTdOne,GBL_cssFormTdTwo
clsForm.AddText "iptLinkUrl",240,30
clsForm.AddValue strLinkUrl
clsForm.AddTr GBL_cssFormTr
clsForm.AddTd "*鏈接設定",GBL_cssFormTdOne,GBL_cssFormTdTwo
clsForm.AddRadio "rdoLogoSet",0,"文字顯示",intLogoSet
clsForm.AddRadio "rdoLogoSet",1,"Logo顯示 (鏈接的顯示方式)",intLogoSet
clsForm.AddTr GBL_cssFormTr
clsForm.AddTd "Logo地址",GBL_cssFormTdOne,GBL_cssFormTdTwo
clsForm.AddText "iptLogoLink",240,30
clsForm.AddValue strLogoLink
If intLogoSet = 1 Then
clsForm.AddTr GBL_cssFormTr
clsForm.AddTd "Logo預覽",GBL_cssFormTdOne,GBL_cssFormTdTwo
clsForm.AddLine "<img src=" & strLogoLink & " onload=""DrawImage(this,150,50,1)"">"
End If
clsForm.AddTr GBL_cssFormSubTr
clsForm.AddSubTd GBL_cssFormSubTd
clsForm.AddSub "subFormAddLinkAdmin","提 交","submit"
clsForm.AddSub "rstFormAddLinkAdmin","重 來","reset"
clsForm.OutPutForm()
Set clsForm = Nothing
End Sub
'================ End of Sub FormAddLinkAdmin() ====================
'===================================================================
'= Sub : FormSaveAddLinkAdmin()
'= Time : Created At Jan,03,2004
'= Input : None
'= Called by :
'= Calls :
'= Table : INSERT _LINK,
'= Description : add a new link of your website
'===================================================================
Sub FormSaveAddLinkAdmin()
Dim intErrId
Dim strAddInfo
Dim strLinkName,strLinkDesc,strLinkUrl,strLinkLogo,intLogoSet
Dim GetRSId
GetRSId = ""
intErrId = 0
If Trim(Request.QueryString("LinkId")) <> "" Then
GetRSId = Trim(Request.QueryString("LinkId"))
strAddInfo = "鏈接"
intErrId = DataCheck("DT_ID",GetRSId ,strAddInfo,"")
Call ResultExecute(intErrId,strAddInfo,"ES_ERR")
End If
strLinkName = Trim(Request.Form("iptLinkName"))
strAddInfo = "鏈接名稱"
intErrId = DataCheck("DT_FIX_LENGTH",strLinkName,strAddInfo,"4|DTC_LESS_MORE_LEN|20|")
Call ResultExecute(intErrId,strAddInfo,"ES_ERR")
strLinkDesc = Trim(Request.Form("iptLinkDesc"))
strAddInfo = "鏈接描述"
intErrId = DataCheck("DT_FIX_LENGTH",strLinkDesc,strAddInfo,"4|DTC_LESS_MORE_LEN|240|")
Call ResultExecute(intErrId,strAddInfo,"ES_ERR")
strLinkUrl = Trim(Request.Form("iptLinkUrl"))
strAddInfo = "鏈接地址"
intErrId = DataCheck("DT_FIX_LENGTH",strLinkUrl,strAddInfo,"8|DTC_LESS_MORE_LEN|200|")
Call ResultExecute(intErrId,strAddInfo,"ES_ERR")
intErrId = DataCheck("DT_HEAD_INC_CHAR",strLinkUrl,strAddInfo,"http://")
Call ResultExecute(intErrId,strAddInfo,"ES_ERR")
intLogoSet = Trim(Request.Form("rdoLogoSet"))
strAddInfo = "鏈接設定"
intErrId = DataCheck("DT_ENUM",intLogoSet,strAddInfo,"0,1")
Call ResultExecute(intErrId,strAddInfo,"ES_ERR")
If intLogoSet = 1 Then
strLogoLink = Trim(Request.Form("iptLogoLink"))
strAddInfo = "Logo地址"
intErrId = DataCheck("DT_FIX_LENGTH",strLogoLink,strAddInfo,"8|DTC_LESS_MORE_LEN|240|")
Call ResultExecute(intErrId,strAddInfo,"ES_ERR")
intErrId = DataCheck("DT_HEAD_INC_CHAR",strLogoLink,strAddInfo,"http://")
Call ResultExecute(intErrId,strAddInfo,"ES_ERR")
End If
clsPubDB.Clear()
clsPubDB.TableName = "CLASS_LINK"
If GetRSId <> "" Then
clsPubDB.SQLType = "UPDATE"
clsPubDB.Where = "LINK_ID=" & GetRSId
Else
clsPubDB.SQLType = "INSERT"
End If
clsPubDB.AddField "LINK_NAME",strLinkName
clsPubDB.AddField "LINK_URL",strLinkUrl
clsPubDB.AddField "LINK_DESC",strLinkDesc
clsPubDB.AddField "LINK_LOGO_SET",intLogoSet
If intLogoSet = 1 Then
clsPubDB.AddField "LINK_LOGO_IMG",strLogoLink
End If
clsPubDB.SQLExecute()
Call ResultExecute(clsPubDB.intErrNum,"add a link","ES_ERR")
Call MakeLinkAdmin()
If GetRSId <> "" Then
Call ResultExecute(320,"修改了本友情鏈接","ES_SUCC")
Else
Call ResultExecute(320,"增加了一個友情鏈接","ES_SUCC")
End If
End Sub
'================ End of Sub FormSaveAddLinkAdmin()=================
'===================================================================
'= Sub : DelLinkAdmin()
'= Time : Created At Jan,03,2004
'= Input : None
'= Called by :
'= Calls :
'= Table : DELETE _LINK,
'= Description : Show the link
'===================================================================
Sub DelLinkAdmin()
Dim intErrId
Dim strAddInfo
Dim GetRSId
intErrId = 0
GetRSId = Trim(Request.QueryString("LinkId"))
strAddInfo = "名稱"
intErrId = DataCheck("DT_ID",GetRSId ,strAddInfo,"")
Call ResultExecute(intErrId,strAddInfo,"ES_ERR")
clsPubDB.Clear()
clsPubDB.TableName = "CLASS_LINK"
clsPubDB.SQLType = "DELETE"
clsPubDB.Where = "LINK_ID=" & GetRSId
clsPubDB.SQLExecute()
Call ResultExecute(clsPubDB.intErrNum,"del link","ES_ERR")
Call MakeLinkAdmin()
Call ResultExecute(320,"刪除了本友情鏈接","ES_SUCC")
End Sub
'================ End of Sub DelLinkAdmin() ========================
'===================================================================
'= Sub : MakeLinkAdmin()
'= Time : Created At June,26,2004
'= Input : None
'= Called by :
'= Calls :
'= Table : _LINK,
'= Description : make the link file
'===================================================================
Sub MakeLinkAdmin()
Dim strTmp
strTmp = ShowColumnLinkCode
If CheckObjInstalled("Scripting.FileSystemObject","") Then
Call fsoWriteToFile(strTmp,GBL_strHomeURL & "html/make_link.html",10)
Response.Write " ·友情鏈接文件生成完成!!<br>"
Response.Write " ·路徑：" & GBL_strHomeURL & "html/make_link.html<br>"
End If
End Sub
'=============== End of Sub MakeLinkAdmin() ========================
'=============== FUNCTION BODY END =================================
%>
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -