<%
'===================================================================
'= ASP FILENAME	: /dialog/dialog_collection_save.asp
'= CREATED TIME : 2006-5-5
'= LAST MODIFIED: 2006-5-5
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 加為收藏
'= Change Log:
'===================================================================
%>
<!-- #include file = "../inc/customer/include_customer_action_execute.asp" -->
<!-- #include file = "./dialog_inc.asp" -->
<!-- #include file = "../inc/logic/logic_collection.asp" -->
<%
'========================================================
'==   Action參數設置
'========================================================
'== 頁面名
Const CONST_PAGE_FILE	= "dialog/dialog_collection_save.asp"

'== 頁面標題/功能
Const CONST_PAGE_TITLE	= "加為收藏"

'== 功能函數名字空間
Const CONST_ACTION_FUNC	= "FormSaveAddCollectionCtl"

'== 相對根目錄路徑 
GBL_strHomeURL			= "../"

'== 在模板中引用的標簽變量
Dim TAG_strVerifyCode
Dim TAG_strClew

'== 頁面構造
Call ActionBuild()

'== 請求校驗與過濾
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 頁面析構
Call ActionOver()

%>
<%
'===================================================================
'= Function    : LoadPageTpl()
'= Time		   : Created At 2006-5-4
'= Description : 加載頁面模塊
'===================================================================
Function LoadPageTpl()
%>
	<!-- #include file = "../template_c/page_dialog.html.asp" --> 
<%
End Function

'=====================================================================
'= Function    : FormSaveAddCollectionCtl()
'= Time        : Created At 2006-5-6
'= Input       : 
'= Description : 加為收藏
'=====================================================================
Function FormSaveAddCollectionCtl()
	Dim strClew

	'== 服務器端數據校驗
	If Not ServerDataCheck(arrCollectionAddDataChk) Then
		TAG_strClew = "操作失敗，" & GBL_objException.getErrInfo() & "&nbsp;&nbsp;<span onclick='javascript:window.close();' style='cursor:hand'><u>[關閉窗口]</u></span>"
		GBL_objException.errReset()
		Exit Function
	End If

	'== 數據獲取
	Call CnvFormData(strCollectionAddFormName,GBL_objFormData)

	Select Case GBL_objFormData.Item("Type")
		Case	0	:
				strClew = "您已經添加此用戶為我的好友"
		Case	1	:
				strClew = "您已經添加此帖子為我的收藏"
		Case	2	:
				strClew = "您已經添加此相片為我的收藏"
	End Select

	'== 添加
	If Not SaveCollectionLogic(GBL_intUserId,GBL_objFormData) Then
		strClew = GBL_objException.getErrInfo()
		TAG_strClew = "操作失敗，" & strClew & "<span onclick='javascript:window.close();' style='cursor:hand'><u>[關閉窗口]</u></span>"
		GBL_objException.errReset()
		Exit Function
	Else
		TAG_strClew = "操作成功，" & strClew & "&nbsp;&nbsp;<span onclick='javascript:window.close();' style='cursor:hand'><u>[關閉窗口]</u></span>"
	End If
 
End Function
%>