<%
''===================================================================
'= ASP FILENAME	: /album/album_add_save.asp
'= CREATED TIME : 2006-5-5
'= LAST MODIFIED: 2006-5-5
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 添加相片
'= Change Log:
'==================================================================='
%>
<!-- #include file = "../inc/customer/include_customer_action_execute.asp" -->
<!-- #include file = "./album_inc.asp" -->
<!-- #include file = "../inc/logic/logic_album.asp" -->
<!-- #include file = "../class/class_file_up.asp" -->
<%
'========================================================
'==   Action參數設置
'========================================================
'== 頁面名
Const CONST_PAGE_FILE	= "album/album_add_save.asp"

'== 頁面標題/功能
Const CONST_PAGE_TITLE	= "添加相片"

'== 功能函數名字空間
Const CONST_ACTION_FUNC	= "FormSaveUpPhotoCtl"

'== 相對根目錄路徑 
GBL_strHomeURL			= "../"

'== 頁面構造
Call ActionBuild()

'== 請求校驗與過濾
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 頁面析構
Call ActionOver()

%>

<%
''===================================================================
'= Function    : FormSaveUpPhotoCtl()
'= Time		   : Created At 2006-5-5
'= Input       : 
'= Description : 添加相片
'==================================================================='
Function FormSaveUpPhotoCtl()
	Dim strFormName,strPicName,strHtmlCode,strSuccUrl,strInfo

	'== 上傳文件
	If Not UpLoadAlbumFileLogic("file1",strPicName,GBL_objFormData) Then Exit Function

	'== 服務器端數據校驗(muti-data類型不能做通用數據校驗)
	GBL_blnServerDataCheck = False

	Dim strPicTitle : strPicTitle = GBL_objFormData.Item("PicTitle")
	strInfo = "相片標題"
	If DataCheck(arrAlbumAddDataChk(0)(0),strPicTitle,strInfo,"1|DTC_LESS_MORE_LEN|20|") Then
		Call GBL_objException.catchErr(E_DATA_PUB,strInfo)
		FormSaveUpPhotoCtl = False
		Exit Function
	End If
	Dim strPicType : strPicType = GBL_objFormData.Item("PicType")
	strInfo = "相片類型"
	If DataCheck(arrAlbumAddDataChk(1)(0),strPicType,strInfo,arrAlbumAddDataChk(1)(3)) Then
		Call GBL_objException.catchErr(E_DATA_PUB,strInfo)
		FormSaveUpPhotoCtl = False
		Exit Function
	End If
	
	'== 數據獲取
	'Call CnvFormData(strAlbumAddFormName,GBL_objFormData)

	'== 保留上傳記錄
	If Not SaveAlbumLogic(GBL_intUserId,GBL_objFormData,strPicName) Then Exit Function

	'== Update user photo number
	Call RecordCounter("CLASS_USER","USER_PHOTO",1,"AND USER_ID=" & GBL_intUserId)

	'== Update user level
	Call UpdateLevel(GBL_intAlbumLevel)

	'== 成功處理
	strHtmlCode = "您上傳文件成功"
	strSuccUrl = "album/album_list.asp"
	Call SuccExecute(strHtmlCode,strSuccUrl)

End Function

%>