<%
'===================================================================
'= ASP FILENAME	: /forum/forum_good.asp
'= CREATED TIME : 2006-6-24
'= LAST MODIFIED: 2006-6-24
'= VERSION INFO : CCASP Framework Ver 2.0.1 ALL RIGHTS RESERVED BY www.cclinux.com
'= DESCRIPTION  : 帖子設置為精華
'= Change Log:
'===================================================================
%>

<!-- #include file = "../inc/customer/include_customer_action_execute.asp" -->
<!-- #include file = "../main_func.asp" -->
<!-- #include file = "./forum_inc.asp" -->
<!-- #include file = "./forum_func.asp" -->

<%
'========================================================
'==   Action參數設置
'========================================================
'== 頁面名
Const CONST_PAGE_FILE	= "forum/forum_good.asp"

'== 頁面標題/功能
Const CONST_PAGE_TITLE	= "帖子設置為精華"

'== 功能函數名字空間
Const CONST_ACTION_FUNC	= "SetTopicsGoodCtl"

'== 相對根目錄路徑 
GBL_strHomeURL			= "../"

'== 頁面構造
Call ActionBuild()

'== 請求校驗與過濾
Call ActionFilter(CONST_PAGE_FILE,CONST_ACTION_FUNC)

'== 頁面析構
Call ActionOver()

%>
<%
'===================================================================
'= Sub         : SetTopicsGoodCtl()
'= Time		   : Created At 2006-6-25
'= Input       : None
'= Description : 帖子設置為精華
'===================================================================
Sub SetTopicsGoodCtl()

	Dim clsForm			'== Class of form
	Dim strHtmlCode
	Dim ForumId,TopicsId,strSet,intSet

	
	ForumId = Trim(Request.QueryString("ForumId"))
	If Not IsNumeric(ForumId) Then
		Call ResultExecute(E_USER_PUB,"論壇ForumId錯誤","ES_ERR")
		Exit Sub
	End If

	TopicsId = Trim(Request.QueryString("TopicsId")) 
	If Not IsNumeric(TopicsId) Then
		Call ResultExecute(E_USER_PUB,"論壇TopicsID錯誤","ES_ERR")
		Exit Sub
	End If

	If GBL_strUserAuthen <> 1 And Not GetMaster(ForumId) Then
		Call ResultExecute(E_USER_PUB,"你沒有操作權限","ES_ERR")
		Exit Sub
	End If

	strSet = Trim(Request.QueryString("ACT_MODE"))
	If strSet <> "ACT_SET_GOOD" And strSet <> "ACT_UN_GOOD" Then
		Call ResultExecute(E_USER_PUB,"錯誤的處理提交","ES_ERR")
		Exit Sub
	End If

	If strSet = "ACT_SET_GOOD" Then
		intSet = 1
	Else
		intSet = 0
	End If

	GBL_objPubDB.Clear()
	GBL_objPubDB.AllSQL = "UPDATE CLASS_TOPICS SET TOPICS_GOOD=" & intSet & " WHERE TOPICS_ID=" & TopicsId 
	GBL_objPubDB.SQLExecute()
	Call ResultExecute(GBL_objPubDB.intErrNum,"set good topics","ES_ERR")

	Set GBL_objPubDB = Nothing
	Response.Redirect GBL_strHomeURL & "forum/forum_show.asp?action=ShowForumContent&TopicsId=" & TopicsId & "&ForumId=" & ForumId


End Sub
%>