?PR?IR?DS18B20      SEGMENT CODE 
	PUBLIC	IR
	RSEG  ?PR?IR?DS18B20
	
			;以下為進入P2.2腳外部中斷子程序，也就是解碼程序
IR: 
  	MOV 	R6,#9
SB:
	ACALL 	DELAY882	;調用882微秒延時子程序
	JB 	P2.2,EXIT	;延時882微秒后判斷P2.2腳是否出現高電平如果有就退出解碼程序
 	DJNZ 	R6, SB	;重復10次，目的是檢測在8820微秒內如果出現高電平就退出解碼程序
               		;以上完成對遙控信號的9000微秒的初始低電平信號的識別。
	JNB	P2.2, $ 	;等待高電平避開9毫秒低電平引導脈沖
	ACALL	DELAY2400
	JNB	P2.2,IR_Rp	;
	ACALL	DELAY2400   ;延時4.74毫秒避開4.5毫秒的結果碼
	MOV	R1,#1AH 	;設定1AH為起始RAM區
	MOV	R2,#4 
PP: 	
	MOV	R3,#8
JJJJ:	
	JNB	P2.2,$	;等待地址碼第一位的高電平信號
	LCALL DELAY882	;高電平開始后用882微秒的時間尺去判斷信號此時的高低電平狀態
	MOV	C,P2.2	;將P2.2引腳此時的電平狀態0或1存入C中
	JNC	UUU		;如果為0就跳轉到UUU
	LCALL DELAY1000
UUU: 
	MOV	A,@R1		;將R1中地址的給A
	RRC	A		;將C中的值0或1移入A中的最低位
	MOV	@R1,A	;將A中的數暫時存放在R1中
	DJNZ	R3,JJJJ	;接收地址碼的高8位
	INC	R1		;對R1中的值加1，換下一個RAM
	DJNZ	R2,PP 	;接收完16位地址碼和8位數據碼和8位數據，存放在1AH/1BH/1CH/1DH的RAM中

      //MOV	P1,1DH	;將按鍵的鍵值通過P1口的8個LED顯示出來!
        
	CLR	P2.3	;蜂鳴器鳴響－嘀嘀嘀－的聲音，表示解碼成功
	LCALL DELAY2400
	LCALL DELAY2400
	LCALL DELAY2400
	SETB P2.3;蜂鳴器停止

EXIT:	
        MOV     R7,#0FFH
        MOV     A,1DH      
        MOV     R7,A
	ret ;退出解碼子程序
	   
IR_Rp:
	LJMP	IR




;=============================882
DELAY882: ;1.085x ((202x4)+5)=882
	MOV	R7,#202
    DELAY882_A:
    	NOP
	NOP
	DJNZ	R7,DELAY882_A
RET
;=============================1000
DELAY1000: ;1.085x ((229x4)+5)=999.285
	MOV	R7,#229
    DELAY1000_A:
    	NOP
	NOP
	DJNZ	R7,DELAY1000_A
RET
;=============================2400
DELAY2400: ;1.085x ((245x9)+5)=2397.85
	MOV	R7,#245
    DELAY2400_A:
    	NOP
	NOP
    	NOP
	NOP
	NOP
   	NOP
	NOP
	DJNZ	R7,DELAY2400_A
RET
END