//========================================================
//	文件名稱：	isr.asm
//	功能描述：	中斷程序
//	維護(hù)記錄：	2005-10-17	v1.0
//========================================================
.TEXT
.INCLUDE	hardware.inc
.INCLUDE	S480.inc
.INCLUDE	Key.inc
//============================================================================================
//匯編格式：	_FIQ
//實(shí)現(xiàn)功能：	中斷服務(wù)子程序，在FIQ_TMA中斷中調(diào)用F_FIQ_Service_SACM_S480函數(shù)解碼并播放
//參數(shù)：		無(wú)
//返回值：		無(wú)	
//破壞寄存器：	無(wú)
//=============================================================================================
.PUBLIC	_FIQ;
_FIQ:
	PUSH	r1,r4 to [sp];
	r1=0x2000;
	test r1,[P_INT_Ctrl];
	jnz L_FIQ_TimerA;
	r1=0x0800;
	test r1,[P_INT_Ctrl];
	jnz L_FIQ_TimerB;
L_FIQ_PWM:
	r1=C_FIQ_PWM;
	[P_INT_Clear]=r1;
	POP R1,R4 from[sp];
	reti;
L_FIQ_TimerA:
	[P_INT_Clear]=r1;
	call F_FIQ_Service_SACM_S480;         //調(diào)用F_FIQ_Service_SACM_S480解碼
	pop r1,r4 from [sp];
	reti;
L_FIQ_TimerB:
	[P_INT_Clear]=r1;
	pop r1,r4 from [sp];
	reti;

//============================================================================================
//匯編格式：	_IRQ6
//實(shí)現(xiàn)功能：	中斷服務(wù)子程序，在IRQ6的TMB2 128Hz中斷當(dāng)中調(diào)用掃鍵程序
//參數(shù)：		無(wú)
//返回值：		無(wú)
//破壞寄存器：	無(wú)
//=============================================================================================	
.PUBLIC _IRQ6
_IRQ6:        
   	PUSH r1,r4 to [sp];
	r1=0x0001;
	TEST r1,[P_INT_Ctrl];
	JNZ  _IRQ6_TMB2;
	r1=0x0002;
	[P_INT_Clear]=r1;
	POP r1,r4 FROM [sp];
    RETI;         
_IRQ6_TMB2:
	[P_INT_Clear]=r1;
	CALL	F_Key_Scan;                                     //掃描鍵盤
	POP r1,r4 FROM [sp];
    RETI;  
    
//============================================================================================
//匯編格式： 	_Initial_INT
//C語(yǔ)言格式：	void Initial_INT(void)
//實(shí)現(xiàn)功能：	初始化中斷狀態(tài)，以通知音頻程序，目前已打開(kāi)的中斷情況
//參數(shù)：		無(wú)
//返回值：		無(wú)
//破壞寄存器：	無(wú)
//=============================================================================================	
.CODE
.DEFINE		P_INT_Ctrl_New			0x702D		// Same as P_INT_Mask
.PUBLIC _Initial_INT
_Initial_INT:
	r1 = [R_InterruptStatus]					//在hardware.asm當(dāng)中定義
	r2 = [P_INT_Ctrl_New]
	r1 = r1|r2
	[R_InterruptStatus] = r1
	retf