#include  "msp430x44x.h"
;******************************************************************************
;   MSP-FET430P440 Demo - USART1 UART 38400 Echo ISR, DCO SMCLK
;
;   Description; Echo a received character, RX ISR used. Normal mode is LPM0, 
;   USART1 RX interrupt triggers TX Echo. 
;   ACLK = LFXT1 = 32768Hz  MCLK = SMCLK = UCLK1 = DCOCLK = 1048576
;   Baud rate divider with 1048576hz = 1048576Hz/38400 ~ 27 (001Bh)
;   //*An external watch crystal on XIN XOUT is required for ACLK*//	  
;              
;                MSP430F449
;             -----------------
;         /|\|              XIN|-  
;          | |                 | 32768Hz  
;          --|RST          XOUT|-
;            |                 |
;            |             P4.0|-----------> 
;            |                 | 38400 - 8N1
;            |             P4.1|<-----------
;
;   M.Buccini
;   Texas Instruments, Inc
;   January 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     01100h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #0A00h,SP               ; Initialize '449 stackpointer
            call    #Init_Sys               ;
                                            ;   
Mainloop    bis.b   #LPM0,SR                ; Enter LPM0
            jmp     Mainloop                ; Do nothing
                                            ;
;------------------------------------------------------------------------------ 
Init_Sys;   Initalize MSP430 system
;------------------------------------------------------------------------------ 
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; Stop WDT
SetupFLL    bis.b   #XCAP14PF,&FLL_CTL0     ; Configure load caps
SetupUART1  mov.b   #SSEL1,&UTCTL1          ; UCLK = SMCLK
            mov.b   #CHAR,&UCTL1            ; 8-bit characters *SWRST*
            mov.b   #01Bh,&UBR01            ; 1MHz 38400 
            mov.b   #000h,&UBR11            ; 1MHz 38400
            mov.b   #000h,&UMCTL1           ;  no modulation 
            bis.b   #UTXE1+URXE1,&ME2       ; Enable USART1 TXD/RXD
            bis.b   #URXIE1,&IE2            ; Enable USART1 RX interrupt
SetupP3     bis.b   #003h,&P4SEL            ; P4.0,1 = USART1 TXD/RXD
            bis.b   #001h,&P4DIR            ; P4.0 = output direction 
            eint                            ; General enable interrupts
            ret                             ; Return from subroutine
                                            ;             
;------------------------------------------------------------------------------ 
USART1RX_ISR;  Echo back RXed character, confirm TX buffer is ready first
;------------------------------------------------------------------------------ 
TX1         bit.b   #UTXIFG1,&IFG2          ; USART1 TX buffer ready?
            jz      TX1                     ; Jump if TX buffer not ready
            mov.b   &RXBUF1,&TXBUF1         ; TX -> RXed character
            reti                            ; 
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors Used MSP430x44x       
;------------------------------------------------------------------------------ 
            ORG     0FFFEh                  ; 
            DW      RESET                   ; POR, ext. Reset, Watchdog
            ORG     0FFE6h                  ; 
            DW      USART1RX_ISR            ; USART1 receive
            end