#include  "msp430x44x.h"
;******************************************************************************
;   MSP-FET430P440 Demo - USART0 UART 9600 Echo ISR, DCO SMCLK 
;
;   Description; Echo a received character, RX ISR used. Normal mode is LPM0, 
;   USART0 RX interrupt triggers TX Echo. 
;   ACLK = LFXT1 = 32768Hz,  MCLK = SMCLK = UCLK0 = DCOCLK = 1048576
;   Baud rate divider with 1048576hz = 1048576Hz/9600 ~ 109 (006Dh)
;   //*An external watch crystal on XIN XOUT is required for ACLK*//	  
;              
;                MSP430F449
;             -----------------
;         /|\|              XIN|-  
;          | |                 | 32768Hz  
;          --|RST          XOUT|-
;            |                 |
;            |             P2.4|-----------> 
;            |                 | 9600 - 8N1
;            |             P2.5|<-----------
;
;   M.Buccini
;   Texas Instruments, Inc
;   January 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     01100h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #0A00h,SP               ; Initialize '449 stackpointer
            call    #Init_Sys               ;
                                            ;   
Mainloop    bis.b   #LPM0,SR                ; Enter LPM0
            jmp     Mainloop                ; Do nothing
                                            ;
;------------------------------------------------------------------------------ 
Init_Sys;   Initalize MSP430 system
;------------------------------------------------------------------------------ 
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; Stop WDT
SetupFLL    bis.b   #XCAP14PF,&FLL_CTL0     ; Configure load caps
SetupUART0  mov.b   #SSEL1,&UTCTL0          ; UCLK = SMCLK
            mov.b   #06Dh,&UBR00            ; 1MHz 9600 
            mov.b   #000h,&UBR10            ; 1MHz 9600
            mov.b   #000h,&UMCTL0           ; no modulation 
            mov.b   #CHAR,&UCTL0            ; 8-bit characters *SWRST*
            bis.b   #UTXE0+URXE0,&ME1       ; Enable USART0 TXD/RXD
            bis.b   #URXIE0,&IE1            ; Enable USART0 RX interrupt
SetupP3     bis.b   #030h,&P2SEL            ; P2.4,5 = USART0 TXD/RXD
            bis.b   #010h,&P2DIR            ; P2.4 = output direction 
            eint                            ; General enable interrupts
            ret                             ; Return from subroutine
                                            ;             
;------------------------------------------------------------------------------ 
USART0RX_ISR;  Echo back RXed character, confirm TX buffer is ready first
;------------------------------------------------------------------------------ 
TX0         bit.b   #UTXIFG0,&IFG1          ; USART0 TX buffer ready?
            jz      TX0                     ; Jump if TX buffer not ready
            mov.b   &RXBUF0,&TXBUF0         ; TX -> RXed character
            reti                            ; 
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors Used MSP430x44x       
;------------------------------------------------------------------------------ 
            ORG     0FFFEh                  ; 
            DW      RESET                   ; POR, ext. Reset, Watchdog
            ORG     0FFF2h                  ; 
            DW      USART0RX_ISR            ; USART0 receive
            end