;T16550-2.asm
;16550與PC機串口通信
;***************根據(jù)CHECK配置信息修改下列符號值*******************
INTR_IVADD   EQU   01CCH          ;INTR對應(yīng)的中斷矢量地址
INTR_OCW1    EQU   0A1H           ;INTR對應(yīng)PC機內(nèi)部8259的OCW1地址
INTR_OCW2    EQU   0A0H           ;INTR對應(yīng)PC機內(nèi)部8259的OCW2地址
INTR_IM      EQU   0F7H           ;INTR對應(yīng)的中斷屏蔽字
PCI_INTCSR   EQU   9438H          ;PCI卡中斷控制寄存器地址
IOY0         EQU   9C00H          ;片選IOY0對應(yīng)的端口始地址
;****************************************************************
MY16550_0    EQU   IOY0+00H*4     ;16550數(shù)據(jù)緩沖寄存器端口地址
MY16550_1    EQU   IOY0+01H*4     ;16550中斷允許寄存器端口地址
MY16550_3    EQU   IOY0+03H*4     ;16550線路控制寄存器端口地址

PC_COM1_0    EQU   03F8H          ;PC機COM1數(shù)據(jù)緩沖寄存器端口地址
PC_COM1_1    EQU   03F9H          ;PC機COM1中斷允許寄存器端口地址
PC_COM1_3    EQU   03FBH          ;PC機COM1線路控制寄存器端口地址

STACK1 SEGMENT STACK
        DW 256 DUP(?)
STACK1 ENDS

DATA SEGMENT 
CS_BAK   DW  ?                    ;保存INTR原中斷處理程序入口段地址的變量
IP_BAK   DW  ?                    ;保存INTR原中斷處理程序入口偏移地址的變量
IM_BAK   DB  ?                    ;保存INTR原中斷屏蔽字的變量
STR1     DB  'Communication with computer!$'    ;字符串
DATA ENDS

CODE SEGMENT
        ASSUME CS:CODE,DS:DATA

START: MOV AX,DATA
       MOV DS,AX
       CLI

       MOV DX,PCI_INTCSR
       SUB DX,19H
       IN  AL,DX 
       MOV DX,PCI_INTCSR          ;初始化PCI卡中斷控制寄存器
       MOV AX,1F00H               ;向PCI_INTCSR中寫入003F1F00H
       OUT DX,AX
       ADD DX,2
       MOV AX,003FH
       OUT DX,AX

       MOV AX,0000H               ;替換INTR的中斷矢量
       MOV ES,AX
       MOV DI,INTR_IVADD          
       MOV AX,ES:[DI]
       MOV IP_BAK,AX              ;保存INTR原中斷處理程序入口偏移地址
       MOV AX,OFFSET MYISR
       MOV ES:[DI],AX             ;設(shè)置當(dāng)前中斷處理程序入口偏移地址

       ADD DI,2
       MOV AX,ES:[DI]
       MOV CS_BAK,AX              ;保存INTR原中斷處理程序入口段地址
       MOV AX,SEG MYISR
       MOV ES:[DI],AX             ;設(shè)置當(dāng)前中斷處理程序入口段地址

       MOV DX,INTR_OCW1           ;設(shè)置中斷屏蔽寄存器，打開INTR的屏蔽位
       IN  AL,DX
       MOV IM_BAK,AL              ;保存INTR原中斷屏蔽字
       AND AL,INTR_IM
       OUT DX,AL

       MOV DX,PC_COM1_3           ;設(shè)置PC機COM1線路控制寄存器
       MOV AL,80H                 ;準備設(shè)置波特率除數(shù)寄存器
       OUT DX,AL
                
       MOV DX,PC_COM1_0           ;設(shè)置COM1除數(shù)寄存器低字節(jié)0CH
       MOV AL,0CH                 ;000C對應(yīng)9600 bit/s
       OUT DX,AL

       MOV DX,PC_COM1_1           ;設(shè)置COM1除數(shù)寄存器高字節(jié)00H     
       MOV AL,00H
       OUT DX,AL

       MOV DX,PC_COM1_3           ;設(shè)置COM1線路控制寄存器，初始化數(shù)據(jù)格式
       MOV AL,1BH                 ;偶校驗，1位停止位，字符寬度為8
       OUT DX,AL

       MOV DX,PC_COM1_1           ;設(shè)置中斷允許寄存器
       MOV AL,00H                 ;中斷不打開
       OUT DX,AL  
 
       MOV DX,MY16550_3           ;設(shè)置16550線路控制寄存器
       MOV AL,80H                 ;準備設(shè)置波特率除數(shù)寄存器
       OUT DX,AL
 
       MOV DX,MY16550_0           ;設(shè)置除數(shù)寄存器低字節(jié)0CH  
       MOV AL,0CH                 ;000C對應(yīng)9600 bit/s
       OUT DX,AL            
                            
       MOV DX,MY16550_1           ;設(shè)置除數(shù)寄存器高字節(jié)00H
       MOV AL,00H
       OUT DX,AL
       
       MOV DX,MY16550_3           ;設(shè)置線路控制寄存器，初始化數(shù)據(jù)格式
       MOV AL,1BH                 ;偶校驗，1位停止位，字符寬度為8
       OUT DX,AL
           
       MOV DX,MY16550_1           ;設(shè)置中斷允許寄存器
       MOV AL,01H                 ;允許接收緩沖寄存器滿產(chǎn)生中斷
       OUT DX,AL
        
       STI
       MOV BX,OFFSET STR1
       MOV CX,001CH
SEND:  MOV DX,PC_COM1_0           ;將字符串?dāng)?shù)據(jù)寫入COM1發(fā)送緩沖寄存器
       MOV AL,[BX]
       OUT DX,AL              
       INC BX       
       CALL DALLY
       LOOP SEND
         
QUIT:  CLI
       MOV DX,PCI_INTCSR          ;恢復(fù)PCI卡中斷控制寄存器
       MOV AX,0000H
       OUT DX,AX

       MOV AX,0000H               ;恢復(fù)INTR原中斷矢量
       MOV ES,AX
       MOV DI,INTR_IVADD  
       MOV AX,IP_BAK              ;恢復(fù)INTR原中斷處理程序入口偏移地址
       MOV ES:[DI],AX
       ADD DI,2
       MOV AX,CS_BAK              ;恢復(fù)INTR原中斷處理程序入口段地址
       MOV ES:[DI],AX

       MOV DX,INTR_OCW1           ;恢復(fù)INTR原中斷屏蔽寄存器的屏蔽字
       MOV AL,IM_BAK
       OUT DX,AL
       STI

       MOV AX,4C00H               ;返回到DOS
       INT 21H

MYISR PROC NEAR                   ;中斷處理程序MYISR
       MOV DX,MY16550_0           ;讀取16550接收緩沖寄存器數(shù)據(jù)并顯示
       IN  AL,DX
       MOV AH,0EH
       INT 10H

OVER:  MOV DX,PCI_INTCSR
       SUB DX,19H
       IN  AL,DX 
       MOV DX,PCI_INTCSR          ;清PCI卡中斷控制寄存器標志位
       ADD DX,2
       MOV AX,003FH
       OUT DX,AX
       
       MOV DX,INTR_OCW2           ;向PC機內(nèi)部8259發(fā)送中斷結(jié)束命令
       MOV AL,20H
       OUT DX,AL
       MOV AL,20H
       OUT 20H,AL
       IRET
MYISR ENDP

DALLY PROC NEAR                   ;軟件延時子程序
       PUSH CX
       PUSH AX
       MOV CX,0100H
D1:    MOV AX,2000H
D2:    DEC AX
       JNZ D2
       LOOP D1
       POP AX
       POP CX
       RET
DALLY ENDP
   
CODE ENDS
     END START