unit main;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls,
  UnitHookType;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Label1: TLabel;
    Label2: TLabel;
    procedure Button1Click(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure FormCreate(Sender: TObject);

  private
    { Private declarations }
    hMapObj: THandle;
    pShMem: PShareMem;
    fWndClosed: boolean;
    procedure getMouseInfo(var theMess: TMessage); message WM_MOUSEPT;
  public
    { Public declarations }

  end;
var
  Form1: TForm1;

implementation

{$R *.DFM}

{調用32位的DLL進行取詞}

function OpenGetKeyHook(sender: HWND; MessageID: WORD): BOOLean; stdcall; external 'GetWord32.DLL';
{取消取詞}

function CloseGetKeyHook: BOOLean; stdcall; external 'GetWord32.DLL';
{鼠標處理過程}

procedure TForm1.Button1Click(Sender: TObject);
begin
  if button1.caption = '取詞' then
  begin
    OpenGetKeyHook(Form1.Handle, WM_MOUSEPT);
    button1.caption := '取消';
  end
  else begin
    CloseGetKeyHook;
    button1.caption := '取詞';
  end;
end;

procedure TForm1.getMouseInfo(var theMess: TMessage);
begin
  if fWndClosed then
    Exit;
  if theMess.LParam = 1 then
  begin {獲取鼠標信息}
    Label1.caption := format('X:%d Y:%d HWND:%X %s', [pShMem^.pMouse.x, pShMem^.pMouse.y, pShMem^.hHookWnd,
      string(@pShMem^.fStrMouseQueue)]);
    Label2.caption := '';
  end
  else if theMess.LParam = 2 then
  begin
    {進行取詞，獲取緩沖區數據}
    Label1.caption := format('X:%d Y:%d HWND:%X ', [pShMem^.pMouse.x, pShMem^.pMouse.y, pShMem^.hHookWnd]);
    Label2.caption := string(pShMem^.Text);
  end;
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  if button1.caption <> '取詞' then
    Button1Click(Sender);
end;

procedure TForm1.FormCreate(Sender: TObject);
//var
//  wc: TWndClass;
begin
  SetForegroundWindow(self.Handle);
  hMapObj := OpenFileMapping(FILE_MAP_WRITE, {獲得完全訪問權}
    False,
    LPCTSTR(MappingFileName)); {內存映射文件的名字}
  if hMapObj = 0 then
  begin
    ShowMessage('Cannot locate the Share Memory Block!');
    Halt;
  end;
  {pShMem指向內存映象文件}
  pShMem := PShareMem(MapViewOfFile(hMapObj,
    FILE_MAP_WRITE,
    0,
    0,
    0));
  if pShMem = nil then
  begin
    ShowMessage('Map File Mapping Failed! Error ' + IntToStr(GetLastError));
    CloseHandle(hMapObj);
    Halt;
  end;

  FillChar(pShMem^, SizeOf(TShareMem), 0);
  pShMem^.hMainWnd := Self.Handle;
//  pShMem^.MainHinst := hInstance;
  fWndClosed := false;

{  wc.style := 0;
  wc.lpfnWndProc := TFNWndProc(@MouseWndProc);
  wc.cbClsExtra := 0;
  wc.cbWndExtra := 0;
  wc.hInstance := HInstance;
  wc.hIcon := 0;
  wc.hCursor := 0;
  wc.hbrBackground := 0;
  wc.lpszMenuName := nil;
  wc.lpszClassName := 'ZL_MOUSE_WND_PSEUDO';
  Windows.RegisterClass(wc); }
end;

end.