;實(shí)驗(yàn)名稱：字符型LCD接口實(shí)驗(yàn)
;  功能：在LCD上顯示
;	 AT89S51 DEMO
;	www.mcuprog.com
;  作者：http://www.mcuprog.com
;        05-02-01
;

E		BIT	P2.2
RW		BIT	P2.1
RS		BIT	P2.0
LCDPORT		EQU	P0
CMD_BYTE	EQU	30H
DAT_BYTE	EQU	31H

		ORG	0000H
		AJMP	MAIN
		ORG	0050H
MAIN:		MOV	SP,#60H
		LCALL	INITLCD
		LCALL	DISPMSG1
		LCALL	DISPMSG2
		SJMP	$
		
;LCD1602要用到的一些子程序
;寫命令(入口參數(shù)CMD_BYTE)
WRITE_CMD:	CLR	RS
		CLR	RW
		MOV	A,CMD_BYTE
		MOV	LCDPORT,A
		SETB	E
		NOP
		NOP
		CLR	E
		LCALL	DELAY
		RET

;寫顯示數(shù)據(jù)(入口參數(shù)DAT_BYTE)
WRITE_DAT:	SETB	RS
		CLR	RW
		MOV	A,DAT_BYTE
		MOV	LCDPORT,A
		SETB	E
		NOP
		NOP
		CLR	E
		LCALL	DELAY
		RET

;LCD顯示初始化
INITLCD:	MOV	CMD_BYTE,#30H
		LCALL	WRITE_CMD
		MOV	CMD_BYTE,#30H
		LCALL	WRITE_CMD
		MOV	CMD_BYTE,#30H
		LCALL	WRITE_CMD
		MOV	CMD_BYTE,#38H		;設(shè)定工作方式
		LCALL	WRITE_CMD
		MOV	CMD_BYTE,#0CH		;顯示狀態(tài)設(shè)置
		LCALL	WRITE_CMD
		MOV	CMD_BYTE,#01H		;清屏
		LCALL	WRITE_CMD
		MOV	CMD_BYTE,#06H		;輸入方式設(shè)置
		LCALL	WRITE_CMD		
		RET
;在第一行顯示表格1的內(nèi)容
DISPMSG1:	MOV	CMD_BYTE,#80H		//設(shè)置DDRAM的地址
		LCALL	WRITE_CMD
		MOV	R7,#10H
		MOV	R6,#00H
		MOV	DPTR,#TAB1
DISPMSG1_1:	MOV	A,R6
		MOVC	A,@A+DPTR
		MOV	DAT_BYTE,A
		LCALL	WRITE_DAT
		INC	R6
		DJNZ	R7,DISPMSG1_1
		RET

;在第二行顯示表格1的內(nèi)容
DISPMSG2:	MOV	CMD_BYTE,#0C0H		//設(shè)置DDRAM的地址
		LCALL	WRITE_CMD
		MOV	R7,#10H
		MOV	R6,#00H
		MOV	DPTR,#TAB2
DISPMSG2_1:	MOV	A,R6
		MOVC	A,@A+DPTR
		MOV	DAT_BYTE,A
		LCALL	WRITE_DAT
		INC	R6
		DJNZ	R7,DISPMSG2_1
		RET

;延時(shí)子程序
DELAY:		MOV	R5,#0A0H
DELAY1:		NOP
		DJNZ	R5,DELAY1
		RET

		ORG	0200H
;要顯示的內(nèi)容
TAB1:		DB	"REF POWER 18.23 "
TAB2:		DB	"    SWR    1.26 "
		END