?? dig.asm
字號:
//======================================================
// The information contained herein is the exclusive property of
// Sunnnorth Technology Co. And shall not be distributed, reproduced,
// or disclosed in whole in part without prior written permission.
// (C) COPYRIGHT 2003 SUNNORTH TECHNOLOGY CO.
// ALL RIGHTS RESERVED
// The entire notice above must be reproduced on all authorized copies.
//========================================================
//============================================================
// 文件名稱：Dig.asm
// 實現功能：4位共陰數碼管顯示驅動程序，使用IRQ4_4KHz中斷
// 日期： 2005/7/18
//============================================================
//================================================
// LED段控制端口設定
//================================================
.DEFINE SEG_IO_Port 0 // 若LED段選使用IOA口則采用該行定義
//.DEFINE SEG_IO_Port 1 // 若LED段選使用IOB口則采用該行定義
.DEFINE SEG_IO_HighByte 0 // 若LED段選使用IO口低8位則采用該行定義
//.DEFINE SEG_IO_HighByte 1 // 若LED段選使用IO口高8位則采用該行定義
//================================================
// LED位控制端口設定
//================================================
.DEFINE DIG_IO_Port 0 // 若LED位選使用IOA口則采用該行定義
//.DEFINE DIG_IO_Port 1 // 若LED位選使用IOB口則采用該行定義
/////----- 數碼管的位數 -----/////
.DEFINE DIG_Count 4
/////----- 數碼管每一位的控制腳設定 -----/////
.DATA
PIN_DIG:
.DW 0x0100,0x0200,0x0400,0x0800
/////----- 數碼管所有位的控制腳設定，應等于PIN_DIG所有數之和 -----/////
.DEFINE PIN_DIG_ALL 0x0f00
//================================================
// 不必修改下面的定義
//================================================
.IF SEG_IO_Port==0
.DEFINE P_SEG_Data 0x7000
.DEFINE P_SEG_Buf 0x7001
.DEFINE P_SEG_Dir 0x7002
.DEFINE P_SEG_Attrib 0x7003
.ELSE
.DEFINE P_SEG_Data 0x7005
.DEFINE P_SEG_Buf 0x7006
.DEFINE P_SEG_Dir 0x7007
.DEFINE P_SEG_Attrib 0x7008
.ENDIF
.IF SEG_IO_HighByte==0
.DEFINE PIN_SEG_ALL 0x00ff
.ELSE
.DEFINE PIN_SEG_ALL 0xff00
.ENDIF
.IF DIG_IO_Port==0
.DEFINE P_DIG_Data 0x7000
.DEFINE P_DIG_Buf 0x7001
.DEFINE P_DIG_Dir 0x7002
.DEFINE P_DIG_Attrib 0x7003
.ELSE
.DEFINE P_DIG_Data 0x7005
.DEFINE P_DIG_Buf 0x7006
.DEFINE P_DIG_Dir 0x7007
.DEFINE P_DIG_Attrib 0x7008
.ENDIF
//================================================
// 中斷常量定義
//================================================
.DEFINE P_INT_Mask 0x702d
.DEFINE C_IRQ4_4KHz 0x0040
//================================================
// 變量定義
//================================================
.RAM
R_DIG_Buf: .DW DIG_Count DUP (?) // 數碼管顯示緩沖區
.IRAM
R_CurDIG: .DW 0xffff // 當前顯示的數碼管位，0xffff表示不顯示
//================================================
// 公有函數聲明
//================================================
.PUBLIC F_DIG_Init
.PUBLIC _DIG_Init
.PUBLIC F_DIG_Set
.PUBLIC _DIG_Set
.PUBLIC F_DIG_SetAll
.PUBLIC _DIG_SetAll
.PUBLIC F_DIG_Get
.PUBLIC _DIG_Get
.PUBLIC F_DIG_GetAll
.PUBLIC _DIG_GetAll
.PUBLIC F_DIG_Drive
.PUBLIC _DIG_Drive
.PUBLIC F_DIG_Off
.PUBLIC _DIG_Off
.PUBLIC F_DIG_On
.PUBLIC _DIG_On
.code
//======================================================
// 函數名稱： DIG_Init
// C調用： void DIG_Init(void)
// 匯編調用： F_DIG_Init
// 實現功能： 數碼管顯示初始化，該函數將開啟IRQ4_4KHz中斷
// 入口參數： 無
// 出口參數： 無
// 破壞寄存器： 無
//======================================================
_DIG_Init:
F_DIG_Init:
push r1,bp to [sp]
INT Off
r1 = DIG_Count
r2 = 0x0000
bp = R_DIG_Buf
?DIG_InitBuf: // 清除顯示緩沖區
[bp++] = r2
r1 -= 1
jnz ?DIG_InitBuf
[R_CurDIG] = r2 // 當前顯示的位設置為0
r1 = [P_SEG_Attrib] // 初始化段選IO
r1 |= PIN_SEG_ALL
[P_SEG_Attrib] = r1
r1 = [P_SEG_Buf]
r1 &= ~PIN_SEG_ALL
[P_SEG_Data] = r1
r1 = [P_SEG_Dir]
r1 |= PIN_SEG_ALL
[P_SEG_Dir] = r1
r1 = [P_DIG_Attrib] // 初始化位選IO
r1 |= PIN_DIG_ALL
[P_DIG_Attrib] = r1
r1 = [P_DIG_Buf]
r1 &= ~PIN_DIG_ALL
[P_DIG_Buf] = r1
r1 = [P_DIG_Dir]
r1 |= PIN_DIG_ALL
[P_DIG_Dir] = r1
r1 = [P_INT_Mask] // 開啟IRQ4_4KHz中斷
r1 |= C_IRQ4_4KHz
[P_INT_Mask] = r1
INT FIQ,IRQ
pop r1,bp from [sp]
retf
//======================================================
// 函數名稱： DIG_Set
// C調用： void DIG_Set(unsigned DigPos, unsigned DigBuffer)
// 匯編調用： F_DIG_Set
// 實現功能： 設置數碼管某一位的顯示內容
// 入口參數： DigPos(r1) - 設置的數碼管位（1~DIG_Count）
// DigBuffer(r2) - 數碼管的顯示內容
// 出口參數： 無
// 破壞寄存器： 無
//======================================================
_DIG_Set:
push r1,r2 to [sp]
r1 = sp + 5
r1 = [r1]
r2 = sp+6
r2 = [r2]
call F_DIG_Set
pop r1,r2 from [sp]
retf
F_DIG_Set:
push bp to [sp]
.IF SEG_IO_HighByte==1
r2 = r2 lsl 4
r2 = r2 lsl 4
.ENDIF
r1 -= 1
cmp r1,DIG_Count // 如果"位"值超出范圍則退出
ja ?Exit
bp = R_DIG_Buf // 將R_DIG_Buf的相應元素修改為設定值
bp += r1
[bp] = r2
?Exit:
pop bp from [sp]
retf
//======================================================
// 函數名稱： DIG_SetAll
// C調用： void DIG_SetAll(unsigned *DigBuffer)
// 匯編調用： F_DIG_SetAll
// 實現功能： 設置所有數碼管的顯示內容
// 入口參數： DigBuffer(r1) - 數碼管顯示內容的起始地址
// 出口參數： 無
// 破壞寄存器： 無
//======================================================
_DIG_SetAll:
push bp to [sp]
bp = sp
r1 = [bp+4]
call F_DIG_SetAll
pop bp from [sp]
retf
F_DIG_SetAll:
push r2,bp to [sp]
bp = r1
r2 = DIG_Count
r3 = R_DIG_Buf
?DIG_Set_Loop:
r1 = [bp++] // 將R_DIG_Buf修改為設定值
.IF SEG_IO_HighByte==1
r1 = r1 lsl 4
r1 = r1 lsl 4
.ENDIF
[r3++] = r1
r2 -= 1
jnz ?DIG_Set_Loop
pop r2,bp from [sp]
retf
//======================================================
// 函數名稱： DIG_Get
// C調用： unsigned DIG_Get(unsigned DigPos)
// 匯編調用： F_DIG_Get
// 實現功能： 獲取所有數碼管的顯示內容
// 入口參數： DigPos(r1) - 要獲取顯示內容的位
// 出口參數： 該位數碼管的顯示內容
// 破壞寄存器： 無
//======================================================
_DIG_Get:
push bp to [sp]
bp = sp
r1 = [bp+4]
call F_DIG_Get
pop bp from [sp]
retf
F_DIG_Get:
push r2 to [sp]
r2 = R_DIG_Buf
r2 += r1
r1 = [r2]
pop r2 from [sp]
retf
//======================================================
// 函數名稱： DIG_GetAll
// C調用： unsigned *DIG_GetAll(unsigned *DigBuffer)
// 匯編調用： F_DIG_GetAll
// 實現功能： 獲取所有數碼管的顯示內容
// 入口參數： DigBuffer(r1) - 保存數碼管顯示內容的起始地址
// 出口參數： 保存數碼管顯示內容的起始地址
// 破壞寄存器： 無
//======================================================
_DIG_GetAll:
push bp to [sp]
bp = sp
r1 = [bp+4]
call F_DIG_GetAll
pop bp from [sp]
retf
F_DIG_GetAll:
push r2,bp to [sp]
bp = r1
r2 = DIG_Count
r3 = R_DIG_Buf
?DIG_Get_Loop:
r4 = [r3++]
[bp++] = r4
r2 -= 1
jnz ?DIG_Get_Loop
pop r2,bp from [sp]
retf
//======================================================
// 函數名稱： DIG_Drive
// C調用： void DIG_Drive(void)
// 匯編調用： F_DIG_Drive
// 實現功能： 數碼管顯示函數，由IRQ4_4KHz中斷服務程序調用
// 入口參數： 無
// 出口參數： 無
// 破壞寄存器： 無
//======================================================
_DIG_Drive:
F_DIG_Drive:
push r1,r4 to [sp]
r1 = [R_CurDIG] // 如果不顯示則直接退出
cmp r1,0xffff
je ?DIG_Exit
r2 = r1 + R_DIG_Buf
r2 = [r2]
r2 &= PIN_SEG_ALL
r3 = [P_DIG_Buf] // 清除當前位顯示
r3 &= ~PIN_DIG_ALL
[P_DIG_Data] = r3
r4 = [P_SEG_Buf] // 段數據設置
r4 &= ~PIN_SEG_ALL
r4 |= r2
[P_SEG_Data] = r4
r3 = [P_DIG_Buf] // 位數據設置
r4 = r1 + PIN_DIG
r3 |= [r4]
[P_DIG_Data] = r3
r1 += 1
cmp r1,DIG_Count
jb ?DIG_Next // R_CurDIG指向下一位
?DIG_Reverse:
r1 = 0 // 若已顯示到最后一位則R_CurDIG指向第一位
?DIG_Next:
[R_CurDIG] = r1
?DIG_Exit:
pop r1,r4 from [sp]
retf
//======================================================
// 函數名稱： DIG_Off
// C調用： void DIG_Off(void)
// 匯編調用： F_DIG_Off
// 實現功能： 停止數碼管顯示
// 入口參數： 無
// 出口參數： 無
// 破壞寄存器： 無
//======================================================
_DIG_Off:
F_DIG_Off:
push r1 to [sp]
r1 = [P_DIG_Buf]
r1 &= ~PIN_DIG_ALL
[P_DIG_Buf] = r1
r1 = 0xffff
[R_CurDIG] = r1
pop r1 from [sp]
retf
//======================================================
// 函數名稱： DIG_On
// C調用： void DIG_On(void)
// 匯編調用： F_DIG_On
// 實現功能： 恢復數碼管顯示
// 入口參數： 無
// 出口參數： 無
// 破壞寄存器： 無
//======================================================
_DIG_On:
F_DIG_On:
push r1 to [sp]
r1 = 0
[R_CurDIG] = r1
pop r1 from [sp]
retf?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -