?? escreen.txt
字號:
附錄 源程序
; *************************
; * *
; * 電子屏字符顯示器 *
; * "中國加油" *
; *************************
;四個(gè)顯示字符數(shù)據(jù)表在50H-6FH單元內(nèi)，字符用8*8點(diǎn)陣，R4（30H用于
;控制顯示靜止字的時(shí)間，R5（31H）靜止字顯示跳轉(zhuǎn)地址步距，B內(nèi)放顯示首址
;************;
;中斷入口程序;
;************
ORG 0000H ;程序執(zhí)行開始地址
LJMP START ;跳至START執(zhí)行
ORG 0003H ;外中斷0中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 000BH ;定時(shí)器T0中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 0013H ;外中斷1中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 001BH ;定時(shí)器T1中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 0023H ;串行口中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 002BH ;定時(shí)器T2中斷入口地址
RETI ;中斷返回（不開中斷）
;**********
;初始化程序
;**********
CLEARMEN: MOV A,#0FFH ;4端口全部置1
MOV P1,A
MOV P2,A
MOV P3,A
MOV P0,A
MOV DPTR,#TAB ;取“中國加油”字符表首地址
CLR A
MOV R3,A ;R3寄存器清零
MOV R1,#50H ;設(shè)字符表移入內(nèi)存單元首址
MOV R2,#20H ;設(shè)置表次數(shù)(32次)
CLLOOP: MOVC A,@A+DPTR ;查表將“中國加油”字符數(shù)據(jù)移入內(nèi)存單元
MOV @R1,A
MOV A,R3 ;保存A并將A自加
INC A
MOV R3,A
INC R1
DJNZ R2,CLLOOP ;查表32次，不到轉(zhuǎn)CLLOOP再查
RET ;子程序返回
;**********
; 主程序
;**********
START: LCALL CLEARMEN ;調(diào)用上電初始化子程序
START1: LCALL KEYWORK ;調(diào)用鍵掃描子程序
AJMP START1
;************
;鍵掃描子程序
;************
KEYWORK: MOV P1,#0FFH
JNB P1.0,KEY1 ;P1.0為0(鍵按下)轉(zhuǎn)KEY1
JNB P1.1,KEY2 ;P1.1為0(鍵按下)轉(zhuǎn)KEY2
JNB P1.2,KEY3 ;P1.2為0(鍵按下)轉(zhuǎn)KEY3
KEYRET: RET
;按鍵1功能處理
KEY1: LCALL DL10MS ;延時(shí)10MS消抖動(dòng)
JB P1.0,KEYRET ;是干擾，轉(zhuǎn)KEYRET結(jié)束
WAIT: JNB P1.0,WAIT ;不是干擾，等待按鍵松開
LCALL CLEARMEN ;調(diào)用上電初始化子程序
MOV 30H,#80H ;1幀顯示時(shí)間控制
MOV 31H,#08H ;換幀跳轉(zhuǎn)步距為8
LJMP DISP1 ;轉(zhuǎn)顯示子程序DISP1
;按鍵2功能處理
KEY2: LCALL DL10MS
JB P1.1,KEYRET
WAIT1: JNB P1.1,WAIT1
LCALL CLEARMEN
MOV 30H,#14H ;1幀顯示時(shí)間控制
MOV 31H,#01H ;換幀跳轉(zhuǎn)步距為1
LJMP DISP1 ;轉(zhuǎn)顯示子程序DISP1
;按鍵3功能處理
KEY3: LCALL DL10MS
JB P1.2,KEYRET
WAIT2: JNB P1.2,WAIT2
LCALL CLEARMEN
LJMP DISP2 ;轉(zhuǎn)顯示子程序DISP2
;************
;顯示控制程序
;************
DISP1: MOV B,#50H ;顯示數(shù)據(jù)首址
MOV R4,30H ;放入1幀顯示時(shí)間控制數(shù)據(jù)
MOV R5,31H ;放入跳轉(zhuǎn)步距控制數(shù)據(jù)
LOOP: LCALL DISPLAY ;調(diào)用顯示子程序一次
DJNZ R4,LOOP ;1幀顯示時(shí)間未到轉(zhuǎn)LOOP循環(huán)
MOV R4,30H ;1幀顯示時(shí)間到，重裝初值
MOV A,B
CJNE A,#68H,CONT ;不是末地址轉(zhuǎn)CONT
AJMP START ;是末地址，重新循環(huán)顯示
CONT: ADD A,R5
MOV B,A
AJMP LOOP
;顯示子程序
DISPLAY: MOV A,#0FFH
MOV P0,A ;關(guān)顯示數(shù)據(jù)
MOV P2,A ;關(guān)掃描
MOV R6,#0FEH ;賦掃描字
MOV R0,B ;賦顯示數(shù)據(jù)首地址
MOV R7,#08H ;一次掃描8行
DISLOOP: MOV A,@R0 ;取顯示數(shù)據(jù)
MOV P0,A ;放入P0口
MOV P2,R6 ;掃描輸出(顯示某一行)
LCALL DL1MS ;亮1ms
INC R0 ;指向下一行數(shù)據(jù)地址
MOV A,R6 ;掃描字移入A
RL A ;循環(huán)左移一位
MOV R6,A ;放回R6
DJNZ R7,DISLOOP ;8行掃描未完成轉(zhuǎn)DISLOOP繼續(xù)
RET ;8行掃描結(jié)束
;左移顯示控制程序
DISP2: MOV R5,#32 ;左移32次
DISP22: LCALL DISPP ;調(diào)用左移顯示控制子程序
LCALL MOVH ;調(diào)用高位移出處理子程序MOVH
LCALL MOVH1 ;調(diào)用高位移出處理子程序MOVH1
DJNZ R5,DISP22 ;左移顯示32次控制
LJMP START ;跳回主程序
;左移顯示控制子程序
DISPP: MOV B,#50H ;顯示字符首址
MOV R4,#25H ;一幀顯示時(shí)間控制
DISPP1: LCALL DISPLAY ;調(diào)用顯示子程序一次
DJNZ R4,DISPP1
RET
;高位移出處理子程序，將"中國加油"4個(gè)字符數(shù)據(jù)的最高位移出至20h---23h單元內(nèi)
MOVH: MOV R1,#20H ;最高位移出存放單元首址
MOV R0,#50H ;取“中國加油”字符數(shù)據(jù)首址
MOV R2,#08H ;每“字”移8次
MOV1: MOV A,@R0 ;取“中國加油”字符數(shù)據(jù)
CLR C ;清進(jìn)位C
RLC A ;帶進(jìn)位循環(huán)左移
MOV @R0,A ;放回原單位
MOV A,@R1 ;存放單元數(shù)據(jù)入A
RRC A ;帶進(jìn)位循環(huán)右移
MOV @R1,A ;放回存放單元
INC R0 ;字符數(shù)據(jù)地址加1
DJNZ R2,MOV1 ;移8次未完轉(zhuǎn)MOV1再移
MOV R2,#08H ;8次移完賦初值
INC R1 ;存放單元地址加1
MOV A,R1
SUBB A,#24H ;判斷地址是否小于24H
JZ OUT ;等于24H退出
AJMP MOV1 ;小于24H轉(zhuǎn)MOV1繼續(xù)
OUT: RET
;高位移出處理子程序
MOVH1: MOV A,20H ;20H與21H,22H,23H單元數(shù)據(jù)循交換
XCH A,23H ;20H與23H全交換
XCH A,22H ;22H與23H全交換
XCH A,21H ;22H與21H全交換
MOV 20H,A ;21H與20H全交換
MOV R1,#20H ;重新組成顯示字符數(shù)據(jù)表程序
MOV R0,#50H ;將20H---23H的各位分別移入
50H--6FH的低位
MOV R2,#08H ;移位次數(shù)
MOV2: MOV A,@R0 ;取字符數(shù)據(jù)
RR A ;右移
MOV @R0,A ;放回原單位
MOV A,@R1 ;取原移出最高位存放單元數(shù)
CLR C ;清C
RRC A ;帶進(jìn)位循環(huán)右移
MOV @R1,A ;放回原單位
MOV A,@R0 ;取字符數(shù)據(jù)
RLC A ;帶進(jìn)位循環(huán)左移
MOV @R0,A ;放回字符數(shù)據(jù)
INC R0 ;字符數(shù)據(jù)地址加1
DJNZ R2,MOV2 ;8次未完成轉(zhuǎn)MOV2再繼續(xù)
MOV R2,#08H ;8次完賦初值
INC R1 ;原移出最高位存放單元地址加1
MOV A,R1 ;判斷地址是否小于24H
SUBB A,#24H
JZ OUT ;等于24H轉(zhuǎn)OUT退出
AJMP MOV2 ;小于24H轉(zhuǎn)MOV2繼續(xù)
;1MS延時(shí)子程序
DL1MS: MOV R3,#64H ;100*（10+2）us
LOOPK: LCALL KEYWORK
DJNZ R3,LOOPK
RET
;0.5MS延時(shí)子程序
DL512: MOV R2,#0FFH
LOOP1: DJNZ R2,LOOP1
RET
;10MS延時(shí)子程序
DL10MS: MOV R3,#14H
LOOP2: LCALL DL512
DJNZ R3,LOOP2
RET
;"中國加油"顯示用ROM數(shù)據(jù)表
TAB: DB 0F7H,80H,0B6H,0B6H,80H,0F7H,0F7H,0F7H ;中
DB 01H,01H,6DH,01H,65H,69H,01H,01H ;國
DB 0DFH,0DFH,00H,0D2H,0D2H,0B0H,67H,0F7H ;加
DB 7BH,0BBH,60H,0AAH,0E0H,0CAH,0A0H,7FH ;油
DB 00H,00H,00H,00H
END
?? 快捷鍵說明
復(fù)制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -