EOC BIT P2.0
STA BIT P2.1
CLK BIT P2.2
OE BIT P2.3
ALE BIT P2.4
;******主程序******
     ORG 0
     LJMP MAIN
     ORG 000BH
     CPL CLK
     RETI
MAIN:MOV TMOD,#02H
     MOV TH0,#56
     MOV TL0,#56
     SETB EA
     SETB ET0
     SETB TR0
     CLR A
     MOV 30H,A      ;30H轉換電壓整數位
     MOV 31H,A      ;31H轉換電壓小數位
     MOV 32H,A      ;32H電壓轉換數據
     CLR P2.7
     CLR P2.6
     CLR P2.5
     CLR ALE
     NOP
     SETB ALE
     NOP
     CLR ALE
     NOP
LOOP:CLR STA
     NOP
     SETB STA
     NOP
     CLR STA
     NOP
LOP1:ACALL DISP     ;延時等待
     JNB EOC,LOP1   ;等待轉換結束
     MOV A,P0
     MOV 32H,A
     ACALL CHAN
     SJMP LOOP
;******數據轉換子程序******
CHAN:MOV A,32H
     ANL A,#0F0H
     SWAP A
     MOV 30H,A
     MOV A,32H
     ANL A,#0FH
     MOV 31H,A
     MOV A,32H      ;
     MOV B,#51
     DIV AB
     MOV 30H,A
     XCH A,B
     MOV B,#5
     DIV AB
     MOV 31H,A
     RET
;******顯示子程序******
DISP:MOV DPTR,#TAB
     MOV A,30H
     MOVC A,@A+DPTR
     CLR ACC.7
     MOV P1,#01H
     MOV P3,A
     ACALL DELY
     MOV A,31H
     MOVC A,@A+DPTR
     MOV P1,#02H
     MOV P3,A
     ACALL DELY
     RET
;******延時子程序******
DELY:MOV R6,#20
DEL1:MOV R7,#100
     DJNZ R7,$
     DJNZ R6,DEL1
     RET
;******共陽段碼表******
TAB: DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H,88H,83H,0C6H,0A1H,86H,8EH,0FFH
     END