#include  "msp430x44x.h"
;******************************************************************************
;   MSP-Test44x Demo - Timer_A Toggle P5.1, CCR0 Contmode ISR, DCO SMCLK 
;
;   Description; Toggle P5.1 using using software and TA_0 ISR. Toggle rate is 
;   set at 50000 DCO/SMCLK cycles. Default DCO frequency used for TACLK. 
;   Durring the TA_0 ISR P5.1 is toggled and 50000 clock cycles are added to 
;   CCR0.  TA_0 ISR is triggered exactly 50000 cycles. CPU is normally off and
;   used only durring TA_ISR.  
;   ACLK = n/a, MCLK = SMCLK = TACLK = default DCO
;
;                MSP430F449
;             -----------------
;         /|\|              XIN|-  
;          | |                 |
;          --|RST          XOUT|-
;            |                 |
;            |             P5.1|-->LED
;
;  Yang Rui
;  Lierda, Inc
;  NOVEMBER 2003
;  Built with IAR Embedded Workbench Version: 1.26B
;------------------------------------------------------------------------------ 
            ORG     01100h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #0A00h,SP               ; Initialize '449 stackpointer
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL  ; Stop WDT
SetupTA     mov.w   #TASSEL1+TACLR,&TACTL   ; SMCLK, clear TAR
SetupC0     mov.w   #CCIE,&CCTL0            ; CCR0 interrupt enabled
            mov.w   #50000,&CCR0            ; 
SetupP5     bis.b   #002h,&P5DIR            ; P5.1 output
            bis.w   #MC1,&TACTL             ; Start Timer_a in continous mode
            eint                            ; Enable interrupts
                                            ;						  
Mainloop    bis.w   #CPUOFF,SR              ; CPU off
            nop                             ; Required for C-spy
                                            ;
;------------------------------------------------------------------------------
TA0_ISR;    Toggle P5.1
;------------------------------------------------------------------------------
            xor.b   #002h,&P5OUT            ; Toggle P5.1
            add.w   #50000,&CCR0            ; Add Offset to CCR0
            reti                            ;		 
                                            ;   
;----------------------------------------------------------------------------- 
;           Interrupt Vectors Used MSP430F44x         
;----------------------------------------------------------------------------- 
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ; 
            ORG     0FFECh                  ; Timer_A0 Vector
            DW      TA0_ISR                 ; 
            END