* 12AT7 Triode PSpice Model                      8/96, Rev. 1.0  (fp)
*
* -------------------------------------------------------------------
*  This model is provided "as is", with no warranty of any kind,
*  either expressed or implied, about the suitability or fitness
*  of this model for any particular purpose.  Use of this model
*  shall be entirely at the user's own risk.
*
*  For a discussion about vacuum tube modeling please refer to:
*  W. Marshall Leach, jr: "SPICE Models for Vacuum-Tube Amplifiers";
*  J. Audio Eng. Soc., Vol 43, No 3, March 1995.
* -------------------------------------------------------------------
*
* This model is valid for the following tubes:
* 12AT7/ECC81, 6AB4/EC92, 6201, 6679;
* at the following conditions:
*  Plate voltage  : 0..500V
*  Grid voltage   : 0..-8V
*  Cathode current: 0..30mA
*
*
* Connections: Plate
*              | Grid
*              | | Cathode
*              | | |
.SUBCKT 12AT7  P G K
E1  2  0  VALUE={V(P,K)+63.19*V(G,K)}
R1  2  0  1.0K
Gp  P  K  VALUE={6.717E-6*(PWR(V(2),1.5)+PWRS(V(2),1.5))/2}
Cgk G  K  2.2P
Cgp G  P  1.5P
Cpk P  K  0.5P
.ENDS 12AT7
* 12AU7A Triode PSpice Model                     8/96, Rev. 1.0  (fp)
*
* -------------------------------------------------------------------
*  This model is provided "as is", with no warranty of any kind,
*  either expressed or implied, about the suitability or fitness
*  of this model for any particular purpose.  Use of this model
*  shall be entirely at the user's own risk.
*
*  For a discussion about vacuum tube modeling please refer to:
*  W. Marshall Leach, jr: "SPICE Models for Vacuum-Tube Amplifiers";
*  J. Audio Eng. Soc., Vol 43, No 3, March 1995.
* -------------------------------------------------------------------
*
* This model is valid for the following tubes:
* 12AU7A/ECC82, 6680, 6C4/EC90, 12DW7/7247 (Unit #2);
* at the following conditions:
*  Plate voltage  : 0..400V
*  Grid voltage   : 0..-18V
*  Cathode current: 0..30mA
*
*
* Connections: Plate
*              | Grid
*              | | Cathode
*              | | |
.SUBCKT 12AU7A P G K
E1  2  0  VALUE={V(P,K)+18.28*V(G,K)}
R1  2  0  1.0K
Gp  P  K  VALUE={10.88E-6*(PWR(V(2),1.5)+PWRS(V(2),1.5))/2}
Cgk G  K  1.6P
Cgp G  P  1.5P
Cpk P  K  0.5P
.ENDS 12AU7A
* 12AX7A Triode PSpice Model                     8/96, Rev. 1.0  (fp)
*
* -------------------------------------------------------------------
*  This model is provided "as is", with no warranty of any kind,
*  either expressed or implied, about the suitability or fitness
*  of this model for any particular purpose.  Use of this model
*  shall be entirely at the user's own risk.
*
*  For a discussion about vacuum tube modeling please refer to:
*  W. Marshall Leach, jr: "SPICE Models for Vacuum-Tube Amplifiers";
*  J. Audio Eng. Soc., Vol 43, No 3, March 1995.
* -------------------------------------------------------------------
*
* This model is valid for the following tubes:
* 12AX7A/ECC83, 7025, 6EU7, 6681, 6AV6, 12DW7/7247 (Unit #1);
* at the following conditions:
*  Plate voltage  : 25..400V
*  Grid voltage   : 0..-3.5V
*  Cathode current: 0..8mA
*
*
* Connections: Plate
*              | Grid
*              | | Cathode
*              | | |
.SUBCKT 12AX7A P G K
E1  2  0  VALUE={45+V(P,K)+95.43*V(G,K)}
R1  2  0  1.0K
Gp  P  K  VALUE={1.147E-6*(PWR(V(2),1.5)+PWRS(V(2),1.5))/2}
Cgk G  K  1.6P
Cgp G  P  1.7P
Cpk P  K  0.46P
.ENDS 12AX7A
* 12BH7A Triode PSpice Model                     9/96, Rev. 1.0  (fp)
*
* -------------------------------------------------------------------
*  This model is provided "as is", with no warranty of any kind,
*  either expressed or implied, about the suitability or fitness
*  of this model for any particular purpose.  Use of this model
*  shall be entirely at the user's own risk.
*
*  For a discussion about vacuum tube modeling please refer to:
*  W. Marshall Leach, jr: "SPICE Models for Vacuum-Tube Amplifiers";
*  J. Audio Eng. Soc., Vol 43, No 3, March 1995.
* -------------------------------------------------------------------
*
* This model is valid for the following tubes:
* 12BH7A;
* at the following conditions:
*  Plate voltage  : 0..600V
*  Grid voltage   : 0..-35V
*  Cathode current: 0..50mA
*
*
* Connections: Plate
*              | Grid
*              | | Cathode
*              | | |
.SUBCKT 12BH7A P G K
E1  2  0  VALUE={V(P,K)+16.64*V(G,K)}
R1  2  0  1.0K
Gp  P  K  VALUE={22.34E-6*(PWR(V(2),1.5)+PWRS(V(2),1.5))/2}
Cgk G  K  3.2P
Cgp G  P  2.6P
Cpk P  K  0.5P
.ENDS 12BH7A
* 5AR4 Rectifier diode PSpice Model              8/96, Rev. 1.0  (fp)
*
* -------------------------------------------------------------------
*  This model is provided "as is", with no warranty of any kind,
*  either expressed or implied, about the suitability or fitness
*  of this model for any particular purpose.  Use of this model
*  shall be entirely at the user's own risk.
*
*  For a discussion about vacuum tube modeling please refer to:
*  W. Marshall Leach, jr: "SPICE Models for Vacuum-Tube Amplifiers";
*  J. Audio Eng. Soc., Vol 43, No 3, March 1995.
* -------------------------------------------------------------------
*
* This model is valid for the following tubes:
* 5AR4/GZ34;
* at the following conditions:
*  Plate current  : 0..1.2A
*
*
* Connections: Plate
*              | Cathode
*              | |
.SUBCKT 5AR4   P K
GP  P  K  VALUE={3.96E-3*(PWR(V(P,K),1.5)+PWRS(V(P,K),1.5))/2}
.ENDS 5AR4
* 5U4GB pspice rectifier model
*
* The following parameters are not modelled:
*
*   (1) Filament and filament warmup time
*   (2) Reverse voltage breakdown
*   (3) Saturation
*   (4) Interelectrode capacitance
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* 5U4GB maximum ratings:
*
*   PIV     1550V
*   Max in  550V RMS
*   Ia pk   1000mA repetitive  (4600mA transient)
*
*
*             .----- Anode
*             | .--- Cathode
*             | |
.SUBCKT 5U4GB A K
GP  A  K  VALUE={7.55E-4*(PWR(V(A,K),1.5)+PWRS(V(A,K),1.5))/2}
.ENDS 5U4GB

*
* 5V3A pspice rectifier model
*
* The following parameters are not modelled:
*
*   (1) Filament and filament warmup time
*   (2) Reverse voltage breakdown
*   (3) Saturation
*   (4) Interelectrode capacitance
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* 5V3A maximum ratings:
*
*   PIV     1550V
*   Max in  550V RMS
*   Iout    550mA DC output current
*   Ia pk   1400mA repetitive  (6600mA transient)
*
*
*            .----- Anode
*            | .--- Cathode
*            | |
.SUBCKT 5V3A A K
GP  A  K  VALUE={1.287E-3*(PWR(V(A,K),1.5)+PWRS(V(A,K),1.5))/2}
.ENDS 5V3A

*
* 5V4GA pspice rectifier model
*
* The following parameters are not modelled:
*
*   (1) Filament and filament warmup time
*   (2) Reverse voltage breakdown
*   (3) Saturation
*   (4) Interelectrode capacitance
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* 5V4GA maximum ratings:
*
*   PIV     1400V
*   Ia pk   525mA repetitive  (3500mA transient)
*
*
*             .----- Anode
*             | .--- Cathode
*             | |
.SUBCKT 5V4GA A K
GP  A  K  VALUE={1.4E-3*(PWR(V(A,K),1.5)+PWRS(V(A,K),1.5))/2}
.ENDS 5V4GA

*
* 5Y3GT pspice rectifier model
*
* The following parameters are not modelled:
*
*   (1) Filament and filament warmup time
*   (2) Reverse voltage breakdown
*   (3) Saturation
*   (4) Interelectrode capacitance
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* 5Y3GT maximum ratings:
*
*   PIV     1400V
*   Max in  500V RMS
*   Iout    42mA DC output current (per anode)
*   Ia pk   400mA repetitive  (2200mA transient)
*
*
*             .----- Anode
*             | .--- Cathode
*             | |
.SUBCKT 5Y3GT A K
GP  A  K  VALUE={2.69E-4*(PWR(V(A,K),1.5)+PWRS(V(A,K),1.5))/2}
.ENDS 5Y3GT

*
* 6DJ8 Triode PSpice Model                       9/96, Rev. 1.0  (fp)
*
* -------------------------------------------------------------------
*  This model is provided "as is", with no warranty of any kind,
*  either expressed or implied, about the suitability or fitness
*  of this model for any particular purpose.  Use of this model
*  shall be entirely at the user's own risk.
*
*  For a discussion about vacuum tube modeling please refer to:
*  W. Marshall Leach, jr: "SPICE Models for Vacuum-Tube Amplifiers";
*  J. Audio Eng. Soc., Vol 43, No 3, March 1995.
* -------------------------------------------------------------------
*
* This model is valid for the following tubes:
* 6DJ8/ECC88, 6922/E88CC, 7308;
* at the following conditions:
*  Plate voltage  : 0..300V
*  Grid voltage   : 0..-8V
*  Cathode current: 0..100mA
*
*
* Connections: Plate
*              | Grid
*              | | Cathode
*              | | |
.SUBCKT 6DJ8   P G K
E1  2  0  VALUE={V(P,K)+30.95*V(G,K)}
R1  2  0  1.0K
Gp  P  K  VALUE={34.56E-6*(PWR(V(2),1.5)+PWRS(V(2),1.5))/2}
Cgk G  K  3.1P
Cgp G  P  1.4P
Cpk P  K  0.18P
.ENDS 6DJ8
* 6L6GC Beam Power Tube PSpice Model             8/96, Rev. 1.0  (fp)
*
* -------------------------------------------------------------------
*  This model is provided "as is", with no warranty of any kind,
*  either expressed or implied, about the suitability or fitness
*  of this model for any particular purpose.  Use of this model