*  shall be entirely at the user's own risk.
*
*  For a discussion about vacuum tube modeling please refer to:
*  W. Marshall Leach, jr: "SPICE Models for Vacuum-Tube Amplifiers";
*  J. Audio Eng. Soc., Vol 43, No 3, March 1995.
* -------------------------------------------------------------------
*
* This model is valid for the following tubes (within max. ratings):
*                 6L6/G/GA/   5881/
*                 GB, 1614,   6L6WGB,   6L6GC,   7581A,   7027A.
* --------------+-------------------------------------------------
* Plate Dissip. :    19W        23W       30W      35W      35W
* Screen Input  :   2.5W         3W        5W       5W       5W
* Plate Voltage :   360V       400V      500V     500V     600V
* Screen Voltage:   270V       400V      450V     450V     500V
*
* at the following conditions:
*  Plate voltage  : 0..800V
*  Screen voltage : 0..600V
*  Grid voltage   : 0..-60V
*  Cathode current: 0..400mA
*
*
* Connections: Plate
*              | Screen Grid
*              | | Control Grid
*              | | | Cathode
*              | | | |
.SUBCKT  6L6GC P S G K
Esp 2  0  VALUE={V(P,K)+15.15*V(S,K)+134.6*V(G,K)}
E1  3  2  VALUE={7.731E-7*(PWR(LIMIT(V(2),-1E6,1E6),1.5)+PWRS(LIMIT(V(2),-1E6,1E6),1.5))/2}
E2  3  4  VALUE={7.731E-7*PWR(LIMIT(15.15*V(S,K),-1E6,1E6),1.5)*V(P,K)/60}
E3  5  4  VALUE={(1-V(4,2)/ABS(V(4,2)+0.001))/2}
R1  5  0  1.0K
Gk  S  K  VALUE={V(3,2)}
Gp  P  S  VALUE={0.94*(V(3,4)*(1-V(5,4))+V(3,2)*V(5,4))}
Cgk G  K  5P
Cgs G  S  5P
Cgp G  P  0.6P
Cpk P  K  6.5P
.ENDS 6L6GC
* 6SL7GT Triode PSpice Model                     8/96, Rev. 1.0  (fp)
*
* -------------------------------------------------------------------
*  This model is provided "as is", with no warranty of any kind,
*  either expressed or implied, about the suitability or fitness
*  of this model for any particular purpose.  Use of this model
*  shall be entirely at the user's own risk.
*
*  For a discussion about vacuum tube modeling please refer to:
*  W. Marshall Leach, jr: "SPICE Models for Vacuum-Tube Amplifiers";
*  J. Audio Eng. Soc., Vol 43, No 3, March 1995.
* -------------------------------------------------------------------
*
* This model is valid for the following tubes:
* 6SL7GT, ECC35, 5691;
* at the following conditions:
*  Plate voltage  : 0..450V
*  Grid voltage   : 0..-6V
*  Cathode current: 0..8mA
*
*
* Connections: Plate
*              | Grid
*              | | Cathode
*              | | |
.SUBCKT 6SL7GT P G K
E1  2  0  VALUE={V(P,K)+65.5*V(G,K)}
R1  2  0  1.0K
Gp  P  K  VALUE={1.54E-6*(PWR(V(2),1.5)+PWRS(V(2),1.5))/2}
Cgk G  K  3.2P
Cgp G  P  2.8P
Cpk P  K  3.5P
.ENDS 6SL7GT
* 6SN7GTB Triode PSpice Model                    8/96, Rev. 1.0  (fp)
*
* -------------------------------------------------------------------
*  This model is provided "as is", with no warranty of any kind,
*  either expressed or implied, about the suitability or fitness
*  of this model for any particular purpose.  Use of this model
*  shall be entirely at the user's own risk.
*
*  For a discussion about vacuum tube modeling please refer to:
*  W. Marshall Leach, jr: "SPICE Models for Vacuum-Tube Amplifiers";
*  J. Audio Eng. Soc., Vol 43, No 3, March 1995.
* -------------------------------------------------------------------
*
* This model is valid for the following tubes:
* 6SN7GTB, ECC32, 6FQ7/6CG7, 5692;
* at the following conditions:
*  Plate voltage  : 0..450V
*  Grid voltage   : 0..-18V
*  Cathode current: 0..30mA
*
*
*  Connections: Plate
*               | Grid
*               | | Cathode
*               | | |
.SUBCKT 6SN7GTB P G K
E1  2  0  VALUE={V(P,K)+20.43*V(G,K)}
R1  2  0  1.0K
Gp  P  K  VALUE={10.89E-6*(PWR(V(2),1.5)+PWRS(V(2),1.5))/2}
Cgk G  K  2.4P
Cgp G  P  4.0P
Cpk P  K  0.7P
.ENDS 6SN7GTB
* 6V6GTA Beam Power Tube PSpice Model            8/96, Rev. 1.0  (fp)
*
* -------------------------------------------------------------------
*  This model is provided "as is", with no warranty of any kind,
*  either expressed or implied, about the suitability or fitness
*  of this model for any particular purpose.  Use of this model
*  shall be entirely at the user's own risk.
*
*  For a discussion about vacuum tube modeling please refer to:
*  W. Marshall Leach, jr: "SPICE Models for Vacuum-Tube Amplifiers";
*  J. Audio Eng. Soc., Vol 43, No 3, March 1995.
* -------------------------------------------------------------------
*
* This model is valid for the following tubes (within max. ratings):
*                   6V6GTA,   6AQ5A/EL90,
*                   7408,     6669.
* --------------+----------------------------
* Plate Dissip. :    14W          12W
* Screen Input  :   2.2W         2.0W
* Plate Voltage :   350V         275V
* Screen Voltage:   315V         275V
*
* at the following conditions:
*  Plate voltage  : 0..500V
*  Screen voltage : 0..450V
*  Grid voltage   : 0..-50V
*  Cathode current: 0..200mA
*
*
* Connections: Plate
*              | Screen Grid
*              | | Control Grid
*              | | | Cathode
*              | | | |
.SUBCKT 6V6GTA P S G K
Esp 2  0  VALUE={V(P,K)+13.49*V(S,K)+130.4*V(G,K)}
E1  3  2  VALUE={5.521E-7*(PWR(LIMIT(V(2),-1E6,1E6),1.5)+PWRS(LIMIT(V(2),-1E6,1E6),1.5))/2}
E2  3  4  VALUE={5.521E-7*PWR(LIMIT(13.49*V(S,K),-1E6,1E6),1.5)*V(P,K)/25}
E3  5  4  VALUE={(1-V(4,2)/ABS(V(4,2)+0.001))/2}
R1  5  0  1.0K
Gk  S  K  VALUE={V(3,2)}
Gp  P  S  VALUE={0.92*(V(3,4)*(1-V(5,4))+V(3,2)*V(5,4))}
Cgk G  K  4.5P
Cgs G  S  4.5P
Cgp G  P  0.7P
Cpk P  K  7.5P
.ENDS 6V6GTA
* GL211 Triode PSpice Model                      9/96, Rev. 1.0  (fp)
*
* -------------------------------------------------------------------
*  This model is provided "as is", with no warranty of any kind,
*  either expressed or implied, about the suitability or fitness
*  of this model for any particular purpose.  Use of this model
*  shall be entirely at the user's own risk.
*
*  For a discussion about vacuum tube modeling please refer to:
*  W. Marshall Leach, jr: "SPICE Models for Vacuum-Tube Amplifiers";
*  J. Audio Eng. Soc., Vol 43, No 3, March 1995.
* -------------------------------------------------------------------
*
* This model is valid for the following tubes:
* GL211, VT4C;
* at the following conditions:
*  Plate voltage  :  0..2200V (grid negative),
*                   100..700V (grid positive) (1)
*  Grid voltage   : +50..-180V (2)
*  Cathode current: 0..200mA
*
* (1) Plate current decrease and grid current increase at low plate
*     voltage are not modeled.
* (2) Since no data was available, grid current modeling is only
*     approximate. Adjust Gg if required.
*
*
* Connections: Plate
*              | Grid
*              | | Cathode
*              | | |
.SUBCKT GL211  P G K
E1  2  0  VALUE={V(P,K)+12.11*V(G,K)}
R1  2  0  1.0K
Gp  P  K  VALUE={9.39E-6*(PWR(V(2),1.5)+PWRS(V(2),1.5))/2}
Gg  G  K  VALUE={358E-6*(PWR(V(G,K),1.5)+PWRS(V(G,K),1.5))/2}
Cgk G  K  6.0P
Cgp G  P  14.5P
Cpk P  K  5.5P
.ENDS GL211
* Vacuum tube Heater PSpice Model                9/96, Rev. 1.0  (fp)
*
* -------------------------------------------------------------------
*  This model is provided "as is", with no warranty of any kind,
*  either expressed or implied, about the suitability or fitness
*  of this model for any particular purpose.  Use of this model
*  shall be entirely at the user's own risk.
*
*  For a discussion about vacuum tube modeling please refer to:
*  W. Marshall Leach, jr: "SPICE Models for Vacuum-Tube Amplifiers";
*  J. Audio Eng. Soc., Vol 43, No 3, March 1995.
* -------------------------------------------------------------------
*
* This model is valid at the following conditions:
*  - Indirectly heated, oxide coated cathodes only;
*  - Tungsten wire, Tnom=1400..1500K (cathode T=1050K);
*  - Heater warm-up time=11s.
*
* This Heater model can be operated either at AC (any waveform), DC
* or any combination thereof, just like a real Heater.  VNOM and INOM
* are the nominal operating voltage and current of the Heater
* respectively.  If many heaters are connected in parallel, set INOM
* to the sum of all heaters' currents.  These parameters are passed
* to the model in the following way:
*
*  X1  Va  Vb   Heater  params: VNOM=6.3 INOM=4.8  *(4x6L6+4x12AX7A)
*  X2  R1  R2   Heater  params: VNOM=5.0 INOM=1.9  *(1x5AR4/GZ34)
*
*
.SUBCKT Heater f1 f2  params: VNOM=6.3 INOM=300m
Grms  1  0  VALUE={1E-3*(V(f2,f1))*(V(f2,f1))/(VNOM*VNOM)}
Rt    1  0  1k
Ct    1  0  9.94m
Gf   f2 f1  VALUE={V(f2,f1)*1.16*INOM/(VNOM*(PWR(V(1),0.3)+0.16))}
.ENDS Heater
* KT88 Beam Power Tube PSpice Model              8/96, Rev. 1.0  (fp)
*
* -------------------------------------------------------------------
*  This model is provided "as is", with no warranty of any kind,
*  either expressed or implied, about the suitability or fitness
*  of this model for any particular purpose.  Use of this model
*  shall be entirely at the user's own risk.
*
*  For a discussion about vacuum tube modeling please refer to:
*  W. Marshall Leach, jr: "SPICE Models for Vacuum-Tube Amplifiers";
*  J. Audio Eng. Soc., Vol 43, No 3, March 1995.
* -------------------------------------------------------------------
*
* This model is valid for the following tubes (within max. ratings):
*                   KT88       6550.
* --------------+-----------------------
* Plate Dissip. :    35W        35W
* Screen Input  :     6W         6W
* Plate Voltage :   800V       600V
* Screen Voltage:   600V       400V
*
* at the following conditions:
*  Plate voltage  : 0..800V
*  Screen voltage : 0..600V
*  Grid voltage   : 0..-60V
*  Cathode current: 0..500mA
*
*
* Connections: Plate
*              | Screen Grid
*              | | Control Grid
*              | | | Cathode
*              | | | |
.SUBCKT   KT88 P S G K
Esp 2  0  VALUE={V(P,K)+24.49*V(S,K)+189.9*V(G,K)}
E1  3  2  VALUE={8.301E-7*(PWR(LIMIT(V(2),-1E6,1E6),1.5)+PWRS(LIMIT(V(2),-1E6,1E6),1.5))/2}
E2  3  4  VALUE={8.301 E-7*PWR(LIMIT(24.49*V(S,K),-1E6,1E6),1.5)*V(P,K)/40}
E3  5  4  VALUE={(1-V(4,2)/ABS(V(4,2)+0.001))/2}
R1  5  0  1.0K
Gk  S  K  VALUE={V(3,2)}
Gp  P  S  VALUE={0.95*(V(3,4)*(1-V(5,4))+V(3,2)*V(5,4))}
Cgk G  K  8.0P
Cgs G  S  8.0P
Cgp G  P  1.2P
Cpk P  K  12P
.ENDS KT88
* WE300B Triode PSpice Model                     8/96, Rev. 1.0  (fp)
*
* -------------------------------------------------------------------
*  This model is provided "as is", with no warranty of any kind,
*  either expressed or implied, about the suitability or fitness
*  of this model for any particular purpose.  Use of this model
*  shall be entirely at the user's own risk.
*
*  For a discussion about vacuum tube modeling please refer to:
*  W. Marshall Leach, jr: "SPICE Models for Vacuum-Tube Amplifiers";
*  J. Audio Eng. Soc., Vol 43, No 3, March 1995.
* -------------------------------------------------------------------
*
* This model is valid for the following tubes:
* WE300B, STC4300B;
* at the following conditions:
*  Plate voltage  : 0..650V
*  Grid voltage   : 0..-160V
*  Cathode current: 0..200mA
*
*
* Connections: Plate
*              | Grid
*              | | Cathode
*              | | |
.SUBCKT WE300B P G K
E1  2  0  VALUE={V(P,K)+3.87*V(G,K)}
R1  2  0  1.0K
Gp  P  K  VALUE={119.5E-6*(PWR(V(2),1.5)+PWRS(V(2),1.5))/2}
Cgk G  K  9.0P
Cgp G  P  15P
Cpk P  K  4.3P
.ENDS WE300B