*The following is a list of Harris Radiation Hardened Power Mosfet PSPICE
*Compatible models contained in this library file.
*See the README.TXT file on this disk for license information.
* File revised on 7/10/1996
*FSF150     FSF250     FSF254     FSF450     FSL130     FSL230     FSL234
*FSL430     FSS130     FSS234
*FRK150     FRK250     FRK254     FRL130     FRL230
*
.SUBCKT FSF250 2 1 3
*Term. Conn. * D G S
*Spice Model circuit file for the FSF250
*For a detail electrical specification see datasheet file FN4046
****************************************************************************
*   For further discussion of this PSPICE Power MOSFET macromodel consult  *
*     A New PSPICE Sub-circuit for the Power MOSFET Featuring Global       *
*      Temperature Options by William J. Hepp and C. Frank Wheatley        *
*Nom Temp=25 deg C                                                         *
****************************************************************************
Ca 12 8 5.2n
Cb 15 14 4.6n
Cin 6 8 2.83n
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Dplcap 10 5 DplcapMOD
Ebreak 11 7 17 18 220.5
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Evthres 6 21 19 8 1
Evtemp 20 6 18 22 1
It 8 17 1
Lgate 1 9 7.456n
Ldrain 2 5 2.679n
Lsource 3 7 6.155n
RLgate 1 9 74.56
RLdrain 2 5 26.79
RLsource 3 7 61.55
Mmed 16 21 8 8 MmedMOD
Mstro 16 6 8 8 MstroMOD
Mweak 16 21 8 8 MweakMOD
Rbreak 17 18 RbreakMOD 1
Rdrain 50 16 RdrainMOD 33m
Rgate 9 20 1
RSLC1 5 51 RSLCMOD 1u
RSLC2 5 50 1k
Rin 6 8 1e9
Rsource 8 7 RsourceMOD 40m
Rvthres 22 8 RvthresMOD 1
Rvtemp 18 19 RvtempMOD 1
S1a 6 12 13 8 S1AMOD
S1b 13 12 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 13 15 14 13 S2BMOD
Vbat 22 19 DC 1
ESLC 51 50  VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)/(1e-6*63),4.05))}
.MODEL DbodyMOD D (IS=2.5e-10  RS=11.5m VJ=0.5 TRS1=2e-3 TRS2=0 XTI=0.25
+ CJO=3.5n TT=480e-9 M=0.5 N =1.25)
.MODEL DbreakMOD D (IS=1e-14 RS=0.65 TRS1=1e-3 TRS2=0)
.MODEL DplcapMOD D (CJO=1.25n IS=1e-30 N=10 M=0.55 VJ=0.75)
.MODEL MmedMOD NMOS (VTO=4.9 KP=6 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=1)
.MODEL MstroMOD NMOS (VTO=6 KP=16 IS=1e-30 N=10 TOX=1 L=1u W=1u)
.MODEL MweakMOD NMOS (VTO=3.1 KP=0.003 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=1
+ RD=100)
.MODEL RbreakMOD RES (TC1=1.2e-3 TC2=-1.5e-6)
.MODEL RdrainMOD RES (TC1=0.015 TC2=3.25e-5)
.MODEL RSLCMOD RES (TC1=3e-3 TC2=-5e-7)
.MODEL RsourceMOD RES (TC1=0 TC2=0)
.MODEL RvthresMOD RES (TC1=-9e-3 TC2=-1e-6)
.MODEL RvtempMOD RES (TC1=-1.5e-3 TC2=-1e-7)
.MODEL S1AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-12 VOFF=-7)
.MODEL S1BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-7 VOFF=-12)
.MODEL S2AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=2 VOFF=8)
.MODEL S2BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=8 VOFF=2)
.ENDS
.SUBCKT FSF150 2 1 3
*Term. Conn. * D G S
*Spice Model circuit file for the FSF150
*For detail electrical specification see datasheet file FN3971
***************************************************************************
*   For further discussion of this PSPICE Power MOSFET macromodel consult *
*    A New PSPICE Sub-circuit for the Power MOSFET Featuring Global       *
*     Temperature Options by William J. Hepp and C. Frank Wheatley        *
*Nom Temp=25 deg C                                                        *
***************************************************************************
Ca 12 8 4.4n
Cb 15 14 4.35n
Cin 6 8 2.8n
Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Dplcap 10 5 DplcapMOD
Ebreak 11 7 17 18 115.5
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Evthres 6 21 19 8 1
Evtemp 20 6 18 22 1
It 8 17 1
Lgate 1 9 3.24n
Ldrain 2 5 2.87n
Lsource 3 7 6.155n
RLgate 1 9 32.4
RLdrain 2 5 28.7
RLsource 3 7 61.55
Mmed 16 21 8 8 MmedMOD
Mstro 16 6 8 8 MstroMOD
Mweak 16 21 8 8 MweakMOD
Rbreak 17 18 RbreakMOD 1
Rdrain 50 16 RdrainMOD 1m
Rgate 9 20 1
Rin 6 8 1e9
RSLC1 5 51 RSLCMOD 1u
RSLC2 5 50 1k
Rsource 8 7 RsourceMOD 34m
Rvthres 22 8 RvthresMOD 1
Rvtemp 18 19 RvtempMOD 1
S1a 6 12 13 8 S1AMOD
S1b 13 12 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 13 15 14 13 S2BMOD
Vbat 22 19 DC 1
ESLC 51 50  VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)/(1e-6*160),6))}
.MODEL DbodyMOD D (IS=5e-12 RS=12.5m N=1.05 TRS1=2.5e-3 TRS2=3.73e-6
+  CJO=3.5n M=0.43 TT=345n VJ=0.5 XTI=0.25)
.MODEL DbreakMOD D (IS=1e-14 RS=0.27 TRS1=0.0 TRS2=0)
.MODEL DplcapMOD D (CJO=3.1n IS=1e-30 N=10 M=0.675)
.MODEL MmedMOD NMOS (VTO=4.2 KP=3.2 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=1)
.MODEL MstroMOD NMOS (VTO=5.7 KP=13 IS=1e-30 N=10 TOX=1 L=1u W=1u)
.MODEL MweakMOD NMOS (VTO=3.0 KP=0.01 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=1
+ RS=0.1)
.MODEL RbreakMOD RES (TC1=1e-3 TC2=0)
.MODEL RdrainMOD RES (TC1=0.16 TC2=3.5e-4)
.MODEL RSLCMOD RES (TC1=3.5e-3 TC2=0)
.MODEL RsourceMOD RES (TC1=0 TC2=0)
.MODEL RvthresMOD RES (TC1=-7.5e-3 TC2=0)
.MODEL RvtempMOD RES (TC1=-3e-3 TC2=0)
.MODEL S1AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-16.5 VOFF=-6.5)
.MODEL S1BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-6.5 VOFF=-16.5)
.MODEL S2AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=3 VOFF=6)
.MODEL S2BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=6 VOFF=3)
.ENDS
*
.SUBCKT FRK150  3 2 11
*Term. Conn.*** D G S
* Spice model circuit for the FRK150
*For a detail electrical specification see datasheet file FN3221
*************************************************************************
*   For further discussion of this PSPICE PowerFET macromodel consult   *
*        Spicing-up SPICE II Software for Power MOSFET Modeling         *
*            by C. Frank Wheatley, H. R. Ronan, G. M. Dolny             *
*                     Application Note   AN-8610                        *
*NOM TEMP=25 deg C                                                      *
*************************************************************************
C21 2 1 3900P
C23 2 3 350P
C24 2 4 8000P
DBODY 9 3 DMOD2
DBREAK 3 7 DMOD3
D1 5 6 DMOD
E41 5 11 4 1 1.0
FDSCHRG 4 2 VMEAS 1.0
LSOURCE 10 11 7.5N
JFET 3 9 4 JMOD 1
MOS1 4 2 1 1 MOSMOD L=1U W=1U
RSOURCE 1 10 0.016
R21 2 1 1E9
R91 9 1 0.0001
VBREAK 7 1 DC 115
VMEAS 8 11 DC 0
VPINCH 6 8 DC 5.5
.MODEL DMOD D (IS=1.0E-13 N=0.03 RS=0.001)
.MODEL DMOD2 D (CJO=8910P TT=700N IS=5.1E-12)
.MODEL DMOD3 D (IS=1.0E-13 RS=0.5 N=1.0)
.MODEL JMOD NJF (VTO=-5.5 BETA=1400.0 IS=5.1E-18 RD=0.0111)
.MODEL MOSMOD NMOS (VTO=4.0 KP=14.0 TOX=1.0E+06U)
.ENDS
*
.SUBCKT FRK250  3 2 11
*Term. Conn.*** D G S
* Spice model circuit for the FRK250
*For a detail electrical specification see datasheet file FN3226
*************************************************************************
*   For further discussion of this PSPICE PowerFET macromodel consult   *
*        Spicing-up SPICE II Software for Power MOSFET Modeling         *
*            by C. Frank Wheatley, H. R. Ronan, G. M. Dolny             *
*                     Application Note   AN-8610                        *
*NOM TEMP=25 deg C                                                      *
*************************************************************************
C21 2 1 4800P
C23 2 3 200P
C24 2 4 9400P
DBODY 9 3 DMOD2
DBREAK 3 7 DMOD3
D1 5 6 DMOD
E41 5 11 4 1 1.0
FDSCHRG 4 2 VMEAS 1.0
JFET 3 9 4 JMOD 1
LSOURCE 10 11 7.5N
MOS1 4 2 1 1 MOSMOD L=1U W=1U
RSOURCE 1 10 0.01827
R21 2 1 1E9
R91 9 1 0.00654
VPINCH 6 8 DC 8.0
VMEAS 8 11 DC 0
VBREAK 7 1 DC 240
.MODEL DMOD D (IS=1.0E-13 N=0.03 RS=0.001)
.MODEL DMOD2 D (CJO=4200P TT=1000N IS=8.7E-13)
.MODEL DMOD3 D (IS=1.0E-13 RS=1.111 N=1.0)
.MODEL JMOD NJF (VTO=-8.0 BETA=1216.2 IS=8.7E-19 RD=0.05983)
.MODEL MOSMOD NMOS (VTO=4.463 KP=12.162 TOX=1.0E+06U)
.ENDS
*
.SUBCKT FRK254  3 2 11
*Term. Conn.*** D G S
* Spice model circuit for the FRK254
*For a detail electrical specification see datasheet file FN3231
*************************************************************************
*   For further discussion of this PSPICE PowerFET macromodel consult   *
*        Spicing-up SPICE II Software for Power MOSFET Modeling         *
*            by C. Frank Wheatley, H. R. Ronan, G. M. Dolny             *
*                     Application Note   AN-8610                        *
*NOM TEMP=25 deg C                                                      *
*************************************************************************
C21 2 1 4800P
C23 2 3 200P
C24 2 4 9400P
DBODY 9 3 DMOD2
DBREAK 3 7 DMOD3
D1 5 6 DMOD
E41 5 11 4 1 1.0
FDSCHRG 4 2 VMEAS 1.0
JFET 3 9 4 JMOD 1
LSOURCE 10 11 7.5N
MOS1 4 2 1 1 MOSMOD L=1U W=1U
RSOURCE 1 10 0.01827
R21 2 1 1E9
R91 9 1 0.00654
VBREAK 7 1 DC 240
VMEAS 8 11 DC 0
VPINCH 6 8 DC 8.0
.MODEL DMOD D (IS=1.0E-13 N=0.03 RS=0.001)
.MODEL DMOD2 D (CJO=4200P TT=1000N IS=8.7E-13)
.MODEL DMOD3 D (IS=1.0E-13 RS=1.111 N=1.0)
.MODEL JMOD NJF (VTO=-8.0 BETA=1216.2 IS=8.7E-19 RD=0.05983)
.MODEL MOSMOD NMOS (VTO=4.463 KP=12.162 TOX=1.0E+06U)
.ENDS
*
.SUBCKT FRL130  1 2 3 4  
*Term. Conn.*** D G S Kelvin
* Spice model circuit for the FRL130
*For a detail electrical specification see datasheet file FN3218
*************************************************************************
*   For further discussion of this PSPICE PowerFET macromodel consult   *
*    A New PSPICE Sub-circuit for the Power MOSFET Featuring Global     *
*     Temperature Options by William J. Hepp and C. Frank Wheatley      *
*   This model however does not include the temperature variation of the*
*   various parameters as outlined in the application note.             *
*NOM TEMP=25 deg C                                                      *
*************************************************************************
Ca 12 8 2.28e-9
Cb 15 14 1.793E-9
Cin 6 8 8.461e-10
Dbreak 5 11 DBKMOD
Dbody 7 5 DBDMOD
Dplcap 10 5 DPLCAPMOD
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Ldrain 1 5 1e-9
Lgate 2 9 5.0e-9
Lkelvin 4 8 5e-9
Lsource 3 7 5.0e-9
Mos 5 6 8 8 MOSMOD
Rgate 9 6 1.00
Rin 6 8 1e9
Rsource 8 7 1.288e-2
S1a 6 12 13 8 S1AMOD
S1b 12 13 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 15 13 14 13 S2BMOD
Vbreak 11 7 DC 107.3
.MODEL DBDMOD D (IS=3.287e-13 RS=1.312e-2 CJO=1.81E-9 TT=2.186e-7)
.MODEL DBKMOD D (RS=7.5e-1)
.MODEL DPLCAPMOD D (CJO=5.415e-10 IS=1e-30 N=10)
.MODEL MOSMOD NMOS (VTO=3.366 KP=3.385 IS=1e-30 N=10 TOX=1 L=1u W=1u
+ RD=4.118E-2)
.MODEL S1AMOD VSWITCH(RON=1e-5 ROFF=0.1 VON=-2.18 VOFF=-0.18)
.MODEL S1BMOD VSWITCH(RON=1e-5 ROFF=0.1 VON=-0.18 VOFF=-2.18)
.MODEL S2AMOD VSWITCH(RON=1e-5 ROFF=0.1 VON=-5.0 VOFF=15)
.MODEL S2BMOD VSWITCH(RON=1e-5 ROFF=0.1 VON=15 VOFF=-5.0)
.ENDS
*
.SUBCKT FRL230  1 2 3  
*Term. Conn.*** D G S 
* Spice model circuit for the FRL230
*For a detail electrical specification see datasheet file FN3223
**************************************************************************
*   For further discussion of the basics of this PSPICE PowerFET         *
*   macromodel consult "A New PSPICE Sub-circuit for the Power MOSFET    *