*-----------------------------------------------------------------------
* Filename:		6146.inc  13/8/97
* Simulator:		PSpice
* Device type:		RF beam tetrode
* Device model:		6146
*
* Author:		Duncan Munro
* Date:			13/8/97
* Copyright:		(C)1997-2000 Duncan Amplification
* 
* The following parameters are not modelled:
*
*   (1) Heater
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A  Anode
*        S  Screen
*        G  Grid
*        K  Cathode
*
*-----------------------------------------------------------------------
.SUBCKT 6146 A S G K
*
* Calculate contribution to cathode current
*
Eat	at	0	VALUE={0.636*ATAN(V(A,K)/10)}
Eme	me	0	VALUE={LIMIT(V(A,K),0,10000)/130}
Emu	mu	0	VALUE={PWRS(V(G,K),1-(LIMIT(-V(G,K),30,9999)-30)/2000)}
Egs	gs	0	VALUE={LIMIT(V(A,K)/10+V(S,K)*4.5+V(mu)*19,0,1E6)}
Egs2	gs2	0	VALUE={PWRS(V(gs),1.5)*16E-6}
Ecath  	cc    	0 	VALUE={LIMIT(V(gs2)*V(at),0,V(me))}
Esd	sd	0	VALUE={LIMIT(V(gs2)*V(at)-V(me),0,99999)}
*
* Calculate anode current
*
Ga     	A     	K     	VALUE={V(cc)}
*
* Calculate screen current
*
Escrn	sc	0	VALUE={2.5E-4*PWRS(V(S,K),1.5)*V(gs2)*(1.1-V(at))+V(sd)}
Gs     	S     	K	VALUE={V(sc)}
*
* Grid current
*
Gg	G	K	VALUE={PWR(LIMIT(V(G,K)+1,0,1E6),1.5)*(1.25-V(at))*870E-6}
*
* Capacitances
*
Cg1	G	K	13.0p
Cak	A	K	8.5p
Cg1a	G	A	0.24p
.ENDS 
*-----------------------------------------------------------------------
* Filename:		6BM8P.inc  03/03/99  V1
* Simulator:		PSpice
* Device type:		Power pentode
* Device model:		6BM8/ECL82
*
* Author:		Duncan Munro
* Date:			3/3/99
* Copyright:		(C)1999-2000 Duncan Amplification
*
*
* The following parameters are not modelled:
*
*   (1) Heater
*   (2) Grid current
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A  Anode
*        S  Screen
*        G  Grid
*        K  Cathode
*
*-----------------------------------------------------------------------
.SUBCKT 6BM8P A S G K
*
* Calculate contribution to cathode current
*
Eat	at	0	VALUE={0.636*ATAN(V(A,K)/15)}
Egs	gs	0	VALUE={LIMIT(V(S,K)/7+V(G,K)*1.3+V(A,K)/700,0,1E6)}
Egs2	gs2	0	VALUE={PWRS(V(gs),1.24)}
Ecath  	cc    	0 	VALUE={V(gs2)*V(at)}
*
* Calculate anode current
*
Ga     	A     	K     	VALUE={3.45E-3*V(cc)}
*
* Calculate screen current
*
Escrn	sc	0	VALUE={V(gs2)*(1.1-V(at))}
Gs     	S     	K	VALUE={3.7E-3*V(sc)*LIMIT(V(S,K),0,10)/10}
*
* Capacitances
*
Cg1	G	K	9.6p
Cak	A	K	9.3p
Cg1a	G	A	0.35p
.ENDS 
*-----------------------------------------------------------------------
* Filename:		6BQ5.inc  12/10/97  V3
* Simulator:		PSpice
* Device type:		Power pentode
* Device model:		6BQ5/EL84
*
* Author:		Duncan Munro
* Date:			12/5/97
* Copyright:		(C)1997-2000 Duncan Amplification
*
*
* V3 [12/10/97]: Screen current limited to prevent screen current
*		 draw at Vs = 0.
* 
* The following parameters are not modelled:
*
*   (1) Heater
*   (2) Grid current is an approximation
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A  Anode
*        S  Screen
*        G  Grid
*        K  Cathode
*
*-----------------------------------------------------------------------
.SUBCKT 6BQ5 A S G K
*
* Calculate contribution to cathode current
*
Eat	at	0	VALUE={0.636*ATAN(V(A,K)/15)}
Egs	gs	0	VALUE={LIMIT(V(S,K)/19+V(G,K)+V(A,K)/1400,0,1E6)}
Egs2	gs2	0	VALUE={PWRS(V(gs),1.5)}
Ecath  	cc    	0 	VALUE={V(gs2)*V(at)}
*
* Calculate anode current
*
Ga     	A     	K     	VALUE={3.2E-3*V(cc)}
*
* Calculate screen current
*
Escrn	sc	0	VALUE={V(gs2)*(1.1-V(at))}
Gs     	S     	K	VALUE={2.0E-3*V(sc)*LIMIT(V(S,K),0,10)/10}
*
* Grid current (approximation - does not model low va/vs)
*
Gg	G	K	VALUE={PWR(LIMIT(V(G,K)+1,0,1E6),1.5)*50E-6}
*
* Capacitances
*
Cg1	G	K	10.8p
Cak	A	K	6.5p
Cg1a	G	A	0.5p
.ENDS 
*-----------------------------------------------------------------------
* Filename:		6CA7.inc  V2 12/10/97
* Simulator:		PSpice
* Device type:		Power pentode
* Device model:		6CA7/EL34
*
* Author:		Duncan Munro
* Date:			2/5/97
* Copyright:		(C)1997-2000 Duncan Amplification
*
*
* V2 [12/10/97]: Screen current limited to prevent screen current
*		 draw at Vs = 0.
* 
* The following parameters are not modelled:
*
*   (1) Heater
*   (2) Grid current is an approximation
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A  Anode
*        S  Screen
*        G  Grid
*        K  Cathode
*
*-----------------------------------------------------------------------
.SUBCKT 6CA7 A S G K
*
* Calculate contribution to cathode current
*
Eat	at	0	VALUE={0.636*ATAN(V(A,K)/23)}
Egs	gs	0	VALUE={LIMIT(V(S,K)/9.3+V(G,K)*0.95,0,1E6)}
Egs2	gs2	0	VALUE={PWRS(V(gs),1.5)}
Ecath  	cc    	0 	VALUE={V(gs2)*V(at)}
*
* Calculate anode current
*
Ga     	A     	K     	VALUE={1.86E-3*V(cc)}
*
* Calculate screen current
*
Escrn	sc	0	VALUE={V(gs2)*(1.1-V(at))}
Gs     	S     	K	VALUE={1.518E-3*V(sc)*LIMIT(V(S,K),0,10)/10}
*
* Grid current (approximation - does not model low va/vs)
*
Gg	G	K	VALUE={PWR(LIMIT(V(G,K)+1,0,1E6),1.5)*50E-6}
*
* Capacitances
*
Cg1	G	K	15.4p
Cak	A	K	8.4p
Cg1a	G	A	1.1p
.ENDS 
*-----------------------------------------------------------------------
* Filename:		6KG6.inc  V2 12/10/97
* Simulator:		PSpice
* Device type:		Power pentode
* Device model:		6KG6/EL509
*			(also 40KG6/PL509 as no heater model)
*
* Author:		Duncan Munro
* Date:			21/7/97
* Copyright:		(C)1997-2000 Duncan Amplification
*
*
* V2 [12/10/97]: Screen current limited to prevent screen current
*		 draw at Vs = 0.
* 
* The following parameters are not modelled:
*
*   (1) Heater
*   (2) Grid current is an approximation in the absence
*       of suitable data
*
* Also see comments below, as the Svetlana EL509 is of different
* construction and has different capacitances.
*
* Please note that this model is provided "as is" and
* no warranty is provided in respect of its suitability
* for any application.
*
* This model is provided for educational and non-profit use.
*
* Email queries to postmaster@duncanamps.com
*
* Pins   A  Anode
*        S  Screen
*        G  Grid
*        K  Cathode
*
*-----------------------------------------------------------------------
.SUBCKT 6KG6 A S G K
*
* Calculate contribution to cathode current
*
Eat	at	0	VALUE={0.636*ATAN(V(A,K)/20)}
Eme	me	0	VALUE={PWR(LIMIT(V(A,K),0,10000),1.5)/17}
Emu	mu	0	VALUE={PWRS(V(G,K),1-(LIMIT(-V(G,K),5,9999)-5)/1150)}
Egs	gs	0	VALUE={LIMIT(V(S,K)/19+V(mu)/4.3+V(A,K)/800,0,1E6)}
Egs2	gs2	0	VALUE={PWRS(V(gs),1.5)}
Ecath  	cc    	0 	VALUE={LIMIT(V(gs2)*V(at),0,V(me))}
Elim	el	0	VALUE={LIMIT(V(gs2)*V(at)-V(cc),0,99999)}
*
* Calculate anode current
*
Ga     	A     	K     	VALUE={6E-2*V(cc)}
*
* Calculate screen current
*
Escrn	sc	0	VALUE={V(gs2)*(1.1-V(at))+1.2*V(el)}
Gs     	S     	K	VALUE={1.2E-2*V(sc)*LIMIT(V(S,K),0,10)/10}
*
* Grid current (approximation - does not model low va/vs)
*
Gg	G	K	VALUE={PWR(LIMIT(V(G,K)+1,0,1E6),1.5)*50E-6}
*
* Capacitances
* NOTE: Change Cg1 from 37p to 25p for Svetlana EL509
*
Cg1	G	K	37p
Cak	A	K	18.5p
Cg1a	G	A	2.5p
.ENDS