#/*
# * 文件:       linker.lcf
# * 目的:    M52235EVB的連接文件
# *
#  說明: 調(diào)試器使用非法指令向量停止運(yùn)行。
#  一段小程序被寫入到地址VBR+0x408-VBR+0x40B來響應(yīng)異常。
#  非法指令向量在向量表的VBR+0x10然后指向它。當(dāng)調(diào)試器遇到非法指令時，
#  程序執(zhí)行這段小程序, 以RTE結(jié)尾，然后退出。
#  不要重寫存儲器的這段區(qū)域，否則調(diào)試器可能不會正確退出
# */

MEMORY
{
    flash   (RX)   : ORIGIN = 0x00000000, LENGTH = 0x00040000
	sram	(RWX)  : ORIGIN = 0x20000000, LENGTH = 0x00007C00
	ipsbar  (RWX)  : ORIGIN = 0x40000000, LENGTH = 0x0
}

SECTIONS 
{
	.ipsbar	 : {} > ipsbar
    
	.flash :
	{
		vectors.s (.text)
		. 			   = ALIGN(0x10);
		*(.text)
		. 			   = ALIGN(0x10);
		*(.rodata)
		___DATA_ROM	   = .;
    } > flash
    
    .data : AT(___DATA_ROM) 
	{
		___DATA_RAM    = . ;

        *(.exception)	
		.              = ALIGN(0x10);	
		__exception_table_start__ = .;
	    EXCEPTION
		__exception_table_end__   = .;

		___sinit__     = .;
	    STATICINIT

        *(.data)
		.              = ALIGN (0x10);
		___DATA_END    = .;

		__START_SDATA  = .;
        *(.sdata)
		.              = ALIGN (0x10);
		__END_SDATA    = .;

		__SDA_BASE     = .;
		.              = ALIGN(0x10);
	} > sram

	.bss :
	{
		. = ALIGN(0x10);
		__START_SBSS = .;
		*(.sbss)
		*(SCOMMON)
		__END_SBSS   = .;

		. = ALIGN(0x10);
		__START_BSS  = .;
		*(.bss)
		*(COMMON)
		__END_BSS    = .;	
        ___BSS_START = __START_SBSS;
        ___BSS_END   = __END_BSS;
        . = ALIGN(0x10);

	} >> sram

	___FLASH		= ADDR(.flash);
	___FLASH_SIZE	= 0x00040000;
	___SRAM			= 0x20000000;
	___SRAM_SIZE	= 0x00008000;

	___VECTOR_RAM	= 0x20000000;
	___IPSBAR		= ADDR(.ipsbar);

    __S_romp        = 0; 

    ___SP_SIZE      = 0x1000;
	___HEAP_START	= .;
	___HEAP_END		= ___SRAM + ___SRAM_SIZE - ___SP_SIZE;
	___SP_END		= ___HEAP_END;
	___SP_INIT		= ___SP_END + ___SP_SIZE;
	
  	___heap_addr 	= ___HEAP_START;
	___heap_size 	= ___HEAP_END - ___HEAP_START ;
	__SP_INIT 		= ___SP_INIT;
	___STACK_SIZE = ___SP_INIT - ___SP_END;
}