*                          MICRON HSPICE MODEL
*
* Disclaimer:   This software code and all associated documentation, comments
*               or other information (collectively "Software") is provided 
*               "AS IS" without warranty of any kind. MICRON TECHNOLOGY, INC. 
*               ("MTI") EXPRESSLY DISCLAIMS ALL WARRANTIES EXPRESS OR IMPLIED,
*               INCLUDING BUT NOT LIMITED TO, NONINFRINGEMENT OF THIRD PARTY
*               RIGHTS, AND ANY IMPLIED WARRANTIES OF MERCHANTABILITY OR FITNESS
*               FOR ANY PARTICULAR PURPOSE. MTI DOES NOT WARRANT THAT THE
*               SOFTWARE WILL MEET YOUR REQUIREMENTS, OR THAT THE OPERATION OF
*               THE SOFTWARE WILL BE UNINTERRUPTED OR ERROR-FREE. FURTHERMORE,
*               MTI DOES NOT MAKE ANY REPRESENTATIONS REGARDING THE USE OR THE
*               RESULTS OF THE USE OF THE SOFTWARE IN TERMS OF ITS CORRECTNESS,
*               ACCURACY, RELIABILITY, OR OTHERWISE. THE ENTIRE RISK ARISING OUT
*               OF USE OR PERFORMANCE OF THE SOFTWARE REMAINS WITH YOU. IN NO
*               EVENT SHALL MTI, ITS AFFILIATED COMPANIES OR THEIR SUPPLIERS BE
*               LIABLE FOR ANY DIRECT, INDIRECT, CONSEQUENTIAL, INCIDENTAL, OR
*               SPECIAL DAMAGES (INCLUDING, WITHOUT LIMITATION, DAMAGES FOR LOSS
*               OF PROFITS, BUSINESS INTERRUPTION, OR LOSS OF INFORMATION)
*               ARISING OUT OF YOUR USE OF OR INABILITY TO USE THE SOFTWARE,
*               EVEN IF MTI HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGES.
*               Because some jurisdictions prohibit the exclusion or limitation
*               of liability for consequential or incidental damages, the above
*               limitation may not apply to you.
* 
*               Copyright 2005 Micron Technology, Inc. All rights reserved.
*
*************** 64Megx4, 32Megx8, 16Megx16 DDR2-400/533 SDRAM *****************
***Example HSPICE setup for all input circuits except CLK/CLK# & DM************

***********************************************************
****             ___                                      *
****            /  +|-----PAD---\/\/\/--@@@@-----IN_PKG   *
**** RCVR_OUT--{   -|-----VREF   R_pkg  L_pkg |           *
****            \___|--RCVREN                ===C_pkg     *
****                                          |           *
****                                         GND          *
***********************************************************

**** This netlist is for the x4, x8, x16 256Mb DDR2-400/533 SDRAM **********
**** The input signal is IN_PKG (input signal).
**** The output of the input receiver circuit is the node RCVR_OUT.
**** To account for package parasitics correlative impedance values
**** (netlist elements r_pkg,l_pkg,c_pkg) have been attached to the PAD node.

**** The .LIB statement selects the following modes:
****    TT - Typical N, Typical P, Typical die capacitance
****    SS - Slow N, Slow P, Maximum die capacitance
****    FF - Fast N, Fast P, Minimum die capacitance

**** To run this simulation, the files "model.cnr" and "u26a_inbuff.inc" are
**** required to be in the same directory as this netlist.
**** Temperature settings are: Typical 40C, Slow 100C, Fast 0C

.OPTIONS ACCT OPTS NOPAGE POST
.OPTIONS METHOD=GEAR
.OPTIONS SEARCH=' '  $This option must be present for decryption to work

.TRAN 0.05ns 10.0ns
**The temperature is for the slow case
.TEMP 100
.LIB "model.cnr" SS

**** Input signals and power supplies setup
**** Note: vccp is a regulated internal voltage
**** Match up typ, min, or max voltages for corner sims
.PARAM  vcc_typ   = 1.800V
.PARAM  vcc_min   = 1.700V
.PARAM  vcc_max   = 1.900V

.PARAM  vccp_typ  = 3.30V
.PARAM  vccp_min  = 3.20V
.PARAM  vccp_max  = 3.40V

.PARAM  gnd       = 0.0V
********************************************************************************
.PARAM  vcc       = vcc_min
.PARAM  vccp      = vccp_min
********************************************************************************
Vvcc    vcc   0  DC = vcc
Vvccp   vccp  0  DC = vccp
Vref    vref  0  DC = 'vcc/2' 

Ven   rcvr_en  0  DC = vcc
**Active high receiver enable

Vin   in_pkg  0  PULSE gnd vcc 100ps 400ps 400ps 4.60ns 10.00ns
**Vin toggles the Input at 100MHz

* top cell:  input
* *********************************************
* Output load circuits:
xi0 pad rcvr_en vref rcvr_out gnd vcc u26a_inbuff

* Refer to the IBIS model for specific package parasitic values.
r_pkg pad net1 R=56.5e-3
l_pkg net1 in_pkg L=1.96e-9
c_pkg in_pkg gnd c=270e-15


.alter typ
.PARAM  vcc         = vcc_typ
.PARAM  vccp        = vccp_typ
.temp 40
.LIB "model.cnr" TT

.alter fast
.PARAM  vcc         = vcc_max
.PARAM  vccp        = vccp_max
.temp 0
.LIB "model.cnr" FF

.END